I_TranspOrdStageAnalytics

@EndUserText.label:          'Transportation Order Stage Analytics'
@ClientHandling.algorithm:   #SESSION_VARIABLE

@Metadata:          {allowExtensions:             true,
                     ignorePropagatedAnnotations: true}

@AbapCatalog:       {sqlViewName:               'ITRANSPORDSTGANA',
                     compiler.compareFilter:    true,
                     buffering:                 {status: #NOT_ALLOWED}}

@AccessControl:     {authorizationCheck:        #CHECK,
                     personalData.blocking:     #('TRANSACTIONAL_DATA')}

@ObjectModel:       {representativeKey:         'TransportationOrderStageUUID',
                     usageType:                 {serviceQuality: #D,
                                                 sizeCategory:   #XXL,
                                                 dataClass:      #MIXED},
                     modelingPattern:           #NONE,
                     supportedCapabilities:    [#CDS_MODELING_DATA_SOURCE,
                                                #CDS_MODELING_ASSOCIATION_TARGET,
                                                #SQL_DATA_SOURCE,
                                                #EXTRACTION_DATA_SOURCE,
                                                #ANALYTICAL_PROVIDER,
                                                #ANALYTICAL_DIMENSION],
                     sapObjectNodeType.name:    'TransportationOrderStage'}

@VDM:               {viewType:                  #COMPOSITE}

@Analytics:         {dataCategory:              #DIMENSION,
                     dataExtraction:           {enabled: true,
                                                delta.changeDataCapture: {
                                                mapping:[
                                                          {
                                                          table: '/scmtms/d_torsts', role: #MAIN,
                                                          viewElement:  ['TransportationOrderStageUUID'],
                                                          tableElement: ['db_key']
                                                          }
                                                        ]                }
                                                },
                     internalName:                #LOCAL}


// view origin in Private Cloud; not relevant in Public Cloud

@VDM.lifecycle:     {status:    #DEPRECATED,
                     successor: 'I_TransportationOrderStage_2'}
                     

define view I_TranspOrdStageAnalytics
  as select from I_TransportationOrderStage

  /* Business Object related Node Associations*/
  association [1..1] to I_TransportationOrderAnalytics as _TransportationOrderAnalytics on $projection.TransportationOrderUUID = _TransportationOrderAnalytics.TransportationOrderUUID
  association [1..1] to I_TranspOrdStopAnalytics       as _TranspOrdStageSrceStopAnlyts on $projection.TranspOrdStageSrceStopUUID = _TranspOrdStageSrceStopAnlyts.TransportationOrderStopUUID
  association [1..1] to I_TranspOrdStopAnalytics       as _TranspOrdStageDestStopAnlyts on $projection.TranspOrdStageDestStopUUID = _TranspOrdStageDestStopAnlyts.TransportationOrderStopUUID

  /* Foreign Key and Text Associations */
  association [1..1] to I_UnitOfMeasure                as _TranspOrdStageDistanceUnit   on $projection.TranspOrdStageDistanceUnit = _TranspOrdStageDistanceUnit.UnitOfMeasure

{
      /* keys and references */
      @Semantics.uuid:true
  key cast(TransportationOrderStageUUID as /scmtms/vdm_tor_stage_db_key preserving type )    as TransportationOrderStageUUID,

      @ObjectModel.foreignKey.association: '_TransportationOrderAnalytics'
      @Semantics.uuid:true
      TransportationOrderUUID,

      @ObjectModel.foreignKey.association: '_TranspOrdStageSrceStopAnlyts'
      @Semantics.uuid:true
      cast(TranspOrdStageSrceStopUUID as /scmtms/vdm_tor_stg_s_stop_key preserving type)     as TranspOrdStageSrceStopUUID,

      @ObjectModel.foreignKey.association: '_TranspOrdStageDestStopAnlyts'
      @Semantics.uuid:true
      cast(TranspOrdStageDestStopUUID as /scmtms/vdm_tor_stg_d_stop_key preserving type)     as TranspOrdStageDestStopUUID,

      @Semantics.uuid:true
      cast(CarrierUUID as /scmtms/vdm_carrier_party_key preserving type )                    as CarrierUUID,

      /* Stage */
      cast(TransportationOrderStage as /scmtms/vdm_stage preserving type)                    as TransportationOrderStage,
      cast(TranspOrdStageDestStopCategory as /scmtms/vdm_tor_stg_d_stop_cat preserving type) as TranspOrdStageDestStopCategory,

      @ObjectModel.foreignKey.association: '_TranspOrdStageType'
      cast(TranspOrdStageType as /scmtms/vdm_stage_type preserving type )                    as TranspOrdStageType,

      @ObjectModel.foreignKey.association: '_TranspOrdStageCategory'
      cast(TranspOrdStageCategory as /scmtms/vdm_stage_category preserving type )            as TranspOrdStageCategory,
      cast(TranspOrdStagePlnStatus as /scmtms/vdm_tor_stg_pln_status preserving type)        as TranspOrdStagePlnStatus,

      @ObjectModel.foreignKey.association: '_MeansOfTransport'
      // cast as TranspOrdMeansOfTransport in using views necessary (C1 incompatibe here)

      cast(MeansOfTransport as /scmtms/vdm_tor_mot preserving type)                          as MeansOfTransport,

      @ObjectModel.foreignKey.association: '_TransportationMode'
      TransportationMode,

      @ObjectModel.foreignKey.association: '_TransportationModeCategory'
      TransportationModeCategory,

      @ObjectModel.foreignKey.association: '_TranspAirlineIATACode'
      TranspOrdStageAirlineIATACode,
      TranspOrdStageAirWayBill,
      TranspOrdStageVoyage,
      TranspOrdStageFlight,
      TranspOrdStageVessel,
      TranspOrdStageIMOShip,

      @ObjectModel.foreignKey.association: '_RequestingCompanyCode'
      RequestingCompanyCode,

      /* Carrier */
      @ObjectModel.foreignKey.association: '_Carrier'
      Carrier,

      @ObjectModel.foreignKey.association: '_TranspSCACCode'
      TranspOrdStageSCACCode,

      /* Utilization */
      @DefaultAggregation: #MAX
      @Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
      TranspOrdStageMaxUtilznRatio, // contains Max value of Mass and Volume and Length Ratio


      @DefaultAggregation: #MAX
      @Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
      TranspOrdStageUtilznMassRatio,

      @DefaultAggregation: #MAX
      @Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
      TranspOrdStageUtilznVolRatio,

      @DefaultAggregation: #MAX
      @Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
      TranspOrdStageUtilznLenRatio,

      @DefaultAggregation: #MAX
      @Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
      TranspOrdStageUtilznQtyRatio,

      @Semantics.unitOfMeasure: true
      cast(cast('%' as abap.unit(3)) as /scmtms/vdm_util_percent_unit preserving type)       as TranspOrdUtilznUnit,

      /* Quantities */
      @Semantics.quantity.unitOfMeasure: 'TranspOrdStageDistanceUnit'
      TranspOrdStageDistance,

      @ObjectModel.foreignKey.association: '_TranspOrdStageDistanceUnit'
      cast('KM' as /scmtms/vdm_stage_dstnc_unit)                                             as TranspOrdStageDistanceUnit,

      /* Durations */
      cast(TranspOrdStageNetDuration as /scmtms/vdm_stg_net_duration preserving type)        as TranspOrdStageNetDuration,

      /* Associations */

      // defined in this view

      _TransportationOrderAnalytics,
      _TranspOrdStageSrceStopAnlyts,
      _TranspOrdStageDestStopAnlyts,
      _TranspOrdStageDistanceUnit,

      // propagated from underlying view

      _TranspOrdStageType,
      _TranspOrdStageCategory,
      _TranspOrdStagePlnStatus,
      _MeansOfTransport,
      _TransportationMode,
      _TransportationModeCategory,
      _Carrier,
      _TranspSCACCode,
      _TranspAirlineIATACode,
      _RequestingCompanyCode
}