I_RtlPromnStoreGroup

@Analytics.technicalName: 'IRTLPROMNSTGRP'
@EndUserText: {label: 'Retail Promotion Store Group'}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}

@VDM.viewType: #BASIC
@ObjectModel: {
//    semanticKey: [''] ,

    representativeKey: 'StoreGroupInternalID',
    usageType: {
        serviceQuality: #A,
        sizeCategory: #M,
        dataClass: #TRANSACTIONAL
   }
}

define view entity I_RtlPromnStoreGroup
  as select from wagu

  association [0..1] to I_RtlPromnLocalStoreGroup as _RtlPromnLocalStoreGroup on  $projection.RetailPromotion      = _RtlPromnLocalStoreGroup.RetailPromotion
                                                                              and $projection.StoreGroupInternalID = _RtlPromnLocalStoreGroup.StoreGroupInternalID
  association [0..1] to I_ClassHeader             as _ClassHeader             on  $projection.StoreGroupInternalID = _ClassHeader.ClassInternalID                                                                            
  association [0..*] to I_ClassText               as _ClassText               on  $projection.StoreGroupInternalID = _ClassText.ClassInternalID
  association [1..1] to I_RetailPromotion         as _RetailPromotion         on  $projection.RetailPromotion      = _RetailPromotion.RetailPromotion
{
      @ObjectModel.foreignKey.association: '_RetailPromotion'
  key aktnr  as RetailPromotion,
  key clint  as StoreGroupInternalID,
      _RtlPromnLocalStoreGroup,
      _ClassText,
      _ClassHeader,

      alivo  as PromnListingStartDate,
      alibi  as PromnListingEndDate,

      avkvo  as RetailPromotionSalesFromDate,
      avkbi  as RetailPromotionSalesToDate,

      abekm  as PromotionAnnouncementDate,
      rudat  as PromotionAnncmntReplyDate,
      awefi  as RtlPromnLatestPossibleGRDate,

      stplgr as RtlPromnStoreGroupCategory,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _RetailPromotion
}