P_AR_StRpJournalEntryLogDetail

@AbapCatalog.sqlViewName: 'PARJRNLENTRDET'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_AR_StRpJournalEntryLogDetail
  as select from           P_AR_JournalEntry            as JournalEntry
  
    inner join             I_CompanyCode                 as CompanyCode                 on JournalEntry.CompanyCode = CompanyCode.CompanyCode
    
    inner join             I_StRpJournalEntryLog         as StRpJournalEntryLog         on  StRpJournalEntryLog.CompanyCode        = JournalEntry.CompanyCode
                                                                                        and StRpJournalEntryLog.FiscalYear         = JournalEntry.FiscalYear
                                                                                        and StRpJournalEntryLog.AccountingDocument = JournalEntry.AccountingDocument

    left outer to one join I_CountrySpecificDocumentType as CountrySpecificDocumentType on  CountrySpecificDocumentType.Country                = CompanyCode.Country
                                                                                        and CountrySpecificDocumentType.AccountingDocumentType = JournalEntry.AccountingDocumentType

    left outer to one join I_AR_OfficialDocumentTypeDetn as AR_OfficialDocumentTypeDetn on  AR_OfficialDocumentTypeDetn.AR_OfficialDocumentClass = CountrySpecificDocumentType.AR_OfficialDocumentClass
                                                                                        and AR_OfficialDocumentTypeDetn.Country                  = CompanyCode.Country
                                                                                        and AR_OfficialDocumentTypeDetn.AR_PrintCharacter        = JournalEntry.AR_PrintCharacter
                                                                                        and AR_OfficialDocumentTypeDetn.AR_Report                = 'J_1AF004'

{
  key JournalEntry.CompanyCode,
  key JournalEntry.FiscalYear,
  key JournalEntry.AccountingDocument,
  key StRpJournalEntryLog.StatryRptgEntity,
  key StRpJournalEntryLog.StatryRptCategory,
  key StRpJournalEntryLog.StatryRptRunID,
      JournalEntry.PostingDate,
      JournalEntry.ReportingDate,
      JournalEntry.DocumentReferenceID,
      JournalEntry.AR_Branch,
      JournalEntry.AR_OfficialDocumentNumber,
      JournalEntry.ReversalReferenceDocument,
      JournalEntry.AccountingDocumentType,
      JournalEntry.AR_PrintCharacter,
      JournalEntry.ReferenceDocumentType,
      cast(
        case
          when AR_OfficialDocumentTypeDetn._AR_OfficialDocumentTypeText[1: Language = $session.system_language].AR_OfficialDocTypeLongDesc is not null
            then AR_OfficialDocumentTypeDetn._AR_OfficialDocumentTypeText[1: Language = $session.system_language].AR_OfficialDocTypeLongDesc
          else JournalEntry._AccountingDocumentTypeText[1: Language = $session.system_language].AccountingDocumentTypeName
        end as logar_officialdoctypelongdesc
      ) as AR_OfficialDocTypeLongDesc,
      cast(
        case
          when JournalEntry.ExchangeRate = 0
            then 1
          else JournalEntry.ExchangeRate
        end as fis_exchange_rate
      ) as ExchangeRate,
      
      @Semantics.currencyCode:true
      JournalEntry.CompanyCodeCurrency,
      @Semantics.currencyCode:true
      JournalEntry.TransactionCurrency
}