I_VATTaxCodeVH

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'VAT Tax Code'
@ObjectModel: { dataCategory: #VALUE_HELP,
                representativeKey: 'TaxCode',
                usageType: { sizeCategory: #S,
                             dataClass: #CUSTOMIZING,
                             serviceQuality: #A },
                supportedCapabilities: [#VALUE_HELP_PROVIDER],
                modelingPattern: #VALUE_HELP_PROVIDER }

@Metadata.ignorePropagatedAnnotations: true 
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Search.searchable: true

define view entity I_VATTaxCodeVH 
  as select from I_TaxCode 
  
  association [0..*] to I_TaxCodeText             as _Text                    on  $projection.TaxCalculationProcedure = _Text.TaxCalculationProcedure
                                                                              and $projection.TaxCode                 = _Text.TaxCode

  association [0..1] to I_TaxType                 as _TaxType                 on  $projection.TaxType = _TaxType.TaxType

  association [0..1] to I_TaxCalculationProcedure as _TaxCalculationProcedure on  $projection.TaxCalculationProcedure = _TaxCalculationProcedure.TaxCalculationProcedure
 
  
{  
      @ObjectModel.foreignKey.association: '_TaxCalculationProcedure'
  key I_TaxCode.TaxCalculationProcedure,                                              
      @ObjectModel.text.association: '_Text'
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
  key I_TaxCode.TaxCode,
      @ObjectModel.foreignKey.association: '_TaxType'
      I_TaxCode.TaxType,
      I_TaxCode.TargetTaxCode,
      I_TaxCode.EUTaxClassification,
      I_TaxCode.IsSalesTaxes,
      I_TaxCode.UnitedStatesTaxCategory,
      I_TaxCode.TaxReturnCountry,
      I_TaxCode.TaxTolerancePercent,
      I_TaxCode.EUAcqnInputTaxCode,
      I_TaxCode.EUAcqnOutputTaxCode,
      I_TaxCode.TaxCodeIsInactive,
      I_TaxCode.OneStopShopTaxReportingCountry,
      I_TaxCode.OneStopShopScheme,

      _TaxCalculationProcedure,
      _TaxType,
      _Text
}