I_ProviderContractItemVH

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Provider Contract Item'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MASTER
}
@VDM.viewType: #COMPOSITE
@ObjectModel.dataCategory:#VALUE_HELP
@ObjectModel.representativeKey: 'ProviderContractItem'
@Consumption.ranked: true
@Search.searchable: true
define view entity I_ProviderContractItemVH
  as select from I_ProviderContractItem
{
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
      @ObjectModel.foreignKey.association: '_PrvdrContr'
  key ProviderContract,

      @ObjectModel.text.element: ['CAProviderContractItemText']
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
  key ProviderContractItem,

      @Semantics.text: true
      @EndUserText.label: 'Item Description'
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8,  ranking: #LOW }
      @Consumption.filter.hidden: true
      CAProviderContractItemText,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8,  ranking: #LOW }
      @ObjectModel.text.element: ['BusinessPartnerName']
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      @Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'}}]
      _PrvdrContr.BusinessPartner,

      @Semantics.text: true
      @Consumption.filter.hidden: true
      @EndUserText.label: 'Business Partner Name'
      _PrvdrContr._BusinessPartner.BusinessPartnerName,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8,  ranking: #LOW }
      @ObjectModel.text.element: ['ContractAccountName']
      @ObjectModel.foreignKey.association: '_ContrAcc'
      @Consumption.valueHelpDefinition: [{entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount'}}]
      ContractAccount,

      @Semantics.text: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8,  ranking: #LOW }
      @Consumption.filter.hidden: true
      _ContrAcc.ContractAccountName,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8,  ranking: #LOW }
      @ObjectModel.text.element: ['CAProviderContractCategoryText']
      @ObjectModel.foreignKey.association: '_ProviderContractCategory'
      _PrvdrContr.CAProviderContractCategory,

      @Semantics.text: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8,  ranking: #LOW }
      @Consumption.filter.hidden: true
      _PrvdrContr._ProviderContractCategory._Text[1:Language = $session.system_language].CAProviderContractCategoryText,

      @Consumption.hidden: true
      CreationDate,

      @Consumption.hidden: true
      CreationTime,

      @Semantics.dateTime: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_FKK_VT_TMSTMP_FILTER_TRANSF'
      @Consumption.filter.selectionType: #INTERVAL
      cast(dats_tims_to_tstmp(CreationDate,
                              CreationTime,
                              abap_system_timezone($session.client, 'NULL'),
                              $session.client, 'NULL') as vdm_creationdatetime) as CreationDateTime,

      @Consumption.hidden: true
      LastChangeDate,

      @Consumption.hidden: true
      LastChangeTime,

      @Semantics.dateTime: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_FKK_VT_TMSTMP_FILTER_TRANSF'
      @Consumption.filter.selectionType: #INTERVAL
      cast(dats_tims_to_tstmp(LastChangeDate,
                              LastChangeTime,
                              abap_system_timezone($session.client, 'NULL'),
                              $session.client, 'NULL') as vdm_lastchangedon)    as LastChangeDateTime,

      @Consumption.hidden: true
      CompanyCode,

      _PrvdrContr._BusinessPartner,
      _PrvdrContr,
      _PrvdrContr._ProviderContractCategory,
      _ContrAcc
}
where _PrvdrContr.CAProviderContractCategory != 'A'