I_ProdAssgblToExplctModuleTP

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@EndUserText.label: 'Product Assignable to Assortment Module'

@VDM: {
  viewType: #TRANSACTIONAL,

  lifecycle: {
    contract: {
      type: #SAP_INTERNAL_API
    }
  }
}
@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #MASTER
   },
   sapObjectNodeType.name: 'Product'
}

@Metadata.ignorePropagatedAnnotations: true

define root view entity I_ProdAssgblToExplctModuleTP
  as select distinct from I_Product                    as Product
    inner to one join     I_AsstmtMdlMgmtSolnGenSetting                           on I_AsstmtMdlMgmtSolnGenSetting.AsstmtMdlMgmtSolnIsEnbld = 'X'

    inner join            I_ProdToExplicitAsstmtModule as ProdExplctAssortmentMdl on Product.Product = ProdExplctAssortmentMdl.Product

  association [0..*] to I_ProdToExplicitAsstmtMdlTP as _ProductAssortMdlListing on $projection.Product = _ProductAssortMdlListing.Product

  association [0..1] to I_ArticleHierNodeToProduct  as _ArticleHierNode         on $projection.Product = _ArticleHierNode.Product
{

  key Product.Product                                                                                as Product,
      cast( 'X' as rfm_asm_prd_asgnd_to_expl_mod preserving type )                                   as ProdIsLstdInAnyExplctAsstmtMdl,
      cast ( Product.ProductGroup as  rfm_mrchdscategory preserving type   ) as ProductGroup,
      Product.ProductCategory,
      Product.ProductType,
      Product.AuthorizationGroup,
      Product.ProductStandardID,
      cast ( Product.CrossPlantConfigurableProduct as rfm_asm_crossplant_conf_prod preserving type ) as CrossPlantConfigurableProduct,
      _ArticleHierNode.HierarchyID                                                                   as HierarchyID,
      _ArticleHierNode.RetailArticleHierarchyNode                                                    as RetailArticleHierarchyNode,

      _ArticleHierNode,
      _ArticleHierNode._NodeText                                                                     as _ArtHierNodeText,
      _ArticleHierNode._ActiveArticleHierarchy                                                       as _ActiveArticleHierarchy,
      Product._Text,
      Product._ProductType,
      Product._ProductCategory,
      Product._ProductGroup,
      Product._ProductGroup_2,
      Product._CrossPlantConfigurableProduct,

      _ProductAssortMdlListing
}
where
       Product.ProductCategory     <> ''
  and(
       Product.ProductCategory     =  '00'
    or Product.ProductCategory     =  '02'
    or Product.ProductCategory     =  '10'
    or Product.ProductCategory     =  '11'
    or Product.ProductCategory     =  '12'
  )
  and  Product.IsMarkedForDeletion =  ' '

union all select distinct from I_Product                    as Product
  inner to one join            I_AsstmtMdlMgmtSolnGenSetting                           on I_AsstmtMdlMgmtSolnGenSetting.AsstmtMdlMgmtSolnIsEnbld = 'X'
  left outer join              I_ProdToExplicitAsstmtModule as ProdExplctAssortmentMdl on Product.Product = ProdExplctAssortmentMdl.Product

association [0..*] to I_ProdToExplicitAsstmtMdlTP as _ProductAssortMdlListing on $projection.Product = _ProductAssortMdlListing.Product

association [0..1] to I_ArticleHierNodeToProduct  as _ArticleHierNode         on $projection.Product = _ArticleHierNode.Product
{

  key Product.Product                                                                                as Product,
      cast( ' ' as rfm_asm_prd_asgnd_to_expl_mod preserving type )                                   as ProdIsLstdInAnyExplctAsstmtMdl,
      cast ( Product.ProductGroup as  rfm_mrchdscategory preserving type   ) as ProductGroup,
      Product.ProductCategory,
      Product.ProductType,
      Product.AuthorizationGroup,
      Product.ProductStandardID,
      cast ( Product.CrossPlantConfigurableProduct as rfm_asm_crossplant_conf_prod preserving type ) as CrossPlantConfigurableProduct,
      _ArticleHierNode.HierarchyID                                                                   as HierarchyID,
      _ArticleHierNode.RetailArticleHierarchyNode                                                    as RetailArticleHierarchyNode,

      _ArticleHierNode,
      _ArticleHierNode._NodeText                                                                     as _ArtHierNodeText,
      _ArticleHierNode._ActiveArticleHierarchy                                                       as _ActiveArticleHierarchy,
      Product._Text,
      Product._ProductType,
      Product._ProductCategory,
      Product._ProductGroup,
      Product._ProductGroup_2,
      Product._CrossPlantConfigurableProduct,

      _ProductAssortMdlListing
}
where
       ProdExplctAssortmentMdl.AssortmentModuleUUID is null
  and  Product.ProductCategory                      <> ''
  and(
       Product.ProductCategory                      =  '00'
    or Product.ProductCategory                      =  '02'
    or Product.ProductCategory                      =  '10'
    or Product.ProductCategory                      =  '11'
    or Product.ProductCategory                      =  '12'
  )
  and  Product.IsMarkedForDeletion                  =  ' ';