I_WorkforcePersonDet

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.sqlViewName: 'IWRKFRCPERSNDET'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@EndUserText.label: 'Retrive Workforce Person Details'
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_User' ] 
@AbapCatalog.preserveKey:true
@Metadata.ignorePropagatedAnnotations: true

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view I_WorkforcePersonDet
  as select from I_WorkforcePerson
  association [1..1] to I_BusinessPartner         as _BusinessPartner            on $projection.Person = _BusinessPartner.BusinessPartner
  association [0..*] to I_ServicePerformerToSuplr as _ServicePerformerToSupplier on $projection.Person = _ServicePerformerToSupplier.Person
  association [1..*] to I_PersonWorkAgreement_1   as _PersonWorkAgreement        on $projection.Person = _PersonWorkAgreement.Person
  association [0..1] to I_WorkplaceAddress        as _WorkplaceAddress           on $projection.BusinessPartnerUUID = _WorkplaceAddress.BusinessPartnerUUID
  association [0..*] to I_BusinessPartnerToBPRole as _BusinessPartnerToBPRole  on $projection.Person                          = _BusinessPartnerToBPRole.BusinessPartner
                                                                                 and(
                                                                                   _BusinessPartnerToBPRole.BusinessPartnerRole = 'BUP003'
                                                                                   or // BUP003 - Employee

                                                                                   _BusinessPartnerToBPRole.BusinessPartnerRole = 'BBP005'
                                                                                   or // BBP005 - Service Agent

                                                                                   _BusinessPartnerToBPRole.BusinessPartnerRole = 'BBP010'
                                                                                 )    // BBP010 - Freelancer  )

                                                                                 
  association [0..*] to I_BusinessPartnerToBPRole_2 as _BusinessPartnerToBPRole_2  on $projection.Person                          = _BusinessPartnerToBPRole_2.BusinessPartner
                                                                                 and(
                                                                                   _BusinessPartnerToBPRole_2.BusinessPartnerRole = 'BUP003'
                                                                                   or // BUP003 - Employee

                                                                                   _BusinessPartnerToBPRole_2.BusinessPartnerRole = 'BBP005'
                                                                                   or // BBP005 - Service Agent

                                                                                   _BusinessPartnerToBPRole_2.BusinessPartnerRole = 'BBP010'
                                                                                 )    // BBP010 - Freelancer  )

  association [1]    to I_User                    as _User                       on $projection.BusinessPartnerUUID = _User.BusinessPartnerUUID
{
  key Person,
      PersonExternalID,
      FirstName,
      LastName,
      MiddleName,
      AdditionalLastName,
      PersonFullName,
      BusinessPartnerUUID,
      AuthorizationGroup,
      @Semantics.booleanIndicator:true
      IsBusinessPurposeCompleted,
      
      _User.UserID,
      _BusinessPartner,
      _ServicePerformerToSupplier,
      _PersonWorkAgreement,
      _WorkplaceAddress,

       @VDM.lifecycle: {
         successor: '_BusinessPartnerToBPRole_2',
         status: #DEPRECATED
       }
      _BusinessPartnerToBPRole,
      _BusinessPartnerToBPRole_2,
      
      @Consumption.hidden: true
       _User
         
}