I_ProdAllocCharcCtlgPathTP

@AbapCatalog.sqlViewName: 'IPACTLG_PATHTP'
@AbapCatalog.compiler.compareFilter:true
@EndUserText.label: 'Product Allocation Characteristic Catalog Path'
@ObjectModel.writeDraftPersistence: 'PACTLG_PATHD'
@ObjectModel.writeActivePersistence: 'PACTLG_PATH'
@VDM.viewType: #TRANSACTIONAL 
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.representativeKey: ['ProdAllocCharcCtlgPathUUID']
@AccessControl.authorizationCheck: #NOT_REQUIRED   //or #CHECK

@Search.searchable: true
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.semanticKey: ['ProdAllocCharcCatalogType', 
                           'ProdAllocCharcCatalogUseType',
                           'ProdAllocCharcCtlgPathSelName', 
                           'ProdAllocCharcCtlgPathSel', 
                           'ProdAllocCharcCatalogPath']
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass:#MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE

@Consumption.dbHints: [ 'NO_USE_HEX_PLAN' ]

define view I_ProdAllocCharcCtlgPathTP
  as select from I_ProdAllocCharcCatalogPath as Document
  association [1..1] to I_ProdAllocCharcCatalogTP     as _ProdAllocCharcCatalogTP       on  _ProdAllocCharcCatalogTP.ProdAllocCharcCatalogUUID    = $projection.ProdAllocCharcCatalogUUID
                                                                                        //and _ProdAllocCharcCatalogWD.ActiveProdAllocCharcCtlgUUID = $projection.activeprodalloccharcctlguuid

  association [0..*] to I_AllocCharcCtlgPathTTP       as _AllocCharcCtlgPathTTP         on  _AllocCharcCtlgPathTTP.ProdAllocCharcCtlgPathUUID   = $projection.ProdAllocCharcCtlgPathUUID
                                                                                         //and _AllocCharcCtlgPathTWD.ActiveAllocCharcCtlgPathUUID = $projection.activealloccharcctlgpathuuid

  association [0..*] to I_ProdAllocCharcCtlgPathRefTP as _ProdAllocCharcCtlgPathRefTP   on _ProdAllocCharcCtlgPathRefTP.ProdAllocCharcCtlgPathUUID = $projection.ProdAllocCharcCtlgPathUUID     
  association [0..*] to I_AllocCharcCtlgValGrpValTP   as _AllocCharcCtlgValGrpValTP     on _AllocCharcCtlgValGrpValTP.ProdAllocCharcCtlgPathUUID =  $projection.ProdAllocCharcCtlgPathUUID                                                                            
  association [0..1] to I_ProdAllocCharcCatalogType   as _ProdAllocCharcCatalogType     on  _ProdAllocCharcCatalogType.ProdAllocCharcCatalogType = $projection.ProdAllocCharcCatalogType 
  association [0..1] to I_ProdAllocCharcCtlgUseType   as _ProdAllocCharcCtlgUseType     on _ProdAllocCharcCtlgUseType.ProdAllocCharcCatalogUseType = $projection.ProdAllocCharcCatalogUseType 
  association [0..1] to I_ProdAllocCharcCtlgCharcType as _ProdAllocCharcCtlgCharcType   on  _ProdAllocCharcCtlgCharcType.ProdAllocCharcCatalogCharcType = $projection.ProdAllocCharcCatalogCharcType
  association [0..1] to I_ProdAllocCharcCtlgPathType  as _ProdAllocCharcCtlgPathType    on  _ProdAllocCharcCtlgPathType.ProdAllocCharcCatalogPathType = $projection.ProdAllocCharcCatalogPathType
  association [0..*] to I_ProdAllocCharcCatalogPath   as _NextLvlProdAllocCharcCtlgPath on  _NextLvlProdAllocCharcCtlgPath.ProdAllocCharcCtlgParPathIntID = $projection.ProdAllocCharcCtlgPathIntID
  association [0..1] to I_ProdAllocCharcCtlgPathTP    as _ParProdAllocCharcCtlgPathTP   on $projection.ProdAllocCharcCtlgParPathIntID = _ParProdAllocCharcCtlgPathTP.ProdAllocCharcCtlgPathIntID
  association [0..*] to I_DataElementLabelText        as _DataElementLabelText          on  _DataElementLabelText.ABAPDataElement = $projection.ABAPDataElement
  association [0..*] to I_PartnerFunctionText         as _PartnerFunctionText           on  _PartnerFunctionText.PartnerFunction = $projection.ProdAllocCharcCtlgPathSel
  association [0..1] to I_ProdAllocCharcCtlgPathRefTP as _MainCharcCtlgPathRefTP        on _MainCharcCtlgPathRefTP.ProdAllocCharcCtlgPathUUID = $projection.ProdAllocCharcCtlgPathUUID
                                                                                          and _MainCharcCtlgPathRefTP.ProdAllocCharcCatalogIsMain = 'X'
  
  association [0..*] to I_AllocCharcCtlgPathTTP       as _GrpAllocCharcCtlgPathTTP      on  _GrpAllocCharcCtlgPathTTP.ProdAllocCharcCtlgPathUUID   = $projection.ProdAllocCharcCtlgPathUUID
  association [0..*] to I_AllocCharcCtlgPathTTP       as _ClfnAllocCharcCtlgPathTTP      on _ClfnAllocCharcCtlgPathTTP.ProdAllocCharcCtlgPathUUID  = $projection.ProdAllocCharcCtlgPathUUID
  association [0..1] to I_CharcValExistenceCheckType  as _CharcValExistenceCheckType    on _CharcValExistenceCheckType.CharcValExistenceCheckType = $projection.CharcValExistenceCheckType 
  association [0..1] to I_CharacteristicValueGroupType as _CharacteristicValueGroupType on _CharacteristicValueGroupType.CharacteristicValueGroupType = $projection.CharacteristicValueGroupType
  association [0..1] to I_UnitOfMeasure               as _CharacteristicUnitOfMeasure   on $projection.CharacteristicUnit = _CharacteristicUnitOfMeasure.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _ValueGroupUnitOfMeasure       on $projection.CharacteristicValueGroupUnit = _ValueGroupUnitOfMeasure.UnitOfMeasure
  
  //  association [0..1] to I_ProdAllocCharcCtlgPathWD    as _SiblingEntity                 on  _SiblingEntity.ActiveAllocCharcCtlgPathUUID = $projection.ActiveAllocCharcCtlgPathUUID

  //                                                                                        and _SiblingEntity.IsActiveEntity               <> $projection.IsActiveEntity

  //  association [0..1] to I_DraftAdministrativeData     as _DraftAdministrativeData       on  _DraftAdministrativeData.DraftUUID = $projection.DraftAdministrativeDataUUID

