I_UnpackagedDangerousGoodReld

@AbapCatalog.sqlViewName: 'IUPDGRELD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Composite View for UPs released CRR'

@ClientHandling:
{
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}

@VDM.viewType: #COMPOSITE

@ObjectModel:
{
  usageType:
    {
      dataClass: #MIXED,
      sizeCategory: #L,
      serviceQuality: #C
    }
}

define view I_UnpackagedDangerousGoodReld
  --Select data from master table 'Chemical Compliance Info'
  as select from           I_ChmlCmplncInfo       as ChemicalComplianceInfo

  --Join data from primary material assignment
    left outer to one join I_ChmlCmplncMatlAssgmt as PrimaryMaterial on ChemicalComplianceInfo.ChmlCmplncInfoUUID = PrimaryMaterial.ChmlCmplncInfoUUID
                                                                  and MatlAssgmtIsPrimary = 'X'

  --Join data from product name in current language to define Combined Name
    left outer to one join I_ProductText                as ProductText on  PrimaryMaterial.Material = ProductText.Product
                                                                    and Language             = $session.system_language

    left outer to one join P_BasicDescForReldRegulation as BasicDescForReldRegulation on ChemicalComplianceInfo.ChmlCmplncInfoUUID = BasicDescForReldRegulation.ChmlCmplncInfoUUID
                                                                                         
  association [0..1] to P_ReleasedCRRForUnpckgdDGCount as _RelCRRCount on $projection.ChmlCmplncInfoUUID = _RelCRRCount.ChmlCmplncInfoUUID

{
      @ObjectModel.text.element: ['ChmlCmplncInfoCombinedName']
  key ChemicalComplianceInfo.ChmlCmplncInfoUUID,
      //@ObjectModel.text.element: ['ChmlCmplncInfoCombinedName']

      cast (Material as productnumber preserving type ) as Product,

      ProductName,
      
      ChmlCmplncInternalName,
      
      @Semantics.text: true
      cast( coalesce( ProductText.ProductName, ChemicalComplianceInfo.ChmlCmplncInternalName ) as ehfnd_cci_product_name ) as ChmlCmplncInfoCombinedName,
      
      BasicDescForReldRegulation.DangerousGoodBasicDescription,
      
      // only needed for DCL

      DngrsGdsRespUnit,
      _RespUnitForDangerousGoods      

}
where
      ChmlCmplncInfoType             = 'BU'
  and MaterialIsTransported          = 'X'
  and _RelCRRCount.NmbrOfCmplRqRslts > 0;