I_Project
Project Definition Details
I_Project is a Basic CDS View (Dimension) that provides data about "Project Definition Details" in SAP S/4HANA. It reads from 1 data source (proj) and exposes 99 fields with key field Project. It has 21 associations to related views. Part of development package VDM_PS_ST.
Data Sources (1)
| Source | Alias | Join Type |
|---|---|---|
| proj | proj | from |
Associations (21)
| Cardinality | Target | Alias | Condition |
|---|---|---|---|
| [1..1] | I_ControllingArea | _ControllingArea | $projection.ControllingArea = _ControllingArea.ControllingArea |
| [1..1] | I_CompanyCode | _CompanyCode | $projection.CompanyCode = _CompanyCode.CompanyCode |
| [1..*] | I_CostCenter | _CostCenter | $projection.CostCenter = _CostCenter.CostCenter and $projection.ControllingArea = _CostCenter.ControllingArea |
| [1..*] | I_WBSElement | _WBSElement | $projection.ProjectInternalID = _WBSElement.ProjectInternalID |
| [1..1] | I_BusinessArea | _BusinessArea | $projection.BusinessArea = _BusinessArea.BusinessArea |
| [1..1] | I_Plant | _Plant | $projection.Plant = _Plant.Plant |
| [1..1] | I_ProjectProfileCode | _ProjectProfileCode | $projection.ProjectProfileCode = _ProjectProfileCode.ProjectProfileCode |
| [1..1] | I_ControllingObjectClass | _ControllingObjectClass | $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass |
| [1..*] | I_NetworkProfile | _NetworkProfile | $projection.NetworkProfile = _NetworkProfile.NetworkProfile |
| [1..1] | I_Interestcalculationprofile | _ProjInterestCalcProfile | $projection.ProjInterestCalcProfile = _ProjInterestCalcProfile.ProjInterestCalcProfile |
| [1..1] | I_FunctionalArea | _FunctionalArea | $projection.FunctionalArea = _FunctionalArea.FunctionalArea |
| [1..*] | I_TaxJurisdiction | _TaxJurisdiction | $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction |
| [1..*] | I_ProfitCenter | _ProfitCenter | $projection.ProfitCenter = _ProfitCenter.ProfitCenter and $projection.ControllingArea = _ProfitCenter.ControllingArea |
| [1..1] | I_Wbsschedulingprofile | _Wbsschedulingprofile | $projection.WBSSchedulingProfile = _Wbsschedulingprofile.WBSSchedulingProfile |
| [1..1] | I_PlanningMethod | _ProjBasicDatePlanMethName | $projection.PlanningMethForProjBasicDate = _ProjBasicDatePlanMethName.PlanningMethForProjBasicDate |
| [1..1] | I_PlanningMethod | _ProjFcstdDatePlanMethName | $projection.PlanningMethForProjFcstdDate = _ProjFcstdDatePlanMethName.PlanningMethForProjBasicDate |
| [1..1] | E_Project | _Extension | proj.pspid = _Extension.Project |
| [0..1] | I_ProjectResponsiblePerson | _ResponsiblePerson | $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson |
| [0..1] | I_ProjectApplicant | _ProjectApplicant | $projection.ApplicantCode = _ProjectApplicant.ApplicantCode |
| [0..1] | I_ProjectObjectShortText | _ProjectShortText | _ProjectShortText.Language = $session.system_language and _ProjectShortText.ProjectApplicationIdentifier = 'PS' and _ProjectShortText.ProjectObjectType = 'PD' and $projection.ProjectObject = _ProjectShortText.ProjectObjectNode |
| [0..1] | I_EntProjProjectRespPersn | _EntProjProjectRespPersn | $projection.ProjectInternalID = _EntProjProjectRespPersn.ProjectInternalID |
Annotations (17)
| Name | Value | Level | Field |
|---|---|---|---|
| EndUserText.label | Project Definition Details | view | |
| VDM.viewType | #BASIC | view | |
| Analytics.dataCategory | #DIMENSION | view | |
| AbapCatalog.compiler.compareFilter | true | view | |
| AbapCatalog.sqlViewName | IPROJECT | view | |
| AbapCatalog.preserveKey | true | view | |
| ObjectModel.representativeKey | Project | view | |
| AccessControl.authorizationCheck | #CHECK | view | |
| Metadata.allowExtensions | true | view | |
| ObjectModel.usageType.serviceQuality | #D | view | |
| ObjectModel.usageType.sizeCategory | #XL | view | |
| ObjectModel.usageType.dataClass | #MASTER | view | |
| ClientHandling.algorithm | #SESSION_VARIABLE | view | |
| AccessControl.personalData.blocking | #REQUIRED | view | |
| Metadata.ignorePropagatedAnnotations | true | view | |
| VDM.lifecycle.status | #DEPRECATED | view | |
| VDM.lifecycle.successor | I_ProjectData_2 | view |
Fields (99)
| Key | Field | Source Table | Source Field | Description |
|---|---|---|---|---|
| KEY | Project | proj | pspid | |
| ProjectWithCodingMask | proj | pspid_edit | ||
| ProjectInternalID | ||||
| ProjectDescription | ||||
| ProjectObject | proj | objnr | ||
| CreatedByUser | ||||
| CreationDate | ||||
| LastChangedByUser | ||||
| LastChangeDate | ||||
| ResponsiblePerson | ||||
| ResponsiblePersonName | ||||
| ApplicantCode | ||||
| ApplicantName | proj | astna | ||
| CompanyCode | ||||
| BusinessArea | ||||
| ControllingArea | ||||
| ProfitCenter | proj | prctr | ||
| Currency | ||||
| NetworkAssignmentType | proj | zuord | ||
| WBSElmntDatesIsDetailed | proj | trmeq | ||
| PlannedStartDate | ||||
| PlannedEndDate | ||||
| Plant | proj | werks | ||
| FactoryCalendar | ||||
| NetworkHdrIsVisibleToUser | proj | nzanz | ||
| NetworkProfile | proj | vprof | ||
| ProjectProfileCode | proj | profl | ||
| BudgetProfile | proj | bprof | ||
| Language | proj | txtsp | ||
| CostCenter | ||||
| CostObject | proj | ktrg | ||
| BasicDatesLastScheduledDate | proj | aedte | ||
| FcstdDatesLastScheduledDate | ||||
| ProjectHasOwnStock | ||||
| ControllingObjectClass | ||||
| WBSIsStatisticalWBSElement | proj | xstat | ||
| TaxJurisdiction | ||||
| ProjInterestCalcProfile | ||||
| InvestmentProfile | proj | imprf | ||
| PaymentPlanProfile | proj | fmprf | ||
| ResultAnalysisInternalID | proj | abgsl | ||
| PlanningProfile | proj | pprof | ||
| WBSIsMarkedForIntegratedPlng | proj | plint | ||
| IsMarkedForDeletion | ||||
| InventorySpecialStockValnType | proj | kzbws | ||
| WBSIsMarkedForAutomReqmtGrpg | proj | grtop | ||
| WorkCenterLocation | ||||
| FunctionalArea | ||||
| SalesOrganization | proj | vkorg | ||
| DistributionChannel | proj | vtweg | ||
| Division | proj | spart | ||
| DynItemProcessorPrfl | proj | dppprof | ||
| JointVenture | proj | vname | ||
| JointVentureCostRecoveryCode | proj | recid | ||
| JointVentureEquityType | proj | etype | ||
| JointVentureObjectType | proj | otype | ||
| JointVentureClass | proj | jibcl | ||
| JointVentureSubClass | proj | jibsa | ||
| PlanningMethForProjBasicDate | ||||
| PlanningMethForProjFcstdDate | ||||
| SchedulingDurationUnit | ||||
| WBSSchedulingProfile | ||||
| FreeDefinedTableFieldSemantic | proj | slwid | ||
| FreeDefinedAttribute01 | ||||
| FreeDefinedAttribute02 | ||||
| FreeDefinedAttribute03 | ||||
| FreeDefinedAttribute04 | ||||
| FreeDefinedQuantity1 | ||||
| FreeDefinedQuantity1Unit | ||||
| FreeDefinedQuantity2 | ||||
| FreeDefinedQuantity2Unit | ||||
| FreeDefinedAmount1 | ||||
| FreeDefinedAmount1Currency | ||||
| FreeDefinedAmount2 | ||||
| FreeDefinedAmount2Currency | ||||
| FreeDefinedDate1 | ||||
| FreeDefinedDate2 | ||||
| FreeDefinedIndicator1 | ||||
| FreeDefinedIndicator2 | ||||
| _ControllingArea | _ControllingArea | |||
| _CompanyCode | _CompanyCode | |||
| _BusinessArea | _BusinessArea | |||
| _CostCenter | _CostCenter | |||
| _Plant | _Plant | |||
| _WBSElement | _WBSElement | |||
| _ProjectProfileCode | _ProjectProfileCode | |||
| _ControllingObjectClass | _ControllingObjectClass | |||
| _NetworkProfile | _NetworkProfile | |||
| _ProjInterestCalcProfile | _ProjInterestCalcProfile | |||
| _FunctionalArea | _FunctionalArea | |||
| _TaxJurisdiction | _TaxJurisdiction | |||
| _Wbsschedulingprofile | _Wbsschedulingprofile | |||
| _ProfitCenter | _ProfitCenter | |||
| _ProjBasicDatePlanMethName | _ProjBasicDatePlanMethName | |||
| _ProjFcstdDatePlanMethName | _ProjFcstdDatePlanMethName | |||
| _ResponsiblePerson | _ResponsiblePerson | |||
| _ProjectApplicant | _ProjectApplicant | |||
| _ProjectShortText | _ProjectShortText | |||
| _EntProjProjectRespPersn | _EntProjProjectRespPersn |
@EndUserText.label: 'Project Definition Details'
@VDM.viewType: #BASIC
@Analytics: { dataCategory: #DIMENSION }
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IPROJECT'
@AbapCatalog.preserveKey:true
@ObjectModel.representativeKey: 'Project'
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions:true
//@AccessControl.privilegedAssociations: [ '_Extension' ]
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@Metadata.ignorePropagatedAnnotations:true
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_ProjectData_2'
//@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
//NOTE: TO BE USED ONLY FOR OP. FOR CLOUD USE I_PROJECTBASICDATA.
define view I_Project
as select from proj
association [1..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..*] to I_CostCenter as _CostCenter on $projection.CostCenter = _CostCenter.CostCenter
and $projection.ControllingArea = _CostCenter.ControllingArea
association [1..*] to I_WBSElement as _WBSElement on $projection.ProjectInternalID = _WBSElement.ProjectInternalID
association [1..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [1..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [1..1] to I_ProjectProfileCode as _ProjectProfileCode on $projection.ProjectProfileCode = _ProjectProfileCode.ProjectProfileCode
association [1..1] to I_ControllingObjectClass as _ControllingObjectClass on $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
association [1..*] to I_NetworkProfile as _NetworkProfile on $projection.NetworkProfile = _NetworkProfile.NetworkProfile
association [1..1] to I_Interestcalculationprofile as _ProjInterestCalcProfile on $projection.ProjInterestCalcProfile = _ProjInterestCalcProfile.ProjInterestCalcProfile
association [1..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [1..*] to I_TaxJurisdiction as _TaxJurisdiction on $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction
association [1..*] to I_ProfitCenter as _ProfitCenter on $projection.ProfitCenter = _ProfitCenter.ProfitCenter
and $projection.ControllingArea = _ProfitCenter.ControllingArea
association [1..1] to I_Wbsschedulingprofile as _Wbsschedulingprofile on $projection.WBSSchedulingProfile = _Wbsschedulingprofile.WBSSchedulingProfile
association [1..1] to I_PlanningMethod as _ProjBasicDatePlanMethName on $projection.PlanningMethForProjBasicDate = _ProjBasicDatePlanMethName.PlanningMethForProjBasicDate
association [1..1] to I_PlanningMethod as _ProjFcstdDatePlanMethName on $projection.PlanningMethForProjFcstdDate = _ProjFcstdDatePlanMethName.PlanningMethForProjBasicDate
// association [0..*] to I_Projecttext as _ProjLangBsdDescription on $projection.ProjectObject = _ProjLangBsdDescription.ProjectObject
association [1..1] to E_Project as _Extension on proj.pspid = _Extension.Project
// association [1..*] to I_PERSRESPONSIBLE as _Persresponsible on $projection.ResponsiblePersonName = _Persresponsible.ResponsiblePerson
// DPP Changes
// Person in Responsible for Project
association [0..1] to I_ProjectResponsiblePerson as _ResponsiblePerson on $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
// Project Applicant
association [0..1] to I_ProjectApplicant as _ProjectApplicant on $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
// Multilanguage Short text
association [0..1] to I_ProjectObjectShortText as _ProjectShortText on _ProjectShortText.Language = $session.system_language
and _ProjectShortText.ProjectApplicationIdentifier = 'PS'
and _ProjectShortText.ProjectObjectType = 'PD'
and $projection.ProjectObject = _ProjectShortText.ProjectObjectNode
// Responsible person for Project
association [0..1] to I_EntProjProjectRespPersn as _EntProjProjectRespPersn on $projection.ProjectInternalID = _EntProjProjectRespPersn.ProjectInternalID
{
@ObjectModel.text.element: 'ProjectDescription'
key proj.pspid as Project,
proj.pspid_edit /*Not finalized field - please donot use */ as ProjectWithCodingMask, //Not finalized field - please donot use
cast ( proj.pspnr as ps_s4_proj_pspnr preserving type ) as ProjectInternalID,
@Semantics.text: true
cast ( proj.post1 as ps_s4_proj_post1 ) as ProjectDescription,
// @ObjectModel.text.association:'_ProjLangBsdDescription'
proj.objnr as ProjectObject,
cast (proj.ernam as ernam ) as CreatedByUser,
cast (proj.erdat as erdat) as CreationDate,
cast ( proj.aenam as ps_s4_aenam ) as LastChangedByUser,
cast ( proj.aedat as ps_s4_aedat ) as LastChangeDate,
@ObjectModel.text.element: 'ResponsiblePersonName'
cast ( proj.vernr as ps_s4_vernr ) as ResponsiblePerson,
@Semantics.text: true
cast ( proj.verna as ps_s4_verna ) as ResponsiblePersonName,
@ObjectModel.text.element: 'ApplicantCode'
cast ( proj.astnr as ps_s4_astnr ) as ApplicantCode,
@Semantics.text: true
proj.astna as ApplicantName,
//--[ GENERATED:011:GFBfhyK17jY4gynYPGEfoG
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CompanyCodeStdVH',
element: 'CompanyCode' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_CompanyCode'
cast ( proj.vbukr as bukrs ) as CompanyCode,
//--[ GENERATED:011:GFBfhyK17jY4gynYPGEfoG
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_BusinessAreaStdVH',
element: 'BusinessArea' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_BusinessArea'
cast ( proj.vgsbr as gsber ) as BusinessArea,
//--[ GENERATED:011:GFBfhyK17jY4gynYPGEfoG
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_ControllingArea',
element: 'ControllingArea' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_ControllingArea'
cast ( proj.vkokr as kokrs ) as ControllingArea,
proj.prctr as ProfitCenter,
cast ( proj.pwhie as ps_pwhie ) as Currency,
proj.zuord as NetworkAssignmentType,
proj.trmeq as WBSElmntDatesIsDetailed,
@Semantics.calendar.dayOfMonth: true
cast ( proj.plfaz as bkk_odate_start ) as PlannedStartDate,
@Semantics.calendar.dayOfMonth: true
cast ( proj.plsez as ende_term ) as PlannedEndDate,
@ObjectModel.foreignKey.association: '_Plant'
proj.werks as Plant,
cast ( proj.kalid as appca ) as FactoryCalendar,
proj.nzanz as NetworkHdrIsVisibleToUser,
proj.vprof as NetworkProfile,
proj.profl as ProjectProfileCode,
proj.bprof as BudgetProfile,
@Semantics.language
proj.txtsp as Language,
//--[ GENERATED:011:GFBfhyK17jY4gynYPGEfoG
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_CostCenterStdVH',
element: 'CostCenter' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_CostCenter'
cast ( proj.kostl as kostl ) as CostCenter,
proj.ktrg as CostObject,
@Semantics.calendar.dayOfMonth: true
proj.aedte as BasicDatesLastScheduledDate,
@Semantics.calendar.dayOfMonth: true
cast ( proj.aedtp as ps_aedtp ) as FcstdDatesLastScheduledDate,
cast ( proj.besta as psb_stock ) as ProjectHasOwnStock,
cast ( proj.scope as ps_s4_scope_cv ) as ControllingObjectClass,
proj.xstat as WBSIsStatisticalWBSElement,
cast ( proj.txjcd as wb2_txjcd_busvol ) as TaxJurisdiction,
cast ( proj.zschm as ps_zschm ) as ProjInterestCalcProfile,
proj.imprf as InvestmentProfile,
proj.fmprf as PaymentPlanProfile,
proj.abgsl as ResultAnalysisInternalID,
proj.pprof as PlanningProfile,
proj.plint as WBSIsMarkedForIntegratedPlng,
cast ( proj.loevm as ps_s4_loevm ) as IsMarkedForDeletion,
proj.kzbws as InventorySpecialStockValnType,
proj.grtop as WBSIsMarkedForAutomReqmtGrpg,
cast ( proj.stort as ps_stort ) as WorkCenterLocation,
cast ( proj.func_area as fkber ) as FunctionalArea,
proj.vkorg as SalesOrganization,
proj.vtweg as DistributionChannel,
proj.spart as Division,
proj.dppprof as DynItemProcessorPrfl,
proj.vname as JointVenture,
proj.recid as JointVentureCostRecoveryCode,
proj.etype as JointVentureEquityType,
proj.otype as JointVentureObjectType,
proj.jibcl as JointVentureClass,
proj.jibsa as JointVentureSubClass,
@Semantics.calendar.dayOfMonth: true
cast ( proj.sprog as pshlp_forecast_start_de ) as ForecastedStartDate,
@Semantics.calendar.dayOfMonth: true
cast ( proj.eprog as ps_s4_forecast_finish ) as ForecastedEndDate,
cast ( proj.vgplf as ps_s4_vgplf ) as PlanningMethForProjBasicDate,
cast ( proj.ewplf as ps_s4_ewplf ) as PlanningMethForProjFcstdDate,
cast ( proj.zteht as cgpl_duration_unit ) as SchedulingDurationUnit,
cast ( proj.scprf as ps_s4_schdprf ) as WBSSchedulingProfile,
proj.slwid as FreeDefinedTableFieldSemantic,
cast ( proj.usr00 as usr00prps preserving type ) as FreeDefinedAttribute01,
cast ( proj.usr01 as usr01prps preserving type ) as FreeDefinedAttribute02,
cast ( proj.usr02 as usr02prps preserving type ) as FreeDefinedAttribute03,
cast ( proj.usr03 as usr03prps preserving type ) as FreeDefinedAttribute04,
@Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity1Unit'
cast ( proj.usr04 as usr04prps preserving type ) as FreeDefinedQuantity1,
cast ( proj.use04 as use04prps preserving type ) as FreeDefinedQuantity1Unit,
@Semantics.quantity.unitOfMeasure:'FreeDefinedQuantity2Unit'
cast ( proj.usr05 as usr05prps preserving type ) as FreeDefinedQuantity2,
cast ( proj.use05 as use05prps preserving type ) as FreeDefinedQuantity2Unit,
@Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
cast ( proj.usr06 as usr06prps preserving type ) as FreeDefinedAmount1,
cast ( proj.use06 as use06prps preserving type ) as FreeDefinedAmount1Currency,
@Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
cast ( proj.usr07 as usr07prps preserving type ) as FreeDefinedAmount2,
cast ( proj.use07 as use07prps preserving type ) as FreeDefinedAmount2Currency,
cast ( proj.usr08 as usr08prps preserving type ) as FreeDefinedDate1,
cast ( proj.usr09 as usr09prps preserving type ) as FreeDefinedDate2,
cast ( proj.usr10 as usr10prps preserving type ) as FreeDefinedIndicator1,
cast ( proj.usr11 as usr11prps preserving type ) as FreeDefinedIndicator2,
_ControllingArea,
_CompanyCode,
_BusinessArea,
_CostCenter,
_Plant,
_WBSElement,
_ProjectProfileCode,
_ControllingObjectClass,
//_ProjLangBsdDescription,
_NetworkProfile,
_ProjInterestCalcProfile,
_FunctionalArea,
_TaxJurisdiction,
_Wbsschedulingprofile,
_ProfitCenter,
_ProjBasicDatePlanMethName,
_ProjFcstdDatePlanMethName,
@UI.hidden: true
@Consumption.hidden: true
_ResponsiblePerson,
@UI.hidden: true
@Consumption.hidden: true
_ProjectApplicant,
_ProjectShortText,
//Responsible Person for Project
_EntProjProjectRespPersn
}
Learn More
- What Is a CDS View in SAP S/4HANA?
- Types of CDS Views: Basic, Composite, Consumption, and Transactional
- SAP Tables vs CDS Views — Key Differences
- Understanding Data Lineage in SAP S/4HANA
- VDM (Virtual Data Model) in SAP S/4HANA Explained
- CDS View Annotations — A Complete Guide
- CDS View Field Mapping and Associations
- Understanding the SAP S/4HANA Data Model
- CDS View Extensions and Custom Fields in SAP S/4HANA
- Released APIs and Stability Contracts in SAP S/4HANA