I_ASSETVALUATION
Asset Valuation
I_ASSETVALUATION is a CDS View in S/4HANA. Asset Valuation. It contains 15 fields. 13 CDS views read from this table.
CDS Views using this table (13)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_AssetValuationVH | view | from | CONSUMPTION | Asset Valuation Value Help |
| C_FixedAssetPostingDeprAreaVH | view_entity | from | CONSUMPTION | Depreciation Area for Asset Posting |
| FAC_AUDIT_Z3_ASSET_MASTER | view | inner | Asset Master | |
| I_AssetValuationForLedger | view | inner | COMPOSITE | Fixed Asset Valuation for Ledger |
| I_AssetValuationTP | view | from | TRANSACTIONAL | Asset Valuation |
| P_AssetLedgerFiscalYear | view | from | COMPOSITE | Fiscal Year in Asset Ledger |
| P_AssetValuationForLedger | view | inner | COMPOSITE | Asset Valuation For Ledger |
| P_AstDeprBalWthAllAreasCube1 | view_entity | inner | CONSUMPTION | Asset Depreciation Balance Cube With Derived Areas 1 |
| P_AstEndgBalForChtWthAllAreas1 | view_entity | inner | CONSUMPTION | Asset Tot.Depr., Total APC and NetBook Val. With Drvd Areas1 |
| P_AstKeyFigBalComprnCube1 | view | inner | CONSUMPTION | Asset Key Figure Balance Comparison Cube 1 |
| P_AstKeyFigBalWthAllAreasCube1 | view_entity | inner | CONSUMPTION | Asset Key Figure Cube Balance With Derived Areas 1 |
| P_AstNetBookBalWthAllAreas1 | view | inner | CONSUMPTION | Asset NetBook Value |
| R_FixedAssetValuationTP | view_entity | from | TRANSACTIONAL | Fixed Asset Valuation |
Fields (15)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| AssetDepreciationArea | AssetDepreciationArea | 1 | |
| AssetOpgReadinessDate | AssetOpgReadinessDate | 2 | |
| DepreciationAreaType | DepreciationAreaType | 2 | |
| DepreciationKey | DepreciationKey | 1 | |
| DepreciationStartDate | DepreciationStartDate | 3 | |
| DeprKeyChangeoverPeriod | DeprKeyChangeoverPeriod | 2 | |
| DeprKeyChangeoverYear | DeprKeyChangeoverYear | 2 | |
| InterestCalcStartDate | InterestCalcStartDate | 1 | |
| LastRetirementValueDate | LastRetirementValueDate | 2 | |
| Ledger | Ledger | 1 | |
| PlannedUsefulLifeInPeriods | PlannedUsefulLifeInPeriods | 1 | |
| PlannedUsefulLifeInYears | PlannedUsefulLifeInYears | 1 | |
| ReplacementValueIndexSers | ReplacementValueIndexSers | 2 | |
| RplcmtValueAgingIndexSers | RplcmtValueAgingIndexSers | 1 | |
| SpecialDeprStartDate | SpecialDeprStartDate | 2 |
@AbapCatalog.sqlViewName: 'IASSETVALN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Asset Valuation'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel: {
usageType.serviceQuality: #B,
usageType.sizeCategory: #XXL,
usageType.dataClass: #MASTER
}
define view I_AssetValuation
as select from faat_md_val as Valuation
association [1..1] to P_AssetTmeBsdValnCurValdtyDte as _AssetTmeBsdValnCurValdtyDte on $projection.CompanyCode = _AssetTmeBsdValnCurValdtyDte.CompanyCode
and $projection.MasterFixedAsset = _AssetTmeBsdValnCurValdtyDte.MasterFixedAsset
and $projection.FixedAsset = _AssetTmeBsdValnCurValdtyDte.FixedAsset
and $projection.Ledger = _AssetTmeBsdValnCurValdtyDte.Ledger
and $projection.AssetDepreciationArea = _AssetTmeBsdValnCurValdtyDte.AssetDepreciationArea
association [1..1] to P_AssetYearOpeningValnAttrib as _AssetYearOpeningValnAttrib on $projection.CompanyCode = _AssetYearOpeningValnAttrib.CompanyCode
and $projection.MasterFixedAsset = _AssetYearOpeningValnAttrib.MasterFixedAsset
and $projection.FixedAsset = _AssetYearOpeningValnAttrib.FixedAsset
and $projection.Ledger = _AssetYearOpeningValnAttrib.Ledger
and $projection.AssetDepreciationArea = _AssetYearOpeningValnAttrib.AssetDepreciationArea
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..1] to I_MasterFixedAsset as _MasterFixedAsset on $projection.CompanyCode = _MasterFixedAsset.CompanyCode
and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
association [1..1] to I_FixedAsset as _FixedAsset on $projection.CompanyCode = _FixedAsset.CompanyCode
and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
and $projection.FixedAsset = _FixedAsset.FixedAsset
association [1..1] to I_Ledger as _Ledger on $projection.Ledger = _Ledger.Ledger
association [1..1] to I_DepreciationArea as _DepreciationArea on $projection.CompanyCode = _DepreciationArea.CompanyCode
and $projection.Ledger = _DepreciationArea.Ledger
and $projection.AssetDepreciationArea = _DepreciationArea.AssetDepreciationArea
//association [1..1] to I_DepreciationKey as _DepreciationKey on $projection.DepreciationKey = _DepreciationKey.DepreciationKey
// and $projection.chartofdepreciation = _DepreciationKey.ChartOfDepreciation
association [0..*] to I_AssetValuationForLedger as _AssetValuationForLedger on $projection.CompanyCode = _AssetValuationForLedger.CompanyCode
and $projection.MasterFixedAsset = _AssetValuationForLedger.MasterFixedAsset
and $projection.FixedAsset = _AssetValuationForLedger.FixedAsset
and $projection.Ledger = _AssetValuationForLedger.Ledger
and $projection.AssetDepreciationArea = _AssetValuationForLedger.AssetRealDepreciationArea
{
@ObjectModel.foreignKey.association: '_CompanyCode'
key Valuation.comp_code as CompanyCode,
@ObjectModel.foreignKey.association: '_MasterFixedAsset'
key Valuation.asset_no as MasterFixedAsset,
@ObjectModel.foreignKey.association: '_FixedAsset'
key Valuation.asset_subno as FixedAsset,
@ObjectModel.foreignKey.association: '_Ledger'
key Valuation.ledger as Ledger,
@ObjectModel.foreignKey.association: '_DepreciationArea'
key Valuation.depr_area as AssetDepreciationArea,
// Current Date Information from Time-Based Valuation
_AssetTmeBsdValnCurValdtyDte.DepreciationKey as DepreciationKey,
_AssetTmeBsdValnCurValdtyDte.PlannedUsefulLifeInYears as PlannedUsefulLifeInYears,
_AssetTmeBsdValnCurValdtyDte.PlannedUsefulLifeInPeriods as PlannedUsefulLifeInPeriods,
// Fields in YDDA
_AssetYearOpeningValnAttrib.ExpiredUsefulLifeInYrs as ExpiredUsefulLifeInYrs,
_AssetYearOpeningValnAttrib.ExpiredUsefulLifeInPerds as ExpiredUsefulLifeInPerds,
_AssetYearOpeningValnAttrib.SpclExpiredUsefulLifeInYrs as SpclExpiredUsefulLifeInYrs,
_AssetYearOpeningValnAttrib.SpclExpiredUsefulLifeInPerds as SpclExpiredUsefulLifeInPerds,
Valuation.negative_values_allowed as NegativeAmountIsAllowed,
cast( Valuation.odepr_start_date as fis_afabg ) as DepreciationStartDate,
Valuation.sdepr_start_date as SpecialDeprStartDate,
Valuation.int_start_date as InterestCalcStartDate,
Valuation.readiness_date as AssetOpgReadinessDate,
// Valuation.index_repl_values as ReplacementValueIndexSers,
cast( '' as wbind ) as ReplacementValueIndexSers,
// Valuation.index_repl_age as RplcmtValueAgingIndexSers,
cast( '' as alind ) as RplcmtValueAgingIndexSers,
Valuation.changeover_year as DeprKeyChangeoverYear,
Valuation.changeover_period as DeprKeyChangeoverPeriod,
Valuation.lva_amount_check_type as LowValueAssetAmountCheckType,
Valuation.last_retirement_date as LastRetirementValueDate,
Valuation.current_fiscal_year as AssetCurrentFiscalYear,
Valuation.number_of_periods as AssetNumberOfPeriods,
Valuation.calculation_view_type as DepreciationAreaType,
//Ignore error for Currency
Valuation.ignore_error_in_hsl as CoCodeCurrencyErrorIsIgnored,
Valuation.ignore_error_in_ksl as GlobalCurrencyErrorIsIgnored,
Valuation.ignore_error_in_osl as FreeDefinedCrcy1ErrorIsIgnored,
Valuation.ignore_error_in_vsl as FreeDefinedCrcy2ErrorIsIgnored,
Valuation.ignore_error_in_bsl as FreeDefinedCrcy3ErrorIsIgnored,
Valuation.ignore_error_in_csl as FreeDefinedCrcy4ErrorIsIgnored,
Valuation.ignore_error_in_dsl as FreeDefinedCrcy5ErrorIsIgnored,
Valuation.ignore_error_in_esl as FreeDefinedCrcy6ErrorIsIgnored,
Valuation.ignore_error_in_fsl as FreeDefinedCrcy7ErrorIsIgnored,
Valuation.ignore_error_in_gsl as FreeDefinedCrcy8ErrorIsIgnored,
// Association
_CompanyCode,
_MasterFixedAsset,
_FixedAsset,
_Ledger,
_DepreciationArea,
//_DepreciationKey,
_AssetValuationForLedger
}