P_SERIALNUMBERHISTORYUNION

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_SerialNumberHistoryUnion

  as select from P_SrlNmbrHistLogisticsDocument
{
  key Equipment,
  key SerialNumberBusinessDocument,
  key SrlNmbrBusinessDocumentItem,
  key SrlNmbrBizDocAdditionalKey1,
  key SrlNmbrBizDocAdditionalKey2,
  key SrlNmbrBizDocumentObjectType,

      Material,
      SerialNumber,
      MaintenanceObjectList,
      MaintenanceObjectListItem,

      DeliveryDocument,
      DeliveryDocumentItem,
      SalesOrder,
      SalesOrderItem,
      MaterialDocumentItem,
      MaterialDocumentYear,
      OrderItem,
      PhysicalInventoryDocumentItem,
      FiscalYear,
      SerialNumberPhysicalInvtryType,
      PurchaseOrderItem,
      PurchaseRequisitionItem,
      JITCallItemNumber,
      CompGrpNumber,
      SerialNumberAssignmentDateTime,
      UserEnteredTimeZone,
      Customer,
      CustomerName,
      Supplier,
      SupplierName,
      NumberOfSerialNumbers,
      SDDocumentCategory,
      GoodsMovementType,
      MovementTypeDescription,
      SalesOrderType,
      SalesDocumentTypeName,
      SalesOrderItemCategory,
      AccountingDocumentType,
      AccountingDocumentTypeName,
      Plant,
      PlantName,
      StorageLocation,
      StorageLocationName,
      Batch,
      DebitCreditCode,
      DebitCreditCodeName,
      OrderCategory,
      OrderType,
      OrderTypeName,
      OrderIsRefurbishmentOrder,
      SrlNumberPhysicalInvtryTypeTxt,
      PhysicalInventoryStockType,
      PhysicalInventoryStockTypeName,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      PurchasingDocumentTypeName,
      PurchasingDocumentItemCategory,
      ExternalJITCallNumber,
      ShipToParty,
      BusinessPartnerName,
      SubcontrgCompOfInbDelivItem
}

union all select from P_SrlNmbrHistServiceDocument
{
  key Equipment,
  key cast( ServiceDocument as lo_sn_business_document_id )       as SerialNumberBusinessDocument,
  key cast( ServiceDocumentItem as lo_sn_business_document_item ) as SrlNmbrBusinessDocumentItem,
  key cast( '' as lo_sn_biz_doc_additional_key )                  as SrlNmbrBizDocAdditionalKey1,
  key cast( '' as lo_sn_biz_doc_additional_key )                  as SrlNmbrBizDocAdditionalKey2,
  key cast( case (ServiceObjectType)
            when 'BUS2000116'
            then 'SRVO'
            when 'BUS2000117'
            then 'SRVC'
            when 'BUS2000256'
            then 'IHRP'
            else ''
            end as srlnmbrbizdocobjecttype )                      as SrlNmbrBizDocumentObjectType,
      Material,
      SerialNumber,
      cast( '0' as abap.int8( 19 ) )                              as MaintenanceObjectList,
      cast( '0' as abap.int4( 10 ) )                              as MaintenanceObjectListItem,

      cast( '' as abap.char( 10 ) )                               as DeliveryDocument,
      cast( '' as abap.numc( 6 ) )                                as DeliveryDocumentItem,
      cast( '' as abap.char( 10 ) )                               as SalesOrder,
      cast( '' as abap.numc( 6 ) )                                as SalesOrderItem,
      cast( '' as abap.numc( 4 ) )                                as MaterialDocumentItem,
      cast( '' as abap.numc( 4 ) )                                as MaterialDocumentYear,
      cast( '' as abap.numc( 4 ) )                                as OrderItem,
      cast( '' as abap.numc( 3 ) )                                as PhysicalInventoryDocumentItem,
      cast( '' as abap.numc( 4 ) )                                as FiscalYear,
      cast( '' as abap.char( 1 ) )                                as SerialNumberPhysicalInvtryType,
      cast( '' as abap.numc( 5 )  )                               as PurchaseOrderItem,
      cast( '' as abap.numc( 5 ) )                                as PurchaseRequisitionItem,
      cast( '' as abap.numc( 4 ) )                                as JITCallItemNumber,
      cast( '' as abap.char( 60 ) )                               as CompGrpNumber,
      SerialNumberAssignmentDateTime,
      abap_system_timezone( $session.client, 'NULL' )             as UserEnteredTimeZone,
      cast( '' as abap.char( 10 ) )                               as Customer,
      cast( '' as abap.char( 220 ) )                              as CustomerName,
      cast( '' as lifnr )                                         as Supplier,
      cast( '' as abap.char( 163 ) )                              as SupplierName,
      NumberOfSerialNumbers,
      cast( '' as abap.char( 4 ) )                                as SDDocumentCategory,
      cast( '' as abap.char( 3 ) )                                as GoodsMovementType,
      cast( '' as abap.char( 20 ) )                               as MovementTypeDescription,
      cast( '' as abap.char( 4 ) )                                as SalesOrderType,
      cast( '' as abap.char( 20 ) )                               as SalesDocumentTypeName,
      cast( '' as abap.char( 4 ) )                                as SalesOrderItemCategory,
      cast( '' as abap.char( 2 ) )                                as AccountingDocumentType,
      cast( '' as abap.char( 20 ) )                               as AccountingDocumentTypeName,
      cast( '' as werks_d )                                       as Plant,
      cast( '' as abap.char( 30 ) )                               as PlantName,
      cast( '' as abap.char( 4 ) )                                as StorageLocation,
      cast( '' as abap.char( 16 ) )                               as StorageLocationName,
      cast( '' as charg_d )                                       as Batch,
      ''                                                          as DebitCreditCode,
      cast( '' as abap.char( 60) )                                as DebitCreditCodeName,
      cast( '' as abap.numc( 2 ) )                                as OrderCategory,
      cast( '' as abap.char( 4 ) )                                as OrderType,
      cast( '' as abap.char( 40 ) )                               as OrderTypeName,
      cast( '' as rsord preserving type )                         as OrderIsRefurbishmentOrder,
      cast( '' as abap.char( 60 ) )                               as SrlNumberPhysicalInvtryTypeTxt,
      ''                                                          as PhysicalInventoryStockType,
      cast( '' as abap.char( 20 ) )                               as PhysicalInventoryStockTypeName,
      ''                                                          as PurchasingDocumentCategory,
      cast( '' as abap.char( 4 ) )                                as PurchasingDocumentType,
      cast( '' as abap.char( 20 ) )                               as PurchasingDocumentTypeName,
      ''                                                          as PurchasingDocumentItemCategory,
      cast( '' as abap.char( 35 ) )                               as ExternalJITCallNumber,
      cast( '' as abap.char( 10 ) )                               as ShipToParty,
      cast( '' as abap.char( 81 ) )                               as BusinessPartnerName,
      cast( '' as abap.numc( 6 ) )                                as SubcontrgCompOfInbDelivItem
}