I_PROVIDERCONTRACTITEM
Provider Contract Item
I_PROVIDERCONTRACTITEM is a CDS View in S/4HANA. Provider Contract Item. It contains 15 fields. 12 CDS views read from this table.
CDS Views using this table (12)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_BSOrdItmProcFlwSubscrpnItem | view | inner | CONSUMPTION | Subscription Item Attrib for BSOrd Prgrs |
| C_EBRRPrvdrContrMonitorItem | view_entity | from | CONSUMPTION | Prov. Contr. Item detail for monitor app |
| I_CAProviderContractItem | view | from | BASIC | Provider Contract Item |
| I_ProviderContractItemVH | view_entity | from | COMPOSITE | Provider Contract Item |
| I_SalesProviderContractItem | view | from | BASIC | Provider-Vertragspositionen für SB |
| I_SlsBillgProviderContractItem | view_entity | from | COMPOSITE | Sales Billing Provider Contract Item |
| P_AllocatedRevenueTot | view_entity | inner | COMPOSITE | Allocated Revenue Totals (private view) |
| P_EBRRPrvdrContrIss | view_entity | inner | COMPOSITE | EBRR: Manage RR Issues – Prov.Contr. |
| P_EBRRPrvdrContrMonitor | view_entity | from | COMPOSITE | EBRR Monitor: Provider Contracts |
| P_EBRRPrvdrContrRslt | view_entity | inner | CONSUMPTION | Results Rev. Rec. Issues - Prvd. Contr |
| P_EBRRPrvdrContrWlItm | view_entity | from | COMPOSITE | PECRun: Provider Contract Worklist item |
| P_RAIntegEBRRProviderContract | view_entity | inner | COMPOSITE | RAR Integration EBRR Provider Contract |
Fields (15)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | ProviderContract | ProviderContract | 6 |
| KEY | ProviderContractItem | ProviderContractItem | 7 |
| _PrvdrContr | _PrvdrContr | 1 | |
| BusinessSolutionOrder | BusinessSolutionOrder | 1 | |
| CAEndOfDurationDateTime | CAEndOfDurationDateTime | 1 | |
| CAProviderContractItemText | CAProviderContractItemText | 3 | |
| CAPrvdrContrItmValidFromDteTme | CAPrvdrContrItmValidFromDteTme | 1 | |
| CompanyCode | CompanyCode | 2 | |
| DistributionChannel | DistributionChannel | 2 | |
| Division | OrganizationDivision | 2 | |
| EBRRResultAnalysisInternalID | ResultAnalysisInternalID | 1 | |
| ProfitCenter | ProfitCenter | 2 | |
| RevenueRecognitionKey | ResultAnalysisInternalID | 4 | |
| SalesOrganization | SalesOrganization | 3 | |
| SoldProduct | SoldProduct | 1 |
@AbapCatalog: { compiler.compareFilter:true,
//preserveKey:true,
sqlViewName: 'IPRVDRCONTRI' }
@AccessControl: { authorizationCheck: #CHECK,
personalData.blocking : #REQUIRED }
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Provider Contract Item'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: { representativeKey: 'ProviderContractItem',
supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE ],
usageType: { dataClass: #MASTER,
serviceQuality: #C,
sizeCategory: #XL } }
@VDM.viewType: #BASIC
define view I_ProviderContractItem
as select from dfkk_vt_i
association [1..1] to E_CAProviderContractItem as _PCoExtension on $projection.ProviderContract = _PCoExtension.CAProviderContract
and $projection.ProviderContractItem = _PCoExtension.CAProviderContractItemNumber
association [0..1] to I_CABillgPln as _BillgPln on $projection.CABillgPlnNumber = _BillgPln.CABillgPlnNumber
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..1] to I_CABillgCycle as _BillgCycle on $projection.CABillgCycle = _BillgCycle.CABillgCycle
association [0..1] to I_CADunningMasterDataOrigin as _CADunningMasterDataOrigin on $projection.CAOriginOfDunningMasterData = _CADunningMasterDataOrigin.CAOriginOfDunningMasterData
association [0..1] to I_CADunningProcedure as _CADunningProcedure on $projection.CADunningProcedure = _CADunningProcedure.CADunningProcedure
association [0..1] to I_CACollectionStrategy as _CACollectionStrategy on $projection.CACollectionStrategy = _CACollectionStrategy.CACollectionStrategy
association [0..1] to I_CACollMasterDataGroup as _CACollMasterDataGroup on $projection.CACollectionsMasterDataGroup = _CACollMasterDataGroup.CACollectionsMasterDataGroup
association [0..1] to I_BusinessPartner as _CACollectionsContactPerson on $projection.CACollectionsContactPerson = _CACollectionsContactPerson.BusinessPartner
association [0..1] to I_CAInvcgSchedule as _InvcgSchedule on $projection.CAInvcgSchedule = _InvcgSchedule.CAInvcgSchedule
association [0..1] to I_CAPaymentMasterDataOrigin as _CAPaymentMasterDataOrigin on $projection.CAOriginOfPaymentMasterData = _CAPaymentMasterDataOrigin.CAOriginOfPaymentMasterData
association [0..1] to I_CAPaymentMethod as _CAPaymentMethod on $projection.CAPaymentMethodForIncgPayment = _CAPaymentMethod.CAPaymentMethod
and $projection.CAReceivingCountry = _CAPaymentMethod.Country
association [0..1] to I_CARevnAcctgServiceType as _CARevnAcctgServiceType on $projection.CARevnAcctgRecrrgServiceType = _CARevnAcctgServiceType.CARevenueAccountingServiceType
association [0..1] to I_CARevnAcctgTransfRecdOrigin as _CARevnAcctgTransfRecdOrigin on $projection.CARevnAcctgTransfRecordOrigin = _CARevnAcctgTransfRecdOrigin.CARevnAcctgTransfRecordOrigin
association [1..1] to I_CARatingArea as _CARatingArea on $projection.CARatingArea = _CARatingArea.CARatingArea
association [1..1] to I_CASubscriptionChargeType as _CASubscriptionChargeType on $projection.CASubscriptionChargeType = _CASubscriptionChargeType.CASubscriptionChargeType
association [1..1] to I_CompanyCode as _CompCode on $projection.CompanyCode = _CompCode.CompanyCode
association [0..1] to I_CompanyCode as _CompCodeSup on $projection.CAIntcoCompanyCodeSupplying = _CompCodeSup.CompanyCode
association [1..1] to I_ContractAccountHeader as _ContrAcc on $projection.ContractAccount = _ContrAcc.ContractAccount
association [0..1] to I_Country as _Country on $projection.CAReceivingCountry = _Country.Country
association [0..1] to I_Division as _Division on $projection.Division = _Division.Division
association [1..1] to I_PaymentCondition as _PaymentCondition on $projection.PaymentCondition = _PaymentCondition.PaymentCondition
association [1..1] to I_ProviderContract as _PrvdrContr on $projection.ProviderContract = _PrvdrContr.ProviderContract
association [1..1] to I_ProviderContractStatus as _ProviderContractStatus on $projection.CAProviderContractStatus = _ProviderContractStatus.CAProviderContractStatus
association [0..1] to I_PrvdrContrItemChgReason as _PrvdrContrItemChgReason on $projection.CAPrvdrContrItmChgReason = _PrvdrContrItemChgReason.CAPrvdrContrItmChgReason
association [0..1] to I_Segment as _Segment on $projection.Segment = _Segment.Segment
{
@ObjectModel.foreignKey.association: '_PrvdrContr'
key vtkey as ProviderContract,
key vtpos as ProviderContractItem,
// administration data
erdat as CreationDate,
cast(ertim as ttet_dt_cr_time preserving type ) as CreationTime,
ernam as CreatedByUser,
aedat as LastChangeDate,
aetim as LastChangeTime,
aenam as LastChangedByUser,
// General data
vtpid as CAProviderContractItemUUID,
papid as CAPrvdrContrParentItemUUID,
valfr as CAPrvdrContrItmValidFromDteTme,
valto as CAPrvdrContrItmValidToDateTime,
cancl as CAPrvdrContrItemCanclnDateTime,
withdrawn_at as PrvdrContrItmWthdrwlDateTime,
@ObjectModel.foreignKey.association: '_ProviderContractStatus'
status as CAProviderContractStatus,
vtitt as CAProviderContractItemText,
@ObjectModel.foreignKey.association: '_ContrAcc'
vkont as ContractAccount,
ppacc as CAPrepaidAccount,
vttrg as CATechnicalResourceGroup,
srvrp as CAServiceRecipient,
adrsr as CAAddressIDOfServiceRecipient,
def_rec as PrvdrContrItmCorrespncRcpnt,
def_rec_adrnr as AddrIDOfCorrespncRcpnt,
prdnr as CAProduct,
cuobj as ProductConfiguration,
prdnr_sp as CASalesPackageProduct,
makey as CAMasterAgreement,
maprd as CAMasterAgreementProduct,
ptsrl as CAPartnerSettlementRule,
vtkrf as CASharingContract,
txjcd as TaxJurisdiction,
@ObjectModel.foreignKey.association: '_Country'
landl as CAReceivingCountry,
tax_country as TaxCountry,
@ObjectModel.foreignKey.association: '_CASubscriptionChargeType'
charge_type as CASubscriptionChargeType,
solution_order_id as BusinessSolutionOrder,
solution_order_item_id as BusinessSolutionOrderItem,
matnr_copa as SoldProduct,
@API.element: {
successor: 'EBRRResultAnalysisInternalID',
releaseState: #DEPRECATED }
@VDM.lifecycle: {
status: #DEPRECATED,
successor: 'EBRRResultAnalysisInternalID' }
rev_rec_key as RevenueRecognitionKey,
rev_rec_key as EBRRResultAnalysisInternalID,
bundling as EBRRIsBundleActive,
@Semantics.quantity.unitOfMeasure: 'CAProviderContractQuantityUnit'
quantity as CAProviderContractQuantity,
@Semantics.unitOfMeasure: true
quantity_unit as CAProviderContractQuantityUnit,
// General data 2 (Utility Fields)
uti_dso_bp as DistrSystOperatorBP,
uti_dso_maco_id as DistrSystOperatorMarketCommID,
uti_metop_bp as MeterOperatorBusinessPartner,
uti_metop_maco_id as MeterOperatorMarketCommID,
uti_malo_id as MarketLocationIdentifier,
// Organizational data
vkorg as SalesOrganization,
vtweg as DistributionChannel,
@ObjectModel.foreignKey.association: '_CompCode'
bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_CompCodeSup'
ico_bukrs_sup as CAIntcoCompanyCodeSupplying,
@ObjectModel.foreignKey.association: '_BusinessArea'
gsber as BusinessArea,
@ObjectModel.foreignKey.association: '_Segment'
segmt as Segment,
// @ObjectModel.foreignKey.association: '_ProfitCenter'
prctr as ProfitCenter,
@ObjectModel.foreignKey.association: '_Division'
spart as Division,
vber1 as CAPrvdrContrSalesAreaAttrib1,
vber2 as CAPrvdrContrSalesAreaAttrib2,
//ps_psp_pnr as WBSElementInternalID, //has conversion exit, not allowed anymore
cast( ps_psp_pnr as fis_wbsint_no_conv preserving type ) as WBSElementInternalID,
aufnr as InternalOrder,
stdsp as CAStandardDivision,
@Semantics.booleanIndicator
x_vt_copa as PrvdrContrItmIsRlvtForPrfSgDrv,
// Billing and Ivoicing data
@ObjectModel.foreignKey.association: '_BillgCycle'
cycle as CABillgCycle,
cycle_day as CALastDayOfBillingPeriod,
cycle_date as CABillgCyclePeriodStartDate,
@ObjectModel.foreignKey.association: '_InvcgSchedule'
inv_schedule as CAInvcgSchedule,
@ObjectModel.foreignKey.association: '_CARatingArea'
rating_area as CARatingArea,
@ObjectModel.foreignKey.association: '_BillgPln'
billplanno as CABillgPlnNumber,
// Consumption Billing
cb_soldto as CAConsumptionBillgSoldToParty,
cb_billto as CAConsumptionBillgInvoiceRcpnt,
cb_dzterm as ConsumptionBillingPaymentTerms,
cb_bemot as CnsmpnBillgBillableControl,
//cb_dzterm as PaymentTerms,
//cb_bemot as BillableControl,
cb_mndid as ConsumptionBillingSEPAMandate,
cb_ccard_id as CAConsumptionBillgPaymentCard,
//cb_ccard_id as CAPaymentCard,
// Revenue Accounting data
@Semantics.booleanIndicator
rarel as CAIsRevenueAccountingRelevant,
ra_mig_package as CARevenueAcctgMigrationPackage,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'CARevenueAccountingRefType'
ra_reftype as RevenueAccountingRefType,
ra_reftype as CARevenueAccountingRefType,
ra_refid as RevenueAccountingReference,
ra_srcdoc_id as CARevenueAcctgDocumentItem,
@Semantics.currencyCode: true
trprc_curr as TransactionPriceCurrency,
@Semantics.amount.currencyCode: 'TransactionPriceCurrency'
trprc as TransactionPrice,
@Semantics.amount.currencyCode: 'TransactionPriceCurrency'
trprc_total as TotalTransactionPrice,
trprc_freq_unit as TransacPriceRcrrcPerdTimeUnit,
// @Semantics.quantity.unitOfMeasure: 'TransacPriceRcrrcPerdTimeUnit'
trprc_freq_duration as TransacPriceRcrrcPerdDuration,
@Semantics.currencyCode: true
ssprc_curr as StandAloneSellingPriceCurrency,
@Semantics.amount.currencyCode: 'StandAloneSellingPriceCurrency'
ssprc as StandAloneSellingPrice,
@Semantics.amount.currencyCode: 'StandAloneSellingPriceCurrency'
ssprc_total as TotalStandAloneSellingPrice,
ssprc_freq_unit as SSPriceRecurrencePerdTimeUnit,
// @Semantics.quantity.unitOfMeasure: 'SSPriceRecurrencePerdTimeUnit'
ssprc_freq_duration as SSPriceRecurrencePerdDuration,
@ObjectModel.foreignKey.association: '_PrvdrContrItemChgReason'
chrsn as CAPrvdrContrItmChgReason,
valfrom_ctrterm as CAStartOfDurationDateTime,
valto_ctrterm as CAEndOfDurationDateTime,
@ObjectModel.foreignKey.association: '_CARevnAcctgServiceType'
recurr_service_type as CARevnAcctgRecrrgServiceType,
@ObjectModel.foreignKey.association: '_CARevnAcctgTransfRecdOrigin'
ra_oi_orig as CARevnAcctgTransfRecordOrigin,
// Payment Data
@ObjectModel.foreignKey.association: '_CAPaymentMasterDataOrigin'
pay_par_active as CAOriginOfPaymentMasterData,
@ObjectModel.foreignKey.association: '_PaymentCondition'
zahlkond as PaymentCondition,
@ObjectModel.foreignKey.association: '_CAPaymentMethod'
ezawe as CAPaymentMethodForIncgPayment,
abwre as CAAlternativePayer,
adrre as CAAddressIDOfAlternativePayer,
ebvty as CABankIDForIncomingPayments,
mndid as SEPAMandate,
ccard_id as CAPaymentCardIDForIncomingPayt,
azawe as CAPaymentMethodForOutgPayment,
abwra as CAAlternativePayee,
adrra as CAAddressIDOfAlternativePayee,
abvty as CABankIDForOutgoingPayments,
ccard_out as CAPaymentCardIDForOutgoingPayt,
pcard_guid as CAKeyForPaymentCardSupplement,
// Dunning Data
@ObjectModel.foreignKey.association: '_CADunningMasterDataOrigin'
dunn_par_active as CAOriginOfDunningMasterData,
@ObjectModel.foreignKey.association: '_CADunningProcedure'
mahnv as CADunningProcedure,
xdiscoexempt as CAServiceDisconncnIsProhibited,
@ObjectModel.foreignKey.association: '_CACollectionStrategy'
strat as CACollectionStrategy,
@ObjectModel.foreignKey.association: '_CACollMasterDataGroup'
cmgrp as CACollectionsMasterDataGroup,
@ObjectModel.foreignKey.association: '_CACollectionsContactPerson'
cpers as CACollectionsContactPerson,
// PEPPOL
bstkd as PurchaseOrderByCustomer,
bstdk as CustomerPurchaseOrderDate,
// Associations
_BillgCycle,
_BillgPln,
_BusinessArea,
_CADunningMasterDataOrigin,
_CADunningProcedure,
_CARatingArea,
_CAPaymentMasterDataOrigin,
_CARevnAcctgServiceType,
_CARevnAcctgTransfRecdOrigin,
_CASubscriptionChargeType,
_ContrAcc,
_CompCode,
_CompCodeSup,
_Country,
_Division,
_InvcgSchedule,
_PaymentCondition,
_CAPaymentMethod,
_ProviderContractStatus,
_PrvdrContr,
_PrvdrContrItemChgReason,
_Segment,
_CACollectionStrategy,
_CACollMasterDataGroup,
_CACollectionsContactPerson
}