I_ShippingNotifQuickView

//TCL_I_MRPPURCHASEORDER

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@EndUserText.label: 'MRP Shipping Notifications'

@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED }

@VDM.viewType: #COMPOSITE

define view entity I_ShippingNotifQuickView
  with parameters
    P_MRPElementCategory : mrpelementcategory

  as select from    I_PurchasingDocument     as Head // EKKO


    inner join      I_PurchasingDocumentItem as Item on Head.PurchasingDocument = Item.PurchasingDocument // EKPO


    left outer join I_PurgDocScheduleLine    as Line on  Line.PurchasingDocument     = Item.PurchasingDocument
                                                     and Line.PurchasingDocumentItem = Item.PurchasingDocumentItem // EKET


  association [0..*] to I_PurgDocSupplierConfirmation as Confirmation              on  $projection.PurchaseOrder     = Confirmation.PurchasingDocument
                                                                                   and $projection.PurchaseOrderItem = Confirmation.PurchasingDocumentItem

  association [0..1] to I_PurgDocumentItemCategory    as _PurgDocumentItemCategory on  $projection.MaterialProcurementCategory = _PurgDocumentItemCategory.PurchasingDocumentItemCategory

  association [0..1] to I_UnitOfMeasure               as _BaseUnit                 on  $projection.PurchaseOrderItemQuantityUnit = _BaseUnit.UnitOfMeasure

{
  key Item.PurchasingDocument                                                                         as PurchaseOrder,
  key Item.PurchasingDocumentItem                                                                     as PurchaseOrderItem,
  key Confirmation.SequentialNmbrOfSuplrConf                                                          as ScheduleLine,
      //  key Line.ScheduleLine,


//      Item.PurchasingDocumentItem                                                  as MRPElementItem,

      Item.Material,
      Item._Material._Text[1: Language = $session.system_language].MaterialName                       as MaterialName,
      Head.PurchasingDocumentCategory,
      Head.PurchasingDocumentType,
      Item.PurchasingDocumentItemCategory                                                             as MaterialProcurementCategory,
      _PurgDocumentItemCategory._Text[1: Language = $session.system_language].PurgDocItemCategoryName as MaterialProcurementCatName,

      Item.Plant                                                                                      as MRPPlant,

      Head.Supplier,
      Item.SupplierMaterialNumber,
      Item.InventorySpecialStockType,
      Head.LastChangeDateTime,
      // Sales data


      // Acct._SalesOrder._SoldToParty._StandardAddress._DefaultEmailAddress.EmailAddress, // Commented out as prop is not needed and

      // it leads to a full table scan of ADR6 table

      Head.PurchasingGroup,
      Head._PurchasingGroup.PurchasingGroupName,
//      case Head._PurchasingGroup.PhoneNumberExtension

//         when '' then Head._PurchasingGroup.PurchasingGroupPhoneNumber

//         else concat(Head._PurchasingGroup.PhoneNumber, concat('-', Head._PurchasingGroup.PhoneNumberExtension))

//       end                                                                                            as PurchasingGroupPhoneNumber,


      Head._PurchasingGroup.EmailAddress                                                              as PurchasingGroupEmailAddress,
      Item.PlannedDeliveryDurationInDays                                                              as MaterialPlannedDeliveryDurn,
      Item.GoodsReceiptDurationInDays                                                                 as MaterialGoodsReceiptDuration,
      Line.ScheduleLineOrderDate,
      Line.ScheduleLineDeliveryDate                                                                   as DeliveryDate,
      Line.ProductAvailabilityDate,
      Item.PartialDeliveryIsAllowed,
      Item.IsOrderAcknRqd,

      Item.OrderItemQtyToBaseQtyDnmntr,
      Item.OrderItemQtyToBaseQtyNmrtr,

      //      Shipping Notification

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      Confirmation.ConfirmedQuantity                                                                  as ConfirmedQuantity,

      Confirmation.SupplierConfirmationCategory                                                       as SupplierConfirmationCategory,
      Confirmation.DeliveryDocument                                                                   as DeliveryDocument,


      // Quantities

      Item.BaseUnit,
      _BaseUnit.UnitOfMeasure,
      _BaseUnit.UnitOfMeasureNumberOfDecimals,
      _BaseUnit.UnitOfMeasureDspNmbrOfDcmls,
      _BaseUnit._Text[1: Language = $session.system_language].UnitOfMeasureCommercialName,

      Item.OrderQuantityUnit                                                                          as PurchaseOrderItemQuantityUnit,

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      Item.OrderQuantity                                                                              as PurchaseOrderItemQuantity,

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      Line.ScheduleLineOrderQuantity, // corresponds to ScheduleLineTotalQuantity


      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      Line.GoodsReceiptQuantity,

      @DefaultAggregation: #NONE
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      Line.ScheduleLineOpenQuantity,

      // Associations

      _BaseUnit,
      Head._Supplier,
      Head._PurchasingGroup,

      Item._Material,
      $parameters.P_MRPElementCategory                                                                as MRPElementCategory,

      Item._PurchasingDocument,
      Head._PurchasingDocumentType,

      Head._PurchasingDocumentCategory,

      _PurgDocumentItemCategory
};