I_ProductionVersionBasic

@AbapCatalog.sqlViewName: 'IPRODNVERSNBASC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'ProductionVersion'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #MASTER}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Production Version Basic'

define view I_ProductionVersionBasic
  as select from mkal

  association [1..1] to I_Product                    as _Product                     on  $projection.Product = _Product.Product
  association [1..1] to I_Plant                      as _Plant                       on  $projection.Plant = _Plant.Plant
  association [1..1] to I_ProductPlant               as _ProductPlant                on  $projection.Product = _ProductPlant.Product
                                                                                     and $projection.Plant    = _ProductPlant.Plant
  association [0..1] to I_ProductPlantBasic          as _ProductPlant2               on  $projection.Plant   = _ProductPlant2.Plant
                                                                                     and $projection.Product = _ProductPlant2.Product
  association [0..1] to I_Product                    as _MainProduct                 on  $projection.MainProduct = _MainProduct.Product
  association [0..1] to I_Product                    as _OriglBatchReferenceMaterial on  $projection.OriginalBatchReferenceMaterial = _OriglBatchReferenceMaterial.Product
  association [1..1] to I_BillOfOperationsType       as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [1..1] to I_BillOfOperationsGroup      as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                     and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [1..1] to I_BillOfOperations           as _BillOfOperations            on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                     and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                     and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [0..1] to I_ProductionLine             as _ProductionLine              on  $projection.Plant          = _ProductionLine.Plant
                                                                                     and $projection.ProductionLine = _ProductionLine.ProductionLine
  association [0..1] to I_ProductionVersionGroup     as _ProductionVersionGroup      on  $projection.Plant                  = _ProductionVersionGroup.Plant
                                                                                     and $projection.ProductionVersionGroup = _ProductionVersionGroup.ProductionVersionGroup
  association [0..1] to I_ProductionSupplyArea       as _ProductionSupplyArea        on  $projection.Plant                = _ProductionSupplyArea.Plant
                                                                                     and $projection.ProductionSupplyArea = _ProductionSupplyArea.ProductionSupplyArea
  association [0..1] to I_ProductionSupplyArea       as _TargetProductionSupplyArea  on  $projection.Plant                = _TargetProductionSupplyArea.Plant
                                                                                     and $projection.TargetProductionSupplyArea = _TargetProductionSupplyArea.ProductionSupplyArea
  association [0..1] to I_StorageLocation            as _IssuingStorageLocation      on  $projection.Plant                  = _IssuingStorageLocation.Plant
                                                                                     and $projection.IssuingStorageLocation = _IssuingStorageLocation.StorageLocation
  association [0..1] to I_StorageLocation            as _ReceivingStorageLocation    on  $projection.Plant                    = _ReceivingStorageLocation.Plant
                                                                                     and $projection.ReceivingStorageLocation = _ReceivingStorageLocation.StorageLocation
  association [0..1] to I_MatlCostApportionmentStruc as _MatlCostApportionmentStruc  on  $projection.Material                       = _MatlCostApportionmentStruc.Material
                                                                                     and $projection.Plant                          = _MatlCostApportionmentStruc.Plant
                                                                                     and $projection.MaterialCostApportionmentStruc = _MatlCostApportionmentStruc.MaterialCostApportionmentStruc
  association [0..1] to I_MRPQuantityDistributionKey as _QuantityDistributionKey     on  $projection.Plant                   = _QuantityDistributionKey.Plant
                                                                                     and $projection.QuantityDistributionKey = _QuantityDistributionKey.QuantityDistributionKey
  association [0..1] to I_UnitOfMeasure              as _MaterialBaseUnit            on  $projection.MaterialBaseUnit = _MaterialBaseUnit.UnitOfMeasure
  association [1..1] to I_Material                   as _Material                    on  $projection.Material = _Material.Material
{
      // Key

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductStdVH', element: 'Product' } } ]
      @ObjectModel.foreignKey.association: '_Product'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key cast(matnr as productnumber preserving type)             as Product,
      @ObjectModel.foreignKey.association: '_Plant'
  key werks                                                    as Plant,
      @ObjectModel.text.element: ['ProductionVersionText']
  key verid                                                    as ProductionVersion,

      // Text

      @Semantics.text: true
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      text1                                                    as ProductionVersionText,

      // kept for compatibility reason (metadata extension)

      @ObjectModel.foreignKey.association: '_Material'
      matnr                                                    as Material,

      // Key of Bill of Operations (BOO, e.g. Routing)

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      cast(plnty as billofoperationstype preserving type)      as BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      cast(plnnr as billofoperationsgroup preserving type)     as BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
      cast(alnal as billofoperationsvariant preserving type)   as BillOfOperationsVariant,
      // Key for Bill of Material (BOM) in addition to matnr and werks

      stlan                                                    as BillOfMaterialVariantUsage,
      stlal                                                    as BillOfMaterialVariant,

      // Assignments

      --@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionLineStdVH', element: 'ProductionLine' } } ]
      @Consumption.valueHelpDefinition: [{entity:{name:'I_WRKCTRBYSEMANTICKEYSTDVH' , element: 'WorkCenter'}}]
      @ObjectModel.foreignKey.association: '_ProductionLine'
      mdv01                                                    as ProductionLine,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionSupplyAreaStdVH', element: 'ProductionSupplyArea' } } ]
      @ObjectModel.foreignKey.association: '_ProductionSupplyArea'
      cast(prvbe as pph_prvbe  preserving type)                as ProductionSupplyArea,
      @ObjectModel.foreignKey.association: '_ProductionVersionGroup'
      cast(mdv02 as pph_mdv   preserving type)                 as ProductionVersionGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductStdVH', element: 'Product' } } ]
      @ObjectModel.foreignKey.association: '_MainProduct'
      cast(matko as pph_matko  preserving type)                as MainProduct,
      @ObjectModel.foreignKey.association: '_MatlCostApportionmentStruc'
      csplt                                                    as MaterialCostApportionmentStruc,
      @ObjectModel.foreignKey.association: '_IssuingStorageLocation'
      elpro                                                    as IssuingStorageLocation,
      @ObjectModel.foreignKey.association: '_ReceivingStorageLocation'
      alort                                                    as ReceivingStorageLocation,
      @ObjectModel.foreignKey.association: '_OriglBatchReferenceMaterial'
      cast(ucmat as pph_rfmat  preserving type)                as OriginalBatchReferenceMaterial,
      @ObjectModel.foreignKey.association: '_QuantityDistributionKey'
      verto                                                    as QuantityDistributionKey,
      prfg_f                                                   as ProductionVersionStatus,
      cast(prdat as pph_mkprdat preserving type)               as ProductionVersionLastCheckDate,
      cast(prfg_r as pph_prfgr  preserving type)               as RateBasedPlanningStatus,
      cast(prfg_g as pph_prfgg  preserving type)               as PreliminaryPlanningStatus,
      cast(prfg_s as pph_prfgs  preserving type)               as BOMCheckStatus,

      // Attributes

      @Semantics.businessDate.from: true
      cast(adatu as vdm_v_validity_start_date preserving type) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast(bdatu as vdm_v_validity_end_date preserving type)   as ValidityEndDate,
      @Semantics.booleanIndicator 
      case mksp                                                
        when '1' then 'X' 
        when '2' then 'X' 
        else ''
      end                                                      as ProductionVersionIsLocked,
      serkz                                                    as ProdnVersIsAllowedForRptvMfg,
      versind                                                  as HasVersionCtrldBOMAndRouting,
      diffplanexemstr                                          as PlanningAndExecutionBOMIsDiff,
      
      // Shop Floor BOM

      exe_stlan                                                as ExecBillOfMaterialVariantUsage,
      exe_stlal                                                as ExecBillOfMaterialVariant,
      exe_plnty                                                as ExecBillOfOperationsType,
      exe_plnnr                                                as ExecBillOfOperationsGroup,
      exe_alnal                                                as ExecBillOfOperationsVariant,
      
      // EWM data

      ewm_lgnum                                                as Warehouse,
      ewm_lgpla                                                as DestinationStorageBin,
      @ObjectModel.foreignKey.association: '_TargetProductionSupplyArea'
      cast(tsa_prvbe as tsa_prvbe preserving type)             as TargetProductionSupplyArea,
      
      // Quantity and UoM

      @Semantics.unitOfMeasure: true      
      _Product.BaseUnit                                        as MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @Aggregation.default: #MIN
      bstmi                                                    as MaterialMinLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @Aggregation.default: #MAX
      bstma                                                    as MaterialMaxLotSizeQuantity,

      // kept for compatibility reasons

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'QuantityDistributionKey'
      verto                                                    as DistributionKey,
      
      // Associations

      _Product,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ProductPlant2'
      _ProductPlant,
      _ProductPlant2,
      _Plant,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperations,
      _ProductionLine,
      _ProductionVersionGroup,
      _ProductionSupplyArea,
      _TargetProductionSupplyArea,
      _MainProduct,
      _OriglBatchReferenceMaterial,
      _IssuingStorageLocation,
      _ReceivingStorageLocation,
      _MatlCostApportionmentStruc,
      _QuantityDistributionKey,      
      _Material,
      _MaterialBaseUnit
};