C_ReExAssignProject

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CREEXASSIGNPROJ'
@AbapCatalog.compiler.compareFilter: true
@AccessControl: { authorizationCheck: #CHECK,
                  personalData.blocking: #REQUIRED }
@EndUserText.label: 'Project'
@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MIXED
@Search.searchable: true
define view C_ReExAssignProject as select from I_Project

{
      @Search.defaultSearchElement: true 
      @Search.ranking: #HIGH
  key I_Project.Project                                                  as Project,
      I_Project.ProjectInternalID                                        as ProjectInternalID,
      @Semantics.text: true
      I_Project.ProjectDescription                                       as ProjectDescription,
      I_Project.ProjectObject                                            as ProjectObject,
      @ObjectModel.text.element: 'ResponsiblePersonName'
//      I_Project.ResponsiblePerson                                        as ResponsiblePerson,

      cast(  case
               when ResponsiblePerson = '00000000' or ResponsiblePerson is null
                  then _EntProjProjectRespPersn.PersonWorkAgreement
                else
                  ResponsiblePerson
              end as persno preserving type ) as ResponsiblePerson,
      @Semantics.text: true
//      I_Project.ResponsiblePersonName                                    as ResponsiblePersonName,

        cast(  case
                 when ResponsiblePerson = '00000000' or ResponsiblePerson is null
                    then _EntProjProjectRespPersn._WorkforcePerson.PersonFullName
                  else
                    ResponsiblePersonName
                end as ad_namtext preserving type ) as ResponsiblePersonName,
      I_Project.CompanyCode                                              as CompanyCode,
      I_Project.BusinessArea                                             as BusinessArea,
      I_Project.ControllingArea                                          as ControllingArea,
      I_Project.ProfitCenter                                             as ProfitCenter,

      I_Project.Currency                                                 as Currency,
      @Semantics.calendar.dayOfMonth: true
      I_Project.PlannedStartDate                                         as PlannedStartDate,
      @Semantics.calendar.dayOfMonth: true
      I_Project.PlannedEndDate                                           as PlannedEndDate,
      I_Project.Plant                                                    as Plant,
      @Semantics.language
      I_Project.Language                                                 as Language,
      I_Project.CostCenter                                               as CostCenter,
      I_Project.CostObject                                               as CostObject,
      @Semantics.calendar.dayOfMonth: true
      I_Project.BasicDatesLastScheduledDate                              as BasicDatesLastScheduledDate,
      @Semantics.calendar.dayOfMonth: true
      I_Project.FcstdDatesLastScheduledDate                              as FcstdDatesLastScheduledDate,
      I_Project.FunctionalArea                                           as FunctionalArea,
      I_Project.SalesOrganization                                        as SalesOrganization,
      I_Project.DistributionChannel                                      as DistributionChannel,
      I_Project.Division                                                 as Division,
      @Semantics.calendar.dayOfMonth: true
      I_Project.ForecastedStartDate                                      as ForecastedStartDate,
      @Semantics.calendar.dayOfMonth: true
      I_Project.ForecastedEndDate                                        as ForecastedEndDate,
      @UI.hidden: true
      @Consumption.filter.hidden: true      
      _ResponsiblePerson.ResponsiblePersonIsBlocked,
//      _ResponsiblePerson,

      @UI.hidden: true
      @Consumption.filter.hidden: true  
      I_Project._EntProjProjectRespPersn      


}