P_AssetValuationForLedger

@AbapCatalog: {sqlViewName: 'PFIASTVALFORLDGR', preserveKey: true, compiler.compareFilter: true}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

define view P_AssetValuationForLedger
  as select from I_FixedAssetDeprArea
    inner join   I_DepreciationAreaForLedger on  I_DepreciationAreaForLedger.CompanyCode           = I_FixedAssetDeprArea.CompanyCode
                                             and I_DepreciationAreaForLedger.AssetDepreciationArea = I_FixedAssetDeprArea.AssetRealDepreciationArea
    inner join   I_AssetRedesignSwitchStatus on I_AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = ''
{
  key  I_FixedAssetDeprArea.CompanyCode,
  key  I_FixedAssetDeprArea.MasterFixedAsset,
  key  I_FixedAssetDeprArea.FixedAsset,
  key  I_DepreciationAreaForLedger.Ledger,
  key  I_FixedAssetDeprArea.AssetRealDepreciationArea,
  key  I_FixedAssetDeprArea.ValidityEndDate,

       I_FixedAssetDeprArea.ValidityStartDate,
       I_FixedAssetDeprArea.DepreciationStartDate,
       I_FixedAssetDeprArea.SpecialDeprStartDate,
       I_FixedAssetDeprArea.DeprKeyChangeoverYear,
       I_FixedAssetDeprArea.DeprKeyChangeoverPeriod,
       I_FixedAssetDeprArea.DepreciationKey,
       I_FixedAssetDeprArea.InvestmentSupportMeasure,
       I_FixedAssetDeprArea.PlannedUsefulLifeInPeriods,
       I_FixedAssetDeprArea.PlannedUsefulLifeInYears,
       I_FixedAssetDeprArea.VintageYear,
       I_FixedAssetDeprArea.VintageMonth,
       I_FixedAssetDeprArea.OriglAstUsefulLifeInPerds,
       I_FixedAssetDeprArea.OriglAstUsefulLifeInYears,
       I_FixedAssetDeprArea.ReplacementValueIndexSers,
       I_FixedAssetDeprArea.RplcmtValueAgingIndexSers,
       I_FixedAssetDeprArea.AcqnProdnCostScrapPercent,
       I_FixedAssetDeprArea.VariableDeprPercent,
       cast('00000000' as abgdat_b)                                                 as LastRetirementValueDate, //Due to performance reasons it is not read from I_FixedAsset

       cast('' as faa_md_calc_view_type)                                            as DepreciationAreaType,
       cast(I_FixedAssetDeprArea.ScrapAmountInCoCodeCrcy as faa_md_scrap_value_hsl) as ScrapAmountInCoCodeCrcy,
       I_FixedAssetDeprArea. AssetOpgReadinessDate,
       cast('000000000000' as faa_uo)                                               as FixedAssetUsageObject    // Usage Object is only available for Asset Redesign

}

union all select from I_AssetTimeBasedValuation
  inner join          I_AssetValuation            on  I_AssetValuation.CompanyCode           = I_AssetTimeBasedValuation.CompanyCode
                                                  and I_AssetValuation.MasterFixedAsset      = I_AssetTimeBasedValuation.MasterFixedAsset
                                                  and I_AssetValuation.FixedAsset            = I_AssetTimeBasedValuation.FixedAsset
                                                  and I_AssetValuation.Ledger                = I_AssetTimeBasedValuation.Ledger
                                                  and I_AssetValuation.AssetDepreciationArea = I_AssetTimeBasedValuation.AssetDepreciationArea
  inner join          I_AssetRedesignSwitchStatus on I_AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = 'X'
{
  key I_AssetTimeBasedValuation.CompanyCode,
  key I_AssetTimeBasedValuation.MasterFixedAsset,
  key I_AssetTimeBasedValuation.FixedAsset,
  key I_AssetTimeBasedValuation.Ledger,
  key I_AssetTimeBasedValuation.AssetDepreciationArea as AssetRealDepreciationArea,
  key I_AssetTimeBasedValuation.ValidityEndDate,

      I_AssetTimeBasedValuation.ValidityStartDate,
      I_AssetValuation.DepreciationStartDate,
      I_AssetValuation.SpecialDeprStartDate,
      I_AssetValuation.DeprKeyChangeoverYear,
      I_AssetValuation.DeprKeyChangeoverPeriod,
      I_AssetTimeBasedValuation.DepreciationKey,
      cast('' as invsl)                               as InvestmentSupportMeasure,
      I_AssetTimeBasedValuation.PlannedUsefulLifeInPeriods,
      I_AssetTimeBasedValuation.PlannedUsefulLifeInYears,
      cast('0000' as vyear)                           as VintageYear,
      cast('000' as vmnth)                            as VintageMonth,
      cast('000' as ndurp)                            as OriglAstUsefulLifeInPerds,
      cast('000' as ndurj)                            as OriglAstUsefulLifeInYears,
      I_AssetValuation.ReplacementValueIndexSers,
      I_AssetValuation.RplcmtValueAgingIndexSers,
      I_AssetTimeBasedValuation.AcqnProdnCostScrapPercent,
      I_AssetTimeBasedValuation.VariableDeprPercent,
      I_AssetValuation.LastRetirementValueDate,
      I_AssetValuation.DepreciationAreaType,
      I_AssetTimeBasedValuation.ScrapAmountInCoCodeCrcy,
      I_AssetValuation.AssetOpgReadinessDate,
      I_AssetTimeBasedValuation.FixedAssetUsageObject
}