I_BusinessPartnerToBPRole_2

@AbapCatalog.sqlViewName: 'IBPTOBPROLE2' //must start with "I"


@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: '_BusinessPartner.IsBusinessPurposeCompleted'
@AccessControl.privilegedAssociations:  [ '_BusinessPartnerDiffValue' ]

@Analytics: {
    dataCategory: #DIMENSION,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
            mapping:[
                
                {
                    table: 'but100', role: #MAIN,
                    viewElement: ['BusinessPartner' ,'BusinessPartnerRole','BusinessPartnerDiffTypeValue'],
                    tableElement: ['partner', 'rltyp' ,'dfval']
                   
                },
               
                {
                    table: 'but000', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['BusinessPartner'],
                    tableElement: ['partner']
                }                              
            ]
        }
    }
 } 
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Business Partner assignment to BP Role' //same as DDL description


@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #CDS_MODELING_ASSOCIATION_TARGET,
                                     #ANALYTICAL_DIMENSION,
                                     #EXTRACTION_DATA_SOURCE]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION    
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.representativeKey:'BusinessPartnerRole'

@VDM.viewType: #BASIC
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BusinessPartnerToBPRole_2 
  as select from but100

  association [0..1] to I_BusinessPartnerRole as _BusinessPartnerRole on $projection.BusinessPartnerRole = _BusinessPartnerRole.BusinessPartnerRole
  association [0..1] to I_BusinessPartner     as _BusinessPartner     on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_BPDifferentiationTypeValue as _BusinessPartnerDiffValue on $projection.BusinessPartnerDiffTypeValue = _BusinessPartnerDiffValue.BusinessPartnerDiffTypeValue 
{
   @Consumption.hidden: true
   but100.mandt as mandt,
      //--[ GENERATED:012:GlBfhyJl7kY4i6}7dD1KRG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_BusinessPartnerVH',
                     element: 'BusinessPartner' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_BusinessPartner'
  key but100.partner     as BusinessPartner,
      // @ObjectModel.text.association: '_BusinessPartnerRoleText'

  key but100.rltyp       as BusinessPartnerRole,
     @ObjectModel.foreignKey.association: '_BusinessPartnerDiffValue'
  key but100.dfval       as BusinessPartnerDiffTypeValue,
      but100.valid_from  as ValidFrom,
      but100.valid_to    as ValidTo,


      //        Association

      _BusinessPartnerRole,
      _BusinessPartner.AuthorizationGroup,
      _BusinessPartner,
      _BusinessPartnerDiffValue  
}
where
  but100.dfval = ''