I_WorkCenterCapacityText_2

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Center Capacity - Text'
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER }
@ObjectModel.dataCategory:  #TEXT
@VDM.viewType: #BASIC
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
//@Metadata.allowExtensions: true

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'CapacityInternalID'
@ObjectModel.supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]
@ObjectModel.sapObjectNodeType.name: 'WorkCenterCapacityText'
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT

define view entity I_WorkCenterCapacityText_2
  as select from I_CapacityText as CapText
   inner join   I_Capacity     as Capacity on Capacity.CapacityInternalID = CapText.CapacityInternalID
    inner join   crca          as CapMap   on Capacity.CapacityInternalID = CapMap.kapid
  
  association [1..1] to I_WorkCenter         as _WorkCenter         on  $projection.WorkCenterTypeCode   = _WorkCenter.WorkCenterTypeCode
                                                                    and $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
  association [1..1] to I_WorkCenterType     as _WorkCenterTypeCode on  $projection.WorkCenterTypeCode = _WorkCenterTypeCode.WorkCenterTypeCode

  association [1..1] to I_WorkCenterCapacity as _WorkCenterCapMap   on  $projection.WorkCenterInternalID       = _WorkCenterCapMap.WorkCenterInternalID
                                                                    and $projection.WorkCenterTypeCode         = _WorkCenterCapMap.WorkCenterTypeCode
                                                                    and $projection.CapacityCategoryAllocation = _WorkCenterCapMap.CapacityCategoryAllocation
{
      @ObjectModel.foreignKey.association: '_WorkCenter'
  key CapMap.objid                                        as WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_WorkCenterTypeCode'
  key CapMap.objty                                        as WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_WorkCenterCapMap'
  key cast(CapMap.canum as pph_cr_capnum preserving type) as CapacityCategoryAllocation,
  key CapText.CapacityInternalID                          as CapacityInternalID,
      @ObjectModel.foreignKey.association: '_Language'
  key CapText.Language,

      @Semantics.text: true
      CapText.CapacityText,

      case when Capacity.CapacityLastChangeDateTime is null then
        cast('20190101120000' as kap_lastchange_datetime)
        else Capacity.CapacityLastChangeDateTime end      as CapacityLastChangeDateTime,

      //Associations

      _WorkCenter,
      _WorkCenterTypeCode,
      _WorkCenterCapMap,
      CapText._Language

}
where
      Capacity.CapacityIsPooled is initial
  and Capacity.Capacity         is initial