I_BILLINGDOCUMENTPARTNERBASIC

CDS View

Partner in Billing Process Document

I_BILLINGDOCUMENTPARTNERBASIC is a CDS View in S/4HANA. Partner in Billing Process Document. It contains 20 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 20 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
I_BillingDocReqPartner view from COMPOSITE Billing Document Request Partner
I_BillingDocumentPartner view from COMPOSITE Billing Document Partner
I_InvoiceListPartner view_entity from COMPOSITE Invoice List Partner
I_PrelimBillingDocPartner view from COMPOSITE Preliminary Billing Document Partner
P_BillgProcDocItemInhtdPartner view_entity inner COMPOSITE Billing process document item inherited partner(from header)
P_BillgProcDocPartnerAddress view_entity from COMPOSITE Billing Process Document Partner Address

Fields (20)

KeyField CDS FieldsUsed in Views
KEY BillingDocument BillingDocument 2
KEY PartnerFunction PartnerFunction 2
_Address _Address 4
_BillingDocumentBasic _BillingDocumentBasic 1
_BPRefAddressForDocSpcfcAddr _BPRefAddressForDocSpcfcAddr 3
_BusinessPartnerAddress _BusinessPartnerAddress 4
_DfltAddrRprstn _DfltAddrRprstn 5
_PartnerFunction _PartnerFunction 5
AddressID AddressID 5
AddressObjectType AddressObjectType 3
AddressPersonID AddressPersonID 5
BPRefAddressIDForDocSpcfcAddr BPRefAddressIDForDocSpcfcAddr 3
ContactPerson ContactPerson 5
Customer Customer 5
Personnel Personnel 5
ReferenceBusinessPartner ReferenceBusinessPartner 5
SDDocPartnerAddressRefType SDDocPartnerAddressRefType 5
Supplier Supplier 5
UnloadingPointName UnloadingPointName 3
VATRegistration VATRegistration 3 
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Partner in Billing Process Document'
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED,
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDBILDOCPTBC',
  compiler.compareFilter: true,
  preserveKey: true
}
@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true

define view I_BillingDocumentPartnerBasic
  as select from I_SDDocumentPartner    as Partner
    inner join   I_BillingDocumentBasic as BillingDocument on BillingDocument.BillingDocument = Partner.SDDocument

  association [1..1] to I_BillingDocumentBasic as _BillingDocumentBasic on $projection.BillingDocument = _BillingDocumentBasic.BillingDocument

{
      //--[ GENERATED:012:GlBfhyJl7kY4v5RWfCiSf0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BillingDocumentBasicStdVH',
                     element: 'BillingDocument' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_BillingDocumentBasic'
  key cast(Partner.SDDocument as vbeln_vf preserving type ) as BillingDocument,
      @ObjectModel.foreignKey.association: '_PartnerFunction'
  key Partner.PartnerFunction,

      Partner.Customer,

      Partner.Supplier,

      Partner.Personnel,
      @ObjectModel.foreignKey.association: '_Address'
      Partner.AddressID,
      Partner.ContactPerson,

      Partner.AddressPersonID,
      Partner.ReferenceBusinessPartner,
      Partner.SDDocPartnerAddressRefType,
      Partner.BPRefAddressIDForDocSpcfcAddr,

      Partner.AddressObjectType,
      Partner.VATRegistration,
      Partner.UnloadingPointName,

      //Association

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _BillingDocumentBasic,
      Partner._PartnerFunction,
      Partner._Address,
      Partner._BusinessPartnerAddress,
      Partner._BPRefAddressForDocSpcfcAddr,
      Partner._DfltAddrRprstn
}

Learn More