I_WorkCenterCapacity_3

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Center Capacity'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #M, dataClass: #MASTER }
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'CapacityInternalID'
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]
@ObjectModel.sapObjectNodeType.name: 'WorkCenterCapacity'
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view entity I_WorkCenterCapacity_3
  as select from I_Capacity           as Cap
  inner join   I_WorkCenterCapacity as CapMap on Cap.CapacityInternalID = CapMap.CapacityInternalID
  
  association [1..1] to I_WorkCenterCapacity as _WorkCenterCapMap on  $projection.WorkCenterInternalID       = _WorkCenterCapMap.WorkCenterInternalID
                                                                  and $projection.WorkCenterTypeCode         = _WorkCenterCapMap.WorkCenterTypeCode
                                                                  and $projection.CapacityCategoryAllocation = _WorkCenterCapMap.CapacityCategoryAllocation
  association [1..*] to I_WorkCenterCapacityText_2 as _Text on  $projection.WorkCenterInternalID             = _Text.WorkCenterInternalID
                                                                  and $projection.WorkCenterTypeCode         = _Text.WorkCenterTypeCode
                                                                  and $projection.CapacityCategoryAllocation = _Text.CapacityCategoryAllocation
                                                                  and $projection.CapacityInternalID         = _Text.CapacityInternalID

{
      @ObjectModel.foreignKey.association: '_WorkCenter'
  key CapMap.WorkCenterInternalID       as WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_WorkCenterTypeCode'
  key CapMap.WorkCenterTypeCode         as WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_WorkCenterCapMap'
  key CapMap.CapacityCategoryAllocation as CapacityCategoryAllocation,
  key Cap.CapacityInternalID             as CapacityInternalID,

      // Capacity Alloc Attributes

      CapMap.LastChangeDate,
      CapMap.LastChangedByUser,
      CapMap.WorkCenter,
      CapMap.WorkCenterCategoryCode,
      CapMap.SetupCapRequirementFormula,
      CapMap.ProcgCapRequirementFormula,
      CapMap.TeardownCapRequirementFormula,
      CapMap.OtherCapRequirementFormula,
      CapMap.ValidityStartDate,
      CapMap.ValidityEndDate,
      CapMap.WorkCenterLastChangeDateTime,

      // Capacity Attributes

      Cap.Capacity,
      Cap.CapacityCategoryCode,
      Cap.CapacityActiveVersion,
      Cap.CapacityIsFinite,
      Cap.CapacityIsPooled,
      Cap.CapacityHasIndivCapacities,
      Cap.CapacityIsExcldFrmLongTermPlng,
      Cap.CapacityNumberOfCapacities,
      Cap.CapacityResponsiblePlanner,
      Cap.CapacityPlanUtilizationPercent,
      Cap.CapacityBreakDuration,

      // Assignments

      Cap.Plant,
      Cap.FactoryCalendar,
      Cap.AuthorizationGroup,
      Cap.ShiftGroup,

      // Times


      @Semantics.durationInHours:true
      Cap.CapacityStartTimeID,
      @Semantics.durationInHours:true
      Cap.CapacityEndTimeID,

      Cap.CapIsUsedInMultiOperations,
      Cap.ReferencedCapacityInternalID,
      Cap.CapOverloadThresholdInPercent,

      // Unit of Measures

      Cap.CapacityQuantityUnit,
      Cap.CapacityBaseQtyUnit,
      Cap.CapacityLastChangeDateTime,

      // Associations

      CapMap._WorkCenter,
      CapMap._WorkCenterTypeCode,
      _WorkCenterCapMap,
      _Text

}
where
      Cap.CapacityIsPooled is initial
  and Cap.Capacity         is initial