I_SerialNumberHistory

@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData.blocking: #NOT_REQUIRED }

@VDM.viewType: #COMPOSITE

@ObjectModel.usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory:   #XL }
@ObjectModel.supportedCapabilities: [
  #SQL_DATA_SOURCE,
  #CDS_MODELING_DATA_SOURCE,
  #CDS_MODELING_ASSOCIATION_TARGET
]

@EndUserText.label: 'Serial Number History'

define view entity I_SerialNumberHistory
  as select from P_SerialNumberHistoryUnion
  association        to parent I_MatlSerialNumberInformation as _MatlSrlNmbrInfo      on  $projection.Equipment = _MatlSrlNmbrInfo.Equipment

  association [0..1] to I_SrlNmbrBizDocObjectTypeText        as _ObjectTypeText       on  $projection.SrlNmbrBizDocumentObjectType = _ObjectTypeText.SrlNmbrBizDocumentObjectType
                                                                                      and _ObjectTypeText.Language                 = $session.system_language
  association [0..1] to I_SalesDocumentItem                  as _SalesDocumentItem    on  $projection.SalesOrder     = _SalesDocumentItem.SalesDocument
                                                                                      and $projection.SalesOrderItem = _SalesDocumentItem.SalesDocumentItem
  association [0..1] to I_DeliveryDocumentItem               as _DeliveryDocumentItem on  $projection.DeliveryDocument     = _DeliveryDocumentItem.DeliveryDocument
                                                                                      and $projection.DeliveryDocumentItem = _DeliveryDocumentItem.DeliveryDocumentItem
{
  key Equipment,
  key SerialNumberBusinessDocument,
  key SrlNmbrBusinessDocumentItem,
  key SrlNmbrBizDocAdditionalKey1,
  key SrlNmbrBizDocAdditionalKey2,
  key SrlNmbrBizDocumentObjectType,

      Material,
      SerialNumber,
      MaintenanceObjectList,
      MaintenanceObjectListItem,

      DeliveryDocument,
      DeliveryDocumentItem,
      SalesOrder,
      SalesOrderItem,
      MaterialDocumentItem,
      MaterialDocumentYear,
      OrderItem,
      PhysicalInventoryDocumentItem,
      FiscalYear,
      SerialNumberPhysicalInvtryType,
      PurchaseOrderItem,
      PurchaseRequisitionItem,
      JITCallItemNumber,
      CompGrpNumber,
      tstmp_to_dats(SerialNumberAssignmentDateTime,
                    UserEnteredTimeZone,
                    $session.client, 'NULL' ) as SerialNumberAssignmentDate,
//      tstmp_to_tims(SerialNumberAssignmentDateTime,

//                    UserEnteredTimeZone,

//                    $session.client, 'NULL' ) as SerialNumberAssignmentTime, 

      @Semantics.dateTime: true
      @Semantics.timeZoneReference: 'UserEnteredTimeZone'
      SerialNumberAssignmentDateTime,
      UserEnteredTimeZone,
      Customer,
      CustomerName,
      Supplier,
      SupplierName,
      NumberOfSerialNumbers,
      SDDocumentCategory,
      GoodsMovementType,
      MovementTypeDescription,
      SalesOrderType,
      SalesDocumentTypeName,
      SalesOrderItemCategory,
      AccountingDocumentType,
      AccountingDocumentTypeName,
      Plant,
      PlantName,
      StorageLocation,
      StorageLocationName,
      Batch,
      DebitCreditCode,
      DebitCreditCodeName,
      OrderCategory,
      OrderType,
      OrderTypeName,
      OrderIsRefurbishmentOrder,
      SrlNumberPhysicalInvtryTypeTxt,
      PhysicalInventoryStockType,
      PhysicalInventoryStockTypeName,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      PurchasingDocumentTypeName,
      PurchasingDocumentItemCategory,
      ExternalJITCallNumber,
      ShipToParty,
      BusinessPartnerName,
      SubcontrgCompOfInbDelivItem,

      _MatlSrlNmbrInfo,
      _ObjectTypeText,
      _DeliveryDocumentItem,
      _SalesDocumentItem
}