P_APProcFlowPurOrdHistQty

DDL: P_APPROCFLOWPURORDHISTQTY Type: view_entity COMPOSITE Package: ODATA_PROCESS_FLOW_AP

Purchase Order History - Quantity

P_APProcFlowPurOrdHistQty is a Composite CDS View that provides data about "Purchase Order History - Quantity" in SAP S/4HANA. It reads from 2 data sources (I_PurchaseOrder, I_PurchasingDocumentHistoryBsc) and exposes 11 fields with key fields PurchaseOrder, PurchaseOrderItem, PurchaseOrderTransactionType, MaterialDocumentYear, MaterialDocument. It has 1 association to related views. Part of development package ODATA_PROCESS_FLOW_AP.

2 data source(s) 11 fields

Data Sources (2)

SourceAliasJoin Type
I_PurchaseOrder _PurchaseOrder inner
I_PurchasingDocumentHistoryBsc PurchaseOrderHistory from

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_PurchaseOrderItem _PurchaseOrderItem $projection.PurchaseOrder = _PurchaseOrderItem.PurchaseOrder and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem

Annotations (6)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #COMPOSITE view
VDM.private true view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY PurchaseOrder
KEY PurchaseOrderItem
KEY PurchaseOrderTransactionType I_PurchasingDocumentHistoryBsc PurchasingHistoryDocumentType
KEY MaterialDocumentYear I_PurchasingDocumentHistoryBsc PurchasingHistoryDocumentYear
KEY MaterialDocument I_PurchasingDocumentHistoryBsc PurchasingHistoryDocument
KEY MaterialDocumentItem I_PurchasingDocumentHistoryBsc PurchasingHistoryDocumentItem
DebitCreditCode I_PurchasingDocumentHistoryBsc DebitCreditCode
Quantity
PurchaseOrderQuantityUnit _PurchaseOrderItem PurchaseOrderQuantityUnit
_PurchaseOrderItem _PurchaseOrderItem
AuthorizationGroup 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType:{
    serviceQuality: #B,
    sizeCategory: #XXL,
    dataClass: #TRANSACTIONAL
}
@VDM: {
  viewType: #COMPOSITE,
  private:true
}
@Consumption.dbHints:['USE_HEX_PLAN', 'NO_SUBPLAN_SHARING']
define view entity P_APProcFlowPurOrdHistQty
  as select from I_PurchasingDocumentHistoryBsc as PurchaseOrderHistory
    inner join   I_PurchaseOrder                as _PurchaseOrder on PurchaseOrderHistory.PurchasingDocument = _PurchaseOrder.PurchaseOrder

  association [1..1] to I_PurchaseOrderItem as _PurchaseOrderItem on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                  and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
{
  key cast( PurchaseOrderHistory.PurchasingDocument as vdm_purchaseorder preserving type )         as PurchaseOrder,
  key cast( PurchaseOrderHistory.PurchasingDocumentItem as vdm_purchaseorderitem preserving type ) as PurchaseOrderItem,
  key PurchaseOrderHistory.PurchasingHistoryDocumentType                                           as PurchaseOrderTransactionType,
  key PurchaseOrderHistory.PurchasingHistoryDocumentYear                                           as MaterialDocumentYear,
  key PurchaseOrderHistory.PurchasingHistoryDocument                                               as MaterialDocument,
  key PurchaseOrderHistory.PurchasingHistoryDocumentItem                                           as MaterialDocumentItem,
      PurchaseOrderHistory.DebitCreditCode,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      sum( PurchaseOrderHistory.Quantity )                                                         as Quantity,
      _PurchaseOrderItem.PurchaseOrderQuantityUnit                                                 as PurchaseOrderQuantityUnit,

      @Consumption.hidden: true
      _PurchaseOrderItem,
      @Consumption.hidden: true
      _PurchaseOrder._Supplier.AuthorizationGroup //GDPR Supplier Authorization

}
where
  _PurchaseOrderItem.PurchaseOrderCategory = 'F'
group by

  PurchaseOrderHistory.PurchasingDocument,
  PurchaseOrderHistory.PurchasingDocumentItem,
  PurchaseOrderHistory.PurchasingHistoryDocumentType,
  PurchaseOrderHistory.PurchasingHistoryDocumentYear,
  PurchaseOrderHistory.PurchasingHistoryDocument,
  PurchaseOrderHistory.PurchasingHistoryDocumentItem,
  PurchaseOrderHistory.DebitCreditCode,
  _PurchaseOrderItem.PurchaseOrderQuantityUnit,
  _PurchaseOrder._Supplier.AuthorizationGroup

Learn More