I_TRANSPORTATIONORDERSTAGE

@EndUserText:   {label:              'Transportation Order: Stages'}
@ObjectModel:   {representativeKey:  'TransportationOrderStageUUID',
                 usageType:          {serviceQuality: #C,
                                      sizeCategory:   #XL,
                                      dataClass:      #TRANSACTIONAL}}
@VDM:           {viewType:           #BASIC}
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: {authorizationCheck: #PRIVILEGED_ONLY,
                 personalData.blocking:#('TRANSACTIONAL_DATA'),
                 privilegedAssociations: [  '_TranspOrdStageSrceStop',
                                            '_TranspOrdStageDestStop']}
@Metadata.ignorePropagatedAnnotations: true

define view entity I_TransportationOrderStage
  as select from /scmtms/d_torsts
  /* Business Object related Node Associations*/
  association [1..1] to I_TransportationOrder        as _TransportationOrder         on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
  association [1..1] to I_TransportationOrderStop    as _TranspOrdStageSrceStop      on $projection.TranspOrdStageSrceStopUUID = _TranspOrdStageSrceStop.TransportationOrderStopUUID
  association [1..1] to I_TransportationOrderStop    as _TranspOrdStageDestStop      on $projection.TranspOrdStageDestStopUUID = _TranspOrdStageDestStop.TransportationOrderStopUUID
  /* Foreign Key and Text Associations */
  association [0..1] to I_TranspOrdStageType         as _TranspOrdStageType          on $projection.TranspOrdStageType = _TranspOrdStageType.TranspOrdStageType
  association [0..1] to I_TranspOrdStageCategory     as _TranspOrdStageCategory      on $projection.TranspOrdStageCategory = _TranspOrdStageCategory.TranspOrdStageCategory
  association [0..1] to I_BusinessPartner            as _Carrier                     on $projection.Carrier = _Carrier.BusinessPartner
  association [0..1] to I_BusinessPartner            as _TranspOrdStageInvoicingCarr on $projection.TranspOrdStageInvoicingCarrier = _TranspOrdStageInvoicingCarr.BusinessPartner
  association [0..1] to I_TranspSCACCode             as _TranspSCACCode              on $projection.TranspOrdStageSCACCode = _TranspSCACCode.TranspSCACCode
  association [0..1] to I_TranspSCACCode             as _TranspOrdStgeInvcgSCACCode  on $projection.TranspOrdStgeInvcgSCACCode = _TranspOrdStgeInvcgSCACCode.TranspSCACCode
  association [0..1] to I_TranspAirlineIATACode      as _TranspAirlineIATACode       on $projection.TranspOrdStageAirlineIATACode = _TranspAirlineIATACode.TranspAirlineIATACode
  association [0..1] to I_MeansOfTransport           as _MeansOfTransport            on $projection.MeansOfTransport = _MeansOfTransport.MeansOfTransport
  association [0..1] to I_TransportationMode_2       as _TransportationMode          on $projection.TransportationMode = _TransportationMode.TransportationMode
  association [0..1] to I_TransportationModeCategory as _TransportationModeCategory  on $projection.TransportationModeCategory = _TransportationModeCategory.TransportationModeCategory
  association [0..1] to I_TranspOrdStagePlnStatus    as _TranspOrdStagePlnStatus     on $projection.TranspOrdStagePlnStatus = _TranspOrdStagePlnStatus.TranspOrdStagePlnStatus
  association [0..1] to I_CompanyCode                as _RequestingCompanyCode       on $projection.RequestingCompanyCode = _RequestingCompanyCode.CompanyCode

{
      @ObjectModel.text.element:  [ 'TransportationOrderStage' ]
  key db_key                                                                                 as TransportationOrderStageUUID,
      @ObjectModel.foreignKey.association: '_TransportationOrder'
      cast(root_key as /scmtms/vdm_tor_db_key preserving type)                               as TransportationOrderUUID,
      @ObjectModel.foreignKey.association: '_TranspOrdStageSrceStop'
      parent_key                                                                             as TranspOrdStageSrceStopUUID,
      @ObjectModel.foreignKey.association: '_TranspOrdStageDestStop'
      succ_stop_key                                                                          as TranspOrdStageDestStopUUID,
      @Semantics.text: true
      successor_id                                                                           as TransportationOrderStage,
      stop_succ_cat                                                                          as TranspOrdStageDestStopCategory,
      @ObjectModel.foreignKey.association: '_TranspOrdStageType'
      stage_type                                                                             as TranspOrdStageType,
      @ObjectModel.foreignKey.association: '_TranspOrdStageCategory'
      stage_cat                                                                              as TranspOrdStageCategory,
      cast(plan_status as char1 preserving type)                                             as TranspOrdStagePlnStatus,
      cast('KM' as /scmtms/vdm_stage_dstnc_unit)                                             as TranspOrdStageDistanceUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdStageDistanceUnit'
      cast(distance_km as /scmtms/vdm_stage_dstnc preserving type)                           as TranspOrdStageDistance,
      cast(duration_net as bapi11201trmdurat preserving type )                               as TranspOrdStageNetDuration,
      @ObjectModel.foreignKey.association: '_MeansOfTransport'
      mtr_tco                                                                                as MeansOfTransport,
      @ObjectModel.foreignKey.association: '_TransportationMode'
      mot                                                                                    as TransportationMode,
      @ObjectModel.foreignKey.association: '_TransportationModeCategory'
      mot_cat                                                                                as TransportationModeCategory,
      cast(tsp_key as bu_partner_guid)                                                       as CarrierUUID,
      @ObjectModel.foreignKey.association: '_Carrier'
      tsp_id                                                                                 as Carrier,
      @ObjectModel.foreignKey.association: '_TranspSCACCode'
      tsp_scac                                                                               as TranspOrdStageSCACCode,
      @ObjectModel.foreignKey.association: '_TranspAirlineIATACode'
      tsp_airlc                                                                              as TranspOrdStageAirlineIATACode,
      tsp_airlcawb                                                                           as TranspOrdStageAirWayBill,
      voyage_id                                                                              as TranspOrdStageVoyage,
      flight_code                                                                            as TranspOrdStageFlight,
      vessel_id                                                                              as TranspOrdStageVessel,
      imo_id                                                                                 as TranspOrdStageIMOShip,
      @Semantics.booleanIndicator:true
      cast(_Carrier.IsBusinessPurposeCompleted as /scmtms/vdm_carrier_xpcpt preserving type) as CarrierBusPurposeIsCompleted,
      cast(max_util     as /scmtms/vdm_stage_util_max preserving type)                       as TranspOrdStageMaxUtilznRatio,
      cast(util_mass    as /scmtms/vdm_stage_util_mass preserving type)                      as TranspOrdStageUtilznMassRatio,
      cast(util_volume  as /scmtms/vdm_stage_util_volume preserving type)                    as TranspOrdStageUtilznVolRatio,
      cast(util_length  as /scmtms/vdm_stage_util_length preserving type)                    as TranspOrdStageUtilznLenRatio,
      cast(util_dimless as /scmtms/vdm_stage_util_dimless preserving type)                   as TranspOrdStageUtilznQtyRatio,
      @ObjectModel.foreignKey.association: '_RequestingCompanyCode'
      payer_company_code                                                                     as RequestingCompanyCode,
      shipping_type                                                                          as TranspOrdStageShippingType,
      stg_pymt_ind                                                                           as TranspOrdStgeInvcgCarrLvl,
      @ObjectModel.foreignKey.association: '_TranspOrdStageInvoicingCarr'
      tsp_pymt_id                                                                            as TranspOrdStageInvoicingCarrier,
      cast (tsp_pymt_key  as /scmtms/vdm_inv_carr_uuid)                                      as TranspOrdStgeInvcgCarrUUID,
      @ObjectModel.foreignKey.association: '_TranspOrdStgeInvcgSCACCode'
      tsp_pymt_scac                                                                          as TranspOrdStgeInvcgSCACCode,


      /* Associations */
      //@ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]

      _TransportationOrder,
      _TranspOrdStageSrceStop,
      _TranspOrdStageDestStop,
      _TranspOrdStageType,
      _TranspOrdStageCategory,
      _TranspOrdStagePlnStatus,
      _Carrier,
      _TranspSCACCode,
      _TranspAirlineIATACode,
      _MeansOfTransport,
      _TransportationMode,
      _TransportationModeCategory,
      _RequestingCompanyCode,
      _TranspOrdStgeInvcgSCACCode,
      _TranspOrdStageInvoicingCarr
}