I_PurgDocScheduleLine

@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Purchasing Document Schedule Line'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IMMPRGDOCSCHEDLN'
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_PurgDocScheduleLine
  as select from eket as eket

  association [0..1] to I_Purchaserequisitionitem as _PurchaseRequisitionItem on  $projection.PurchaseRequisition     = _PurchaseRequisitionItem.PurchaseRequisition
                                                                              and $projection.PurchaseRequisitionItem = _PurchaseRequisitionItem.PurchaseRequisitionItem

  association [1..1] to I_Purchaserequisition     as _PurchaseRequisition     on  $projection.PurchaseRequisition = _PurchaseRequisition.PurchaseRequisition


  association [1..1] to I_Deliverydatecategory    as _DeliveryDateCategory    on  $projection.DelivDateCategory = _DeliveryDateCategory.DelivDateCategory

{
      //@ObjectModel.foreignKey.association: '_PurchasingDocument'

  key eket.ebeln    as PurchasingDocument,

      //@ObjectModel.foreignKey.association: '_PurchaseDocumentItem'

  key eket.ebelp    as PurchasingDocumentItem,

  key etenr         as ScheduleLine,
      //_DeliveryDateCategory.Language,

      //@ObjectModel: { foreignKey.association: '_Deliverydatecategtext'}

      @ObjectModel: { foreignKey.association: '_DeliveryDateCategory'}
      lpein         as DelivDateCategory,

      eindt         as ScheduleLineDeliveryDate,

      slfdt         as SchedLineStscDeliveryDate,

      startdate     as PerformancePeriodStartDate,

      enddate       as PerformancePeriodEndDate,

      uzeit         as ScheduleLineDeliveryTime,

      eket.menge    as ScheduleLineOrderQuantity,

      bedat         as ScheduleLineOrderDate,

      wemng         as RoughGoodsReceiptQty,


      abart         as SchedulingAgreementReleaseType,
      dat01         as CommittedDeliveryDate,
      altdt         as SchedLinePrevDelivDate,
      _dataaging    as SchedulingLineDataAgingFilter,

      @ObjectModel.foreignKey.association: '_PurchaseRequisition'
      eket.banfn    as PurchaseRequisition,

      @ObjectModel.foreignKey.association: '_PurchaseRequisitionItem'
      eket.bnfpo    as PurchaseRequisitionItem,

      estkz         as SourceOfCreation,

      ameng         as PrevDelivQtyOfScheduleLine,

      eket.mahnz    as NoOfRemindersOfScheduleLine,

      fixkz         as ScheduleLineIsFixed,

      mng02         as ScheduleLineCommittedQuantity,

      rsnum         as Reservation,

      mbdat         as ProductAvailabilityDate,
      mbuhr         as MaterialStagingTime,
      tddat         as TransportationPlanningDate,
      tduhr         as TransportationPlanningTime,
      lddat         as LoadingDate,
      lduhr         as LoadingTime,
      wadat         as GoodsIssueDate,
      wauhr         as GoodsIssueTime,
      eldat         as STOLatestPossibleGRDate,
      eluhr         as STOLatestPossibleGRTime,
      wemng         as GoodsReceiptQuantity,
      glmng         as StockTransferDeliveredQuantity,
      wamng         as ScheduleLineIssuedQuantity,
      charg         as Batch,

      // Fields added for R_*TP development, GFN need to be approved

      aulwe         as RouteSchedule,
      mbuhr         as ProductAvailabilityTime,
//      eldat         as GoodsReceiptEndDate,

//      eluhr         as GoodsReceiptEndTime,

//      dat01         as CommittedDate,

//      handoverdate  as HandoverDte,

//      handovertime  as HandoverTme,

//      geo_route     as GeographicalRoute,


      // Fields doen't exist in DB Table, but exist in BAPIMEPOSCHEDULE

      // PurchasingDocumentDeletionCode - DELETE_IND

      // IsClosed - REQ_CLOSED


      //Persistent Key Adoption

      eket.uniqueid as ScheduleLineUniqueID,

      case
        when
         eket.menge > wemng
        then
         (eket.menge - wemng )
         else
         0
      end           as ScheduleLineOpenQuantity,

      _PurchaseRequisition,
      _PurchaseRequisitionItem,
      _DeliveryDateCategory

}