I_TransportationOrder

@EndUserText:   {   label:              'Transportation Orders'}
@ObjectModel:   {   //modelCategory:      #BUSINESS_OBJECT,

                    representativeKey:  'TransportationOrderUUID',
                    semanticKey:        [ 'TransportationOrder' ],
                    usageType:          { serviceQuality: #B,
                                          sizeCategory:   #XL,
                                          dataClass:      #TRANSACTIONAL},
                    compositionRoot:    true}
@VDM:           {   viewType:           #BASIC}
@AccessControl: {   authorizationCheck: #MANDATORY,
                    personalData.blocking:#('TRANSACTIONAL_DATA'),
                    privilegedAssociations:  [  '_CreatedBy', '_LastChangedBy', '_TranspOrdResponsiblePerson',
                                                '_TransportationOrderItem',
                                                '_TransportationOrderStop',
                                                '_TransportationOrderStage',
                                                '_TranspOrdExecution',
                                                '_TransportationOrderBlock',
                                                '_Tendering',
                                                '_DocRef',
                                                '_SourceStop',
                                                '_DestinationStop',
                                                '_TranspChargeItem',
                                                '_TranspOrdSummary',
                                                '_TranspOrdErrHndlg']}

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define root view entity I_TransportationOrder
  as select from /scmtms/d_torrot as root
  /* Business Object related Node Associations*/
  association [0..*] to I_TransportationOrderItem     as _TransportationOrderItem      on  $projection.TransportationOrderUUID = _TransportationOrderItem.TransportationOrderUUID
  association [0..*] to I_TransportationOrderStop     as _TransportationOrderStop      on  $projection.TransportationOrderUUID = _TransportationOrderStop.TransportationOrderUUID
  association [0..*] to I_TransportationOrderStage    as _TransportationOrderStage     on  $projection.TransportationOrderUUID = _TransportationOrderStage.TransportationOrderUUID
  association [0..*] to I_TranspOrdExecution          as _TranspOrdExecution           on  $projection.TransportationOrderUUID = _TranspOrdExecution.TransportationOrderUUID
  association [0..*] to I_TransportationOrderBlock    as _TransportationOrderBlock     on  $projection.TransportationOrderUUID = _TransportationOrderBlock.TransportationOrderUUID
  association [0..*] to I_Tendering                   as _Tendering                    on  $projection.TransportationOrderUUID = _Tendering.TransportationOrderUUID
  association [0..*] to I_TranspOrdDocRef             as _DocRef                       on  $projection.TransportationOrderUUID = _DocRef.TransportationOrderUUID
  association [0..1] to I_TransportationOrderStop     as _SourceStop                   on  $projection.TransportationOrderUUID       = _SourceStop.TransportationOrderUUID
                                                                                       and _SourceStop.TranspOrdStopSequencePosition = 'F' /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_TransportationOrderStop     as _DestinationStop              on  $projection.TransportationOrderUUID            = _DestinationStop.TransportationOrderUUID
                                                                                       and _DestinationStop.TranspOrdStopSequencePosition = 'L' /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
  association [0..*] to I_TranspChargeItem            as _TranspChargeItem             on  $projection.TransportationOrderUUID = _TranspChargeItem.RefTransportationOrderUUID
  association [0..1] to I_BusinessPartner             as _Consignee                    on  $projection.Consignee = _Consignee.BusinessPartner
  association [0..1] to I_BusinessPartner             as _Shipper                      on  $projection.Shipper = _Shipper.BusinessPartner
  association [0..1] to I_BusinessPartner             as _Carrier                      on  $projection.Carrier = _Carrier.BusinessPartner
  association [0..1] to I_BusinessPartner             as _ExectgCarrier                on  $projection.TranspOrdExecutingCarrier = _ExectgCarrier.BusinessPartner
  association [0..1] to I_TranspOrganizationalUnit    as _PurchasingOrganization       on  $projection.PurchasingOrganization = _PurchasingOrganization.OrganizationalUnit
  association [0..1] to I_TranspOrganizationalUnit    as _PurchasingGroup              on  $projection.PurchasingGroup = _PurchasingGroup.OrganizationalUnit
  association [0..1] to I_TranspOrganizationalUnit    as _PlngAndExecOrganization      on  $projection.PlngAndExecOrganization = _PlngAndExecOrganization.OrganizationalUnit
  association [0..1] to I_TranspOrganizationalUnit    as _PlngAndExecGroup             on  $projection.PlngAndExecGroup = _PlngAndExecGroup.OrganizationalUnit
  association [0..1] to I_CompanyCode                 as _PurchasingCompanyCode        on  $projection.PurgOrgCompanyCode = _PurchasingCompanyCode.CompanyCode

  /* Foreign Key and Text Associations */
  association [0..1] to I_TransportationOrderType_2   as _TransportationOrderType      on  $projection.TransportationOrderType = _TransportationOrderType.TransportationOrderType
  association [0..1] to I_TranspOrderCategory_2       as _TransportationOrderCategory  on  $projection.TransportationOrderCategory = _TransportationOrderCategory.TransportationOrderCategory
  association [0..1] to I_TranspOrdPlanningBlock      as _TranspOrdPlanningBlock       on  $projection.TranspOrdPlanningBlock = _TranspOrdPlanningBlock.TranspOrdPlanningBlock
  association [0..1] to I_TranspOrdExecutionIsBlocked as _TranspOrdExecutionIsBlocked  on  $projection.TranspOrdExecutionIsBlocked = _TranspOrdExecutionIsBlocked.TranspOrdExecutionIsBlocked
  association [0..1] to I_InvoicingIsBlocked          as _InvoicingIsBlocked           on  $projection.InvoicingIsBlocked = _InvoicingIsBlocked.InvoicingIsBlocked
  association [0..1] to I_TranspSCACCode              as _TranspSCACCode               on  $projection.StandardCarrierAlphaCode = _TranspSCACCode.TranspSCACCode
  association [0..1] to I_TranspAirlineIATACode       as _TranspAirlineIATACode        on  $projection.TranspOrdAirlineIATACode = _TranspAirlineIATACode.TranspAirlineIATACode
  association [0..1] to I_CarrierOriginOfEntry        as _CarrierOriginOfEntry         on  $projection.CarrierOriginOfEntry = _CarrierOriginOfEntry.CarrierOriginOfEntry
  association [0..1] to I_TranspOrdShippingType       as _TranspOrdShippingType        on  $projection.TranspOrdShippingType = _TranspOrdShippingType.TranspOrdShippingType
  association [0..1] to I_TranspMovementType          as _MovementType                 on  $projection.MovementType = _MovementType.MovementType
  association [0..1] to I_TranspOrdLifeCycleStatus    as _TranspOrdLifeCycleStatus     on  $projection.TranspOrdLifeCycleStatus = _TranspOrdLifeCycleStatus.TranspOrdLifeCycleStatus
  association [0..1] to I_TranspOrdPlanningStatus_2   as _TranspOrdPlanningStatus      on  $projection.TranspOrdPlanningStatus = _TranspOrdPlanningStatus.TranspOrdPlanningStatus
  association [0..1] to I_TransportationOrderExecSts  as _TransportationOrderExecSts   on  $projection.TransportationOrderExecSts = _TransportationOrderExecSts.TransportationOrderExecSts
  association [0..1] to I_TranspOrdDngrsGdsStatus     as _TranspOrdDngrsGdsStatus      on  $projection.TranspOrderDngrsGdsSts = _TranspOrdDngrsGdsStatus.TranspOrderDngrsGdsSts
  association [0..1] to I_TranspOrdConfirmationStatus as _TranspOrdConfirmationStatus  on  $projection.TransportationOrderConfSts = _TranspOrdConfirmationStatus.TransportationOrderConfSts
  association [1..1] to I_TranspOrdSubcontractingSts  as _TranspOrdSubcontractingSts   on  $projection.TranspOrderSubcontrgSts = _TranspOrdSubcontractingSts.TranspOrderSubcontrgSts
  association [1..1] to I_TranspOrdWhseProcgStatus    as _TranspOrdWhseProcgStatus     on  $projection.TranspOrdWhseProcessingStatus = _TranspOrdWhseProcgStatus.TranspOrdWhseProcessingStatus
  association [1..1] to I_TranspOrdGoodsMvtStatus     as _TranspOrdGoodsMvtStatus      on  $projection.TranspOrdGoodsMovementStatus = _TranspOrdGoodsMvtStatus.TranspOrdGoodsMovementStatus
  association [0..1] to I_TranspOrdTrafficDirection   as _TranspOrdTrafficDirection    on  $projection.TranspOrdTrafficDirection = _TranspOrdTrafficDirection.TranspOrdTrafficDirection
  association [0..1] to I_MeansOfTransport            as _MeansOfTransport             on  $projection.MeansOfTransport = _MeansOfTransport.MeansOfTransport
  association [0..1] to I_TransportationMode_2        as _TransportationMode           on  $projection.TransportationMode = _TransportationMode.TransportationMode
  association [0..1] to I_TransportationModeCategory  as _TransportationModeCategory   on  $projection.TransportationModeCategory = _TransportationModeCategory.TransportationModeCategory
  association [0..1] to I_FrtDsputCaseStatus          as _FrtDsputCaseStatus           on  $projection.FrtDsputCaseStatus = _FrtDsputCaseStatus.FrtDsputCaseStatus
  association [1..1] to I_User                        as _CreatedBy                    on  $projection.CreatedByUser = _CreatedBy.UserID
  association [0..1] to I_User                        as _LastChangedBy                on  $projection.LastChangedByUser = _LastChangedBy.UserID
  association [0..1] to I_User                        as _TranspOrdResponsiblePerson   on  $projection.TranspOrdResponsiblePerson = _TranspOrdResponsiblePerson.UserID
  association [0..1] to I_UnitOfMeasure               as _TranspOrdGrossWeightUnit     on  $projection.TranspOrdGrossWeightUnit     = _TranspOrdGrossWeightUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdGrossVolumeUnit     on  $projection.TranspOrdGrossVolumeUnit     = _TranspOrdGrossVolumeUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdNetWeightUnit       on  $projection.TranspOrdNetWeightUnit       = _TranspOrdNetWeightUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdQuantityUnit        on  $projection.TranspOrdQuantityUnit        = _TranspOrdQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdAlternativeQtyUnit  on  $projection.TranspOrdAlternativeQtyUnit  = _TranspOrdAlternativeQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdBaseQuantityUnit    on  $projection.TranspOrdBaseQuantityUnit    = _TranspOrdBaseQuantityUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdTareWeightUnit      on  $projection.TranspOrdTareWeightUnit      = _TranspOrdTareWeightUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdNumberOfCtnsUnit    on  $projection.TranspOrdNumberOfCtnsUnit    = _TranspOrdNumberOfCtnsUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdDngrsGdsExmpPtsUnit on  $projection.TranspOrdDngrsGdsExmpPtsUnit = _TranspOrdDngrsGdsExmpPtsUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdPalletSpacesUnit    on  $projection.TranspOrdPalletSpacesUnit    = _TranspOrdPalletSpacesUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _TranspOrdLoadMetersUnit      on  $projection.TranspOrdLoadMetersUnit      = _TranspOrdLoadMetersUnit.UnitOfMeasure
  association [0..1] to I_TransportationOrderSmmry    as _TranspOrdSummary             on  $projection.TransportationOrderUUID = _TranspOrdSummary.TransportationOrderUUID
  association [0..*] to I_TranspOrdErrHndlg           as _TranspOrdErrHndlg            on  $projection.TransportationOrderUUID = _TranspOrdErrHndlg.TransportationOrderUUID

{
  key cast(db_key          as /scmtms/vdm_tor_db_key preserving type)         as TransportationOrderUUID,
      tor_id                                                                  as TransportationOrder,
      @ObjectModel.foreignKey.association: '_TransportationOrderCategory'
      tor_cat                                                                 as TransportationOrderCategory,
      @ObjectModel.foreignKey.association: '_TransportationOrderType'
      tor_type                                                                as TransportationOrderType,
      dgo_indicator                                                           as DangerousGoodsAreContained, //Why no foreign key view + own domain with descriptive texts?

      transsrvlvl_code                                                        as TransportationServiceLevel,
      resp_person                                                             as TranspOrdResponsiblePerson,
      partner_ref_id                                                          as TranspOrdPartnerReference,
      partner_mbl_id                                                          as MasterBillOfLading,
      @ObjectModel.foreignKey.association: '_TranspOrdPlanningBlock'
      blk_plan                                                                as TranspOrdPlanningBlock,
      @ObjectModel.foreignKey.association: '_TranspOrdExecutionIsBlocked'
      blk_exec                                                                as TranspOrdExecutionIsBlocked,
      @ObjectModel.foreignKey.association: '_InvoicingIsBlocked'
      inv_block                                                               as InvoicingIsBlocked,
      cast(tsp             as bu_partner_guid preserving type)                as CarrierUUID,
      @ObjectModel.foreignKey.association: '_Carrier'
      cast(tspid           as /scmtms/pty_carrier preserving type)            as Carrier, //bu_partner

      @ObjectModel.foreignKey.association: '_TranspSCACCode'
      tsp_scac                                                                as StandardCarrierAlphaCode,
      @ObjectModel.foreignKey.association: '_TranspAirlineIATACode'
      tsp_airlc                                                               as TranspOrdAirlineIATACode,
      tsp_airlcawb                                                            as TranspOrdAirWayBill,
      tsp_address_id                                                          as CarrierAddressID,
      @ObjectModel.foreignKey.association: '_CarrierOriginOfEntry'
      tsp_set_by_srvc                                                         as CarrierOriginOfEntry,
      cast(shipper_key     as bu_partner_guid preserving type)                as ShipperUUID,
      @ObjectModel.foreignKey.association: '_Shipper'
      cast(shipperid       as /scmtms/pty_shipper preserving type)            as Shipper,
      sp_address_id                                                           as ShipperAddressID,
      cast(consignee_key   as bu_partner_guid preserving type)                as ConsigneeUUID,
      @ObjectModel.foreignKey.association: '_Consignee'
      cast(consigneeid     as /scmtms/pty_consignee preserving type)          as Consignee,
      cp_address_id                                                           as ConsigneeAddressID,
      @ObjectModel.foreignKey.association: '_TranspOrdShippingType'
      shipping_type                                                           as TranspOrdShippingType,
      @ObjectModel.foreignKey.association: '_MovementType'
      movement_type                                                           as MovementType,
      @ObjectModel.foreignKey.association: '_TranspOrdTrafficDirection'
      traffic_direct                                                          as TranspOrdTrafficDirection,
      @ObjectModel.foreignKey.association: '_PlngAndExecOrganization'
      exec_org_id                                                             as PlngAndExecOrganization,
      @ObjectModel.foreignKey.association: '_PlngAndExecGroup'
      exec_grp_id                                                             as PlngAndExecGroup,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      purch_org_id                                                            as PurchasingOrganization,
      _PurchasingOrganization.OrganizationalUnitExternalID                    as PurchasingOrgExternalID,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      purch_grp_id                                                            as PurchasingGroup,
      _PurchasingGroup.OrganizationalUnitExternalID                           as PurchasingGroupExternalID,
      @ObjectModel.foreignKey.association: '_PurchasingCompanyCode'
      //@Consumption.valueHelpDefinition: [{ entity: {name: 'I_CompanyCodeVH' , element: 'CompanyCode'}}]

      purch_company_code                                                      as PurgOrgCompanyCode,
      
      purch_org                                                               as TranspPurgOrg,
      purch_grp                                                               as TranspPurgGroup,
      
      @ObjectModel.foreignKey.association: '_TranspOrdLifeCycleStatus'
      lifecycle                                                               as TranspOrdLifeCycleStatus,
      @ObjectModel.foreignKey.association: '_TranspOrdPlanningStatus'
      @Consumption.filter : {  selectionType : #RANGE, multipleSelections : false }
      plan_status_root                                                        as TranspOrdPlanningStatus,
      @ObjectModel.foreignKey.association: '_TransportationOrderExecSts'
      execution                                                               as TransportationOrderExecSts,
      @ObjectModel.foreignKey.association: '_TranspOrdDngrsGdsStatus'
      dg_status                                                               as TranspOrderDngrsGdsSts,
      @ObjectModel.foreignKey.association: '_TranspOrdConfirmationStatus'
      confirmation                                                            as TransportationOrderConfSts,
      @ObjectModel.foreignKey.association: '_TranspOrdSubcontractingSts'
      subcontracting                                                          as TranspOrderSubcontrgSts,
      @ObjectModel.foreignKey.association: '_MeansOfTransport'
      mtr                                                                     as MeansOfTransport,
      @ObjectModel.foreignKey.association: '_TransportationMode'
      trmodcod                                                                as TransportationMode,
      @ObjectModel.foreignKey.association: '_TransportationModeCategory'
      trmodcat                                                                as TransportationModeCategory,
      max_util                                                                as TranspOrdMaxUtilznRatio,

      trq_cat                                                                 as TransportationRequestCategory,
      @ObjectModel.foreignKey.association: '_FrtDsputCaseStatus'
      invdisp_resolution                                                      as FrtDsputCaseStatus,
      cast(max_util_mass   as /scmtms/vdm_max_util_mass preserving type)      as TranspOrdMaxUtilznMassRatio,
      cast(max_util_volume as /scmtms/vdm_max_util_volume preserving type)    as TranspOrdMaxUtilznVolumeRatio,
      cast(max_util_length as /scmtms/vdm_max_util_length preserving type)    as TranspOrdMaxUtilznLengthRatio,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdGrossWeightUnit'
      cast(gro_wei_val as /scmtms/vdm_gro_wei_val preserving type )           as TranspOrdGrossWeight,
      @ObjectModel.foreignKey.association: '_TranspOrdGrossWeightUnit'
      gro_wei_uni                                                             as TranspOrdGrossWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdGrossVolumeUnit'
      cast(gro_vol_val as /scmtms/vdm_gro_vol_val preserving type )           as TranspOrdGrossVolume,
      @ObjectModel.foreignKey.association: '_TranspOrdGrossVolumeUnit'
      gro_vol_uni                                                             as TranspOrdGrossVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdNetWeightUnit'
      cast(net_wei_val as /scmtms/vdm_tor_net_wei_val preserving type )       as TranspOrdNetWeight,
      @ObjectModel.foreignKey.association: '_TranspOrdNetWeightUnit'
      net_wei_uni                                                             as TranspOrdNetWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdQuantityUnit'
      cast(qua_pcs_val as /scmtms/vdm_tor_pcs_val preserving type )           as TranspOrdQuantity,
      @ObjectModel.foreignKey.association: '_TranspOrdQuantityUnit'
      qua_pcs_uni                                                             as TranspOrdQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdAlternativeQtyUnit'
      cast(qua_pcs2_val as /scmtms/vdm_qty_alt_val preserving type )          as TranspOrdAlternativeQty,
      @ObjectModel.foreignKey.association: '_TranspOrdAlternativeQtyUnit'
      qua_pcs2_uni                                                            as TranspOrdAlternativeQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdBaseQuantityUnit'
      cast(base_uom_val as /scmtms/vdm_qty_base_val preserving type )         as TranspOrdBaseQuantity,
      @ObjectModel.foreignKey.association: '_TranspOrdBaseQuantityUnit'
      base_uom_uni                                                            as TranspOrdBaseQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdTareWeightUnit'
      cast(pkgun_wei_val as /scmtms/vdm_tor_pack_unl_wei_v preserving type )  as TranspOrdTareWeight,
      @ObjectModel.foreignKey.association: '_TranspOrdTareWeightUnit'
      pkgun_wei_uni                                                           as TranspOrdTareWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdPalletSpacesUnit'
      cast(normloadconsval as /scmtms/vdm_normloadconsval preserving type )         as TranspOrdPalletSpacesQty,
      @ObjectModel.foreignKey.association: '_TranspOrdPalletSpacesUnit'
      normloadconsuom                                                               as TranspOrdPalletSpacesUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdLoadMetersUnit'
      cast(addnormloadconsval as /scmtms/vdm_addnormloadconsval preserving type )   as TranspOrdLoadMetersQty,
      @ObjectModel.foreignKey.association: '_TranspOrdLoadMetersUnit'
      addnormloadconsuom                                                            as TranspOrdLoadMetersUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdNumberOfCtnsUnit'
      cast(cont_cnt_val as /scmtms/vdm_tor_cont_count_val preserving type )   as TranspOrdNumberOfCtns,
      @ObjectModel.foreignKey.association: '_TranspOrdNumberOfCtnsUnit'
      cont_cnt_uni                                                            as TranspOrdNumberOfCtnsUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdDngrsGdsExmpPtsUnit'
      cast(dg_adr_pts_val as /scmtms/vdm_tor_dg_adr_pts_val preserving type ) as TranspOrdDngrsGdsExmpPts,
      @ObjectModel.foreignKey.association: '_TranspOrdDngrsGdsExmpPtsUnit'
      dg_adr_pts_uni                                                          as TranspOrdDngrsGdsExmpPtsUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdDistanceUnit'
      total_distance_km                                                       as TranspOrdDistance,
      cast('KM' as /scmtms/vdm_dsp_length_unit)                               as TranspOrdDistanceUnit,
      cast(total_duration_net as  bapi11201trmdurat)                          as TranspOrdNetDuration,
      cast('H' as /scmtms/vdm_dsp_time_unit)                                  as TranspOrdNetDurationUnit,

      //@Semantics.user.createdBy: true

      created_by                                                              as CreatedByUser,
      cast(created_on      as log_created_on preserving type)                 as CreationDateTime,
      //@Semantics.user.lastChangedBy: true

      changed_by                                                              as LastChangedByUser,
      cast(changed_on      as log_created_on preserving type)                 as ChangedDateTime,
      cast(datetime_chlc   as log_created_on preserving type)                 as TranspOrdLfcycStsChgDteTime,

      cast(order_date      as log_created_on preserving type)                 as TranspOrdOrderDateTime,

      base_btd_id                                                             as BusinessTransactionDocument,
      base_btd_tco                                                            as BusinessTransactionDocType,

      @ObjectModel.foreignKey.association: '_TranspOrdGoodsMvtStatus'
      dlv_goods_mvmnt                                                         as TranspOrdGoodsMovementStatus,
      @ObjectModel.foreignKey.association: '_TranspOrdWhseProcgStatus'
      wh_processing_status                                                    as TranspOrdWhseProcessingStatus,

      multi_exe_pty                                                           as TranspOrdHasMltplExectgPties,
      pymt_ind                                                                as TranspOrdInvoicingCarrierLevel,
      eikto                                                                   as TransOrdAcctNmbrWthExectgCarr,

      cast(tspexec_key as /scmtms/vdm_tspexec_uuid preserving type)           as TranspOrdExecutingCarrierUUID,
      tspexecid                                                               as TranspOrdExecutingCarrier,
      tspexec_address_id                                                      as ExecutingCarrierAddressID,

      creation_type                                                           as TransportationOrderCrtnType,
      dlv_plan_goods_mvmnt_date                                               as TranspOrdPlannedGdsMvtDteTme,
      tu_cat                                                                  as TransportationUnitCategory,





      /* Associations */
      //@ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]

      _TransportationOrderItem,
      //@ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]

      _TransportationOrderStop,
      //@ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]

      _TransportationOrderStage,
      //@ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]

      _TranspChargeItem,
      //@ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]

      _TranspOrdExecution,
      //@ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]

      _TransportationOrderBlock,
      //@ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]

      _Tendering,
      _DocRef,
      _SourceStop,
      _DestinationStop,
      _Consignee,
      _Shipper,
      _Carrier,
      _ExectgCarrier,
      _PurchasingOrganization,
      _PurchasingGroup,
      _PurchasingCompanyCode,
      _PlngAndExecOrganization,
      _PlngAndExecGroup,
      _TransportationOrderType,
      _TransportationOrderCategory,
      _TranspOrdPlanningBlock,
      _TranspOrdExecutionIsBlocked,
      _InvoicingIsBlocked,
      _TranspSCACCode,
      _TranspAirlineIATACode,
      _CarrierOriginOfEntry,
      _TranspOrdShippingType,
      _MovementType,
      _TranspOrdLifeCycleStatus,
      _TranspOrdPlanningStatus,
      _TransportationOrderExecSts,
      _TranspOrdDngrsGdsStatus,
      _TranspOrdConfirmationStatus,
      _TranspOrdSubcontractingSts,
      _TranspOrdWhseProcgStatus,
      _TranspOrdGoodsMvtStatus,
      _TranspOrdTrafficDirection,
      _MeansOfTransport,
      _TransportationMode,
      _TransportationModeCategory,
      _FrtDsputCaseStatus,
      _CreatedBy,
      _LastChangedBy,
      _TranspOrdResponsiblePerson,
      _TranspOrdGrossWeightUnit,
      _TranspOrdGrossVolumeUnit,
      _TranspOrdNetWeightUnit,
      _TranspOrdQuantityUnit,
      _TranspOrdAlternativeQtyUnit,
      _TranspOrdBaseQuantityUnit,
      _TranspOrdTareWeightUnit,
      _TranspOrdNumberOfCtnsUnit,
      _TranspOrdDngrsGdsExmpPtsUnit,
      _TranspOrdPalletSpacesUnit,
      _TranspOrdLoadMetersUnit,
      _TranspOrdSummary,
      _TranspOrdErrHndlg

}