I_TransportationOrderBlock

@EndUserText:   {label:              'Transportation Order: Blocks'}
@ObjectModel:   {representativeKey:  'TransportationOrderBlockUUID',
                 usageType:          {serviceQuality: #B,
                                      sizeCategory:   #XXL,
                                      dataClass:      #TRANSACTIONAL}}
@VDM:           {viewType:           #BASIC}
@AbapCatalog:   {compiler:           {compareFilter: true},
                 preserveKey:         true,
                 sqlViewName:        'ITORBLOCK',
                 buffering:          {status: #NOT_ALLOWED}}
@AccessControl: {authorizationCheck: #PRIVILEGED_ONLY}
@ClientHandling.algorithm:           #SESSION_VARIABLE

define view I_TransportationOrderBlock
  as select from /scmtms/d_torblk
  /* Business Object related Node Associations */
  association [1..1] to I_TransportationOrder         as _TransportationOrder         on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
  association [0..1] to I_TransportationOrderStage    as _TransportationOrderStage    on $projection.TranspOrdBlockedNodeUUID = _TransportationOrderStage.TransportationOrderStageUUID
  /* Foreign Key and Text Associations */
  association [0..1] to I_TranspOrdBlockIsOverruled   as _TranspOrdBlockIsOverruled   on $projection.TranspOrdBlockIsOverruled = _TranspOrdBlockIsOverruled.TranspOrdBlockIsOverruled
  association [0..1] to I_BlockReasonCode             as _BlockReason                 on $projection.BlockReason = _BlockReason.BlockReason
  association [0..1] to I_TranspOrdPlanningBlock      as _TranspOrdPlanningBlock      on $projection.TranspOrdPlanningBlock = _TranspOrdPlanningBlock.TranspOrdPlanningBlock
  association [0..1] to I_TranspOrdExecutionIsBlocked as _TranspOrdExecutionIsBlocked on $projection.TranspOrdExecutionIsBlocked = _TranspOrdExecutionIsBlocked.TranspOrdExecutionIsBlocked
  association [0..1] to I_InvoicingIsBlocked          as _InvoicingIsBlocked          on $projection.InvoicingIsBlocked = _InvoicingIsBlocked.InvoicingIsBlocked
  association [0..1] to I_BlockCategory               as _BlockCategory               on $projection.BlockCategory = _BlockCategory.BlockCategory
{
  key cast(node_key as /scmtms/vdm_tor_block_nodekey preserving type )   as TranspOrderBlockNodeKeyUUID,
  key cast(db_key as /scmtms/vdm_tor_block_db_key preserving type)       as TransportationOrderBlockUUID,
      @ObjectModel.foreignKey.association: '_TransportationOrder'
      cast(root_key as /scmtms/vdm_tor_db_key preserving type)           as TransportationOrderUUID,
      cast(parent_key as /scmtms/vdm_tor_blknode_db_key preserving type) as TranspOrdBlockedNodeUUID,
      @ObjectModel.foreignKey.association: '_BlockReason'
      block_rc                                                           as BlockReason,
      @ObjectModel.foreignKey.association: '_TranspOrdBlockIsOverruled'
      overruled                                                          as TranspOrdBlockIsOverruled,
      @ObjectModel.foreignKey.association: '_TranspOrdPlanningBlock'
      blk_plan                                                           as TranspOrdPlanningBlock,
      @ObjectModel.foreignKey.association: '_TranspOrdExecutionIsBlocked'
      blk_exec                                                           as TranspOrdExecutionIsBlocked,
      @ObjectModel.foreignKey.association: '_InvoicingIsBlocked'
      blk_invo                                                           as InvoicingIsBlocked,
      @ObjectModel.foreignKey.association: '_BlockCategory'
      block_cat                                                          as BlockCategory,

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _TransportationOrder,
      _TransportationOrderStage,
      _TranspOrdBlockIsOverruled,
      _BlockReason,
      _TranspOrdPlanningBlock,
      _TranspOrdExecutionIsBlocked,
      _InvoicingIsBlocked,
      _BlockCategory
}