P_BillgProcDocPartnerAddress

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Billing Process Document Partner Address'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.private:true
@VDM.viewType: #COMPOSITE
define view entity P_BillgProcDocPartnerAddress
  as select from I_BillingDocumentPartnerBasic as Partner
  association [0..1] to I_ContactPerson                as _ContactPerson                on  $projection.ContactPerson = _ContactPerson.ContactPerson
  association [1]    to I_WorkAssignment               as _WorkAssignment               on  $projection.Personnel = _WorkAssignment.WorkAssignment

  association [0..1] to I_TransportationZone           as _TransportationZone           on  $projection.transportzone = _TransportationZone.TransportZone
                                                                                        and $projection.country       = _TransportationZone.CountryCode
  association [0..1] to I_OrganizationAddress          as _OrganizationAddress          on  $projection.AddressID                          = _OrganizationAddress.AddressID
                                                                                        and $projection.AddressPersonID                    = _OrganizationAddress.AddressPersonID
                                                                                        and $projection.AddressObjectType                  = '1'
                                                                                        and _OrganizationAddress.AddressRepresentationCode is initial
  association [0..1] to I_PersonAddress                as _PersonAddress                on  $projection.AddressID                    = _PersonAddress.AddressID
                                                                                        and $projection.AddressPersonID              = _PersonAddress.AddressPersonID
                                                                                        and $projection.AddressObjectType            = '2'
                                                                                        and _PersonAddress.AddressRepresentationCode is initial

  association [0..1] to I_PersonWorkplaceAddress       as _PersonWorkplaceAddress       on  $projection.AddressID                             = _PersonWorkplaceAddress.AddressID
                                                                                        and $projection.AddressPersonID                       = _PersonWorkplaceAddress.AddressPersonID
                                                                                        and $projection.AddressObjectType                     = '3'
                                                                                        and _PersonWorkplaceAddress.AddressRepresentationCode is initial
  association [0..1] to P_BillingAddrOrgNamePostalAddr as _OrgNamePostalAddress         on  $projection.AddressID                           = _OrgNamePostalAddress.AddressID
                                                                                        and _OrgNamePostalAddress.AddressRepresentationCode is initial

  association [0..1] to P_BillingAddressPersonName     as _PersonName                   on  $projection.AddressPersonID           = _PersonName.AddressPersonID
                                                                                        and _PersonName.AddressRepresentationCode is initial


  association [0..1] to I_AddrCurDfltLandlinePhoneNmbr as _CurrentDfltLandlinePhoneNmbr on  $projection.AddressID       = _CurrentDfltLandlinePhoneNmbr.AddressID
                                                                                        and $projection.AddressPersonID = _CurrentDfltLandlinePhoneNmbr.AddressPersonID

  association [0..1] to I_AddrCurDefaultEmailAddress   as _CurrentDfltEmailAddress      on  $projection.AddressID       = _CurrentDfltEmailAddress.AddressID
                                                                                        and $projection.AddressPersonID = _CurrentDfltEmailAddress.AddressPersonID

  association [0..1] to I_AddrCurDfltMobilePhoneNumber as _CurrentDfltMobilePhoneNumber on  $projection.AddressID       = _CurrentDfltMobilePhoneNumber.AddressID
                                                                                        and $projection.AddressPersonID = _CurrentDfltMobilePhoneNumber.AddressPersonID

  association [0..1] to I_AddrCurDefaultFaxNumber      as _CurrentDfltFaxNumber         on  $projection.AddressID       = _CurrentDfltFaxNumber.AddressID
                                                                                        and $projection.AddressPersonID = _CurrentDfltFaxNumber.AddressPersonID