{

      @ObjectModel.text.association: '_AllocCharcCtlgPathTTP'
  key Document.ProdAllocCharcCtlgPathUUID,  

      Document.ProdAllocCharcCtlgPathIntID,      
      Document.ProdAllocCharcCatalogType,
      Document.ProdAllocCharcCatalogUseType,
      @ObjectModel.foreignKey.association: '_ProdAllocCharcCatalogTP'
      Document.ProdAllocCharcCatalogUUID,
      //      Document.ActiveProdAllocCharcCtlgUUID,

      Document.ProdAllocCharcCtlgParPathIntID,
      Document.CharacteristicUnitPathIntID,
      Document.ProdAllocCharcCatalogCharcType,
      Document.ProdAllocCharcCatalogPathType,
      Document.ClfnCharacteristicUseType,
      Document.CharcCatalogPathHierarchyType,
      
      @ObjectModel.text.association: '_DataElementLabelText'
      Document.ABAPDataElement,
      Document.ProdAllocCharcCtlgPathSelName,
      Document.ProdAllocCharcCtlgPathSel,
      Document.ProdAllocCharcCatalogPath,
      Document.ProdAllocCharcCtlgAltvPath,
      Document.ProdAllocCharcCtlgLegacyTable,
      Document.ProdAllocCharcCtlgLegacyPath,
      Document.ProdAllocCharcValueHelp,
      Document.ProdAllocCharcValHelpTblField,
      Document.ProdAllocCharcValHelpTextLink,
      Document.ProdAllocCharcValHelpTxtTblFld,
      Document.ProdAllocCharcCtlgCharc,
      Document.ProdAllocCharcCtlgPathIsHidden,
      Document.ProdAllocCharcCtlgPathIsRoot,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.CharcValExistenceCheckType,
      Document.ABAPDictionaryDataType,      
      Document.ABAPDictionaryDataTypeLength,      
      Document.ABAPDictionaryDataTypeDecimals,      
      Document.ABAPOutputLengthValue,      
      Document.CharcValueIsCaseSensitive,      
      Document.CharcValueConversionRoutine,    
      Document.CharcInternalID,
      Document.CharacteristicUnit,
      Document.CharacteristicValueGroupUnit,
      @ObjectModel.foreignKey.association: '_CharacteristicValueGroupType'
      Document.CharacteristicValueGroupType,
      Document.CharcIsOnlyUsableInValueGroups,
      Document.CharcCatalogCharacteristicName,
           
      //      @ObjectModel.readOnly: true

      //     Document.IsActiveEntity,

      //      @ObjectModel.readOnly: true

      //      Document.HasActiveEntity,

      //      @ObjectModel.readOnly: true

      //      Document.HasDraftEntity,

      //      @Consumption.hidden: true

      //      Document.DraftAdministrativeDataUUID,

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ProdAllocCharcCatalogTP,
      
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _AllocCharcCtlgPathTTP,
      
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ProdAllocCharcCtlgPathRefTP,
      
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _AllocCharcCtlgValGrpValTP,
      
      _GrpAllocCharcCtlgPathTTP,
      
      _ClfnAllocCharcCtlgPathTTP,
      
      _MainCharcCtlgPathRefTP,

      _ProdAllocCharcCatalogType,
      
      _ProdAllocCharcCtlgUseType,

      _ProdAllocCharcCtlgCharcType,

      _ProdAllocCharcCtlgPathType,

      _NextLvlProdAllocCharcCtlgPath,
      
      _ParProdAllocCharcCtlgPathTP,
      
      _CharcValExistenceCheckType,

      _DataElementLabelText,

      _PartnerFunctionText,
      
      _CharacteristicValueGroupType,
      
      _CharacteristicUnitOfMeasure,
      
      _ValueGroupUnitOfMeasure

      //      _SiblingEntity,


      //      _DraftAdministrativeData

}