P_AR_JOURNALENTRY

@AbapCatalog.sqlViewName: 'PARJOURNALENTRY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_AR_JournalEntry
  as select from I_JournalEntry as JournalEntry

  association [0..1] to P_AR_ConversionFactors as _ConversionFactor on  _ConversionFactor.ExchangeRateType  = $projection.ExchangeRateType
                                                                    and _ConversionFactor.SourceCurrency    = $projection.TransactionCurrency
                                                                    and _ConversionFactor.TargetCurrency    = $projection.CompanyCodeCurrency
                                                                    and _ConversionFactor.ValidityStartDate <= $projection.PostingDate
                                                                    and _ConversionFactor.ValidityEndDate   >= $projection.PostingDate

  association [0..*] to I_OneTimeAccountBP     as _OneTimeAccountBP on  JournalEntry.CompanyCode        = _OneTimeAccountBP.CompanyCode
                                                                    and JournalEntry.FiscalYear         = _OneTimeAccountBP.FiscalYear
                                                                    and JournalEntry.AccountingDocument = _OneTimeAccountBP.AccountingDocument

{
  key JournalEntry.CompanyCode,
  key JournalEntry.FiscalYear,
  key JournalEntry.AccountingDocument,

      JournalEntry.FiscalPeriod,
      JournalEntry.PostingDate,
      JournalEntry.ExchangeRateType,
      JournalEntry.DocumentDate,
      JournalEntry.TaxReportingDate,

      cast(
        case
          when JournalEntry.TaxReportingDate = '00000000' then JournalEntry.PostingDate
          when JournalEntry.TaxReportingDate <> '00000000' then JournalEntry.TaxReportingDate
        end
      as glo_reporting_date preserving type )                                as ReportingDate,

      JournalEntry.AccountingDocumentType,
      JournalEntry.AccountingDocumentCategory,
      JournalEntry.DocumentReferenceID,
      JournalEntry.Branch,

      cast(
        case length( JournalEntry.DocumentReferenceID )
          when 13
            then substring( JournalEntry.DocumentReferenceID,1,4 )
          when 14
            then substring( JournalEntry.DocumentReferenceID,1,5 )
        end as fiar_branch preserving type
      )                                                                      as AR_Branch,

      case length( JournalEntry.DocumentReferenceID )
        when 13
          then substring( JournalEntry.DocumentReferenceID,1,4 )
        when 14
          then substring( JournalEntry.DocumentReferenceID,2,4 )
      end                                                                    as AR_Branch4Digits,

      cast(
        case length( JournalEntry.DocumentReferenceID )
          when 13
            then substring( JournalEntry.DocumentReferenceID,5,1 )
          when 14
            then substring( JournalEntry.DocumentReferenceID,6,1 )
          else ''
        end as j_1apchar preserving type
      )                                                                      as AR_PrintCharacter,

      cast(
        case length( JournalEntry.DocumentReferenceID )
          when 13
            then substring( JournalEntry.DocumentReferenceID,6,8 )
          when 14
            then substring( JournalEntry.DocumentReferenceID,7,8 )
        end as fiar_odn
      )                                                                      as AR_OfficialDocumentNumber,

      cast(
        case
          when JournalEntry.NmbrOfPages = '000' or JournalEntry.NmbrOfPages = ''
            then '001'
          else JournalEntry.NmbrOfPages
        end as j_1anopg
      )                                                                      as NmbrOfPages,

      JournalEntry.AccountingDocumentHeaderText,
      JournalEntry.IsReversal,
      JournalEntry.IsReversed,
      JournalEntry.ReverseDocument,
      JournalEntry.ReverseDocumentFiscalYear,
      JournalEntry.ReversalReferenceDocument,
      JournalEntry.OriginalReferenceDocument,
      JournalEntry.ReferenceDocumentType,

      cast(
        case
          when JournalEntry.ReferenceDocumentType = 'VBRK' or JournalEntry.ReferenceDocumentType = 'CF3PS'
            then 'X'
          else ''
        end as flag
      )                                                                      as IsDocumentFromSD,

      JournalEntry.ReferenceDocumentLogicalSystem,
      JournalEntry.ExchangeRateDate,

      cast(
        case
          when JournalEntry.TransactionCurrency <> JournalEntry.CompanyCodeCurrency
             then JournalEntry.AbsoluteExchangeRate * _ConversionFactor.NumberOfTargetCurrencyUnits
          else JournalEntry.AbsoluteExchangeRate
        end as fis_exchange_rate
      )                                                                      as ExchangeRate,

      JournalEntry.LogicalSystem,
      JournalEntry.CompanyCodeCurrency,
      cast( JournalEntry.TransactionCurrency  as fis_rwcur preserving type ) as TransactionCurrency,
      JournalEntry.AdditionalCurrency1,
      JournalEntry.AdditionalCurrency2,

      _CompanyCode,
      _OneTimeAccountBP,
      _AccountingDocumentTypeText,
      _ConversionFactor
}