{
  key  cast(Partner.BillingDocument as billing_process_document preserving type) as BillingProcessDocument,
  key  cast(PartnerFunction as parvw_unv preserving type )                       as PartnerFunction,

       Personnel,
       ContactPerson,

       AddressID,
       AddressPersonID,
       AddressObjectType,

       @Semantics.name.fullName: true
       @Semantics.text: true
       cast(
       case Partner.AddressID
         when ''
          then
           case
             when Partner.Personnel != '00000000'
               then coalesce(_WorkAssignment.PersonFullName,
                             _WorkAssignment._WorkforcePerson.LastName)
           end
         else
           case
             when Partner.AddressObjectType = '1'
               then
                  case
                    when Partner.ContactPerson != '0000000000'
                      then
                        cast(substring(replace(concat(_ContactPerson.FirstName,
                                               concat(' &@', _ContactPerson.LastName) ), '&@', '') ,1,80) as ad_namtext )
                    when Partner.Personnel != '00000000'
                      then _OrganizationAddress.AddresseeName1  //Document specific personnel

                    else
                      cast(concat_with_space(_OrganizationAddress.AddresseeName1,
                                             _OrganizationAddress.AddresseeName2, 1) as ad_namtext )
                   end
             when Partner.AddressObjectType = '2'
               then _PersonAddress.PersonFullName
             when Partner.AddressObjectType = '3'
               then _PersonWorkplaceAddress.PersonFullName
           end
         end as ad_namtext preserving type )                                                     as FullName,
       
       @Semantics.address.street: true
       _OrgNamePostalAddress.StreetPrefixName1,
       @Semantics.address.street: true
       _OrgNamePostalAddress.StreetPrefixName2,
       @Semantics.address.street: true
       _OrgNamePostalAddress.StreetName,
       @Semantics.address.street: true
       _OrgNamePostalAddress.StreetSuffixName1,
       @Semantics.address.street: true
       _OrgNamePostalAddress.StreetSuffixName2,
       @Semantics.address.streetNoNumber: true
       _OrgNamePostalAddress.HouseNumber,
       @Semantics.address.zipCode:true
       _OrgNamePostalAddress.PostalCode,
       _OrgNamePostalAddress.DistrictName,
       @Semantics.address.city:true
       _OrgNamePostalAddress.CityName,
       @Semantics.address.postBox: true
       _OrgNamePostalAddress.POBox,
       @Semantics.address.zipCode:true
       _OrgNamePostalAddress.POBoxPostalCode,
       _OrgNamePostalAddress.TaxJurisdiction,

       @Semantics.telephone.type: [#WORK]
       cast(coalesce(_CurrentDfltLandlinePhoneNmbr.InternationalPhoneNumber,
                     _WorkAssignment._WorkplaceAddress.NormalizedPhoneNumber)
         as ad_telnrlg preserving type )                                         as InternationalPhoneNumber,

       @Semantics.telephone.type:  [#CELL]
       cast(coalesce(_CurrentDfltMobilePhoneNumber.InternationalPhoneNumber,
                     _WorkAssignment._WorkplaceAddress.MblNormalizedPhoneNumber)
         as ad_telnrlg preserving type )                                         as InternationalMobilePhoneNumber,

       @Semantics.telephone.type: [#FAX]
       cast(coalesce(_CurrentDfltFaxNumber.InternationalFaxNumber,
                     _WorkAssignment._WorkplaceAddress.InternationalFaxNumber)
         as ad_fxnrlng preserving type )                                         as InternationalFaxNumber,

       @Semantics.eMail.address: true
       @Semantics.eMail.type:  [#WORK]
       cast(coalesce( _CurrentDfltEmailAddress.EmailAddress,
                   _WorkAssignment._WorkplaceAddress.DefaultEmailAddress)
        as vdm_sd_ad_smtpadr preserving type )                                   as EmailAddress,

       @Semantics.address.country:true
       @ObjectModel.foreignKey.association: '_Country'
       _OrgNamePostalAddress.Country,
       _OrgNamePostalAddress._Country._Text[1: Language=$session.system_language].CountryName,

       @Semantics.address.region: true
       @ObjectModel.foreignKey.association: '_Region'
       _OrgNamePostalAddress.Region,
       _OrgNamePostalAddress._Region._RegionText[1: Language=$session.system_language].RegionName,

       @ObjectModel.foreignKey.association: '_TransportationZone'
       _OrgNamePostalAddress.TransportZone,
       _OrgNamePostalAddress._TransportationZone._Text[1: Language=$session.system_language].TransportZoneDescription,

       @Semantics.name.jobTitle: true
       cast(coalesce(_PersonName.FormOfAddress,
                     _OrgNamePostalAddress.FormOfAddress)
         as ad_title preserving type )                                           as FormOfAddress,

       cast(coalesce(_PersonName._FormOfAddress._Text[1: Language=$session.system_language].FormOfAddressName,
                     _OrgNamePostalAddress._FormOfAddress._Text[1: Language=$session.system_language].FormOfAddressName)
         as ad_titletx preserving type )                                         as FormOfAddressName,

       coalesce(_PersonName.CorrespondenceLanguage,
                _OrgNamePostalAddress.CorrespondenceLanguage)                    as CorrespondenceLanguage,

       cast(coalesce(_PersonName._CorrespondenceLanguage._Text[1: Language=$session.system_language].LanguageName,
                     _OrgNamePostalAddress._CorrespondenceLanguage._Text[1: Language=$session.system_language].LanguageName)
         as sptxt preserving type )                                              as CorrespondenceLanguageName,

       _OrgNamePostalAddress._Country,
       _OrgNamePostalAddress._Region,
       _TransportationZone

}