I_PaymentRequestTP

@AbapCatalog.sqlViewName: 'IPAYMENTREQTP'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Payment Request Draft'

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL

@ObjectModel:
{  sapObjectNodeType.name: 'PaymentRequest'
 ,modelCategory: #BUSINESS_OBJECT
 ,compositionRoot: true
 ,transactionalProcessingEnabled: true
 ,draftEnabled: true
 ,writeDraftPersistence: 'PAYRQ_DRAFT'
 ,semanticKey:  [ 'PaymentRequest' ]
 ,createEnabled: true
 ,updateEnabled: true }

@VDM:{ viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
  
define view I_PaymentRequestTP
  as select from I_PaymentRequest                       as _PaymentRequest
  
  left outer join I_OperationalAcctgDocItem             as _AccountingDocItem002   on  _AccountingDocItem002.CompanyCode           = _PaymentRequest.CompanyCode        
                                                                                  and _AccountingDocItem002.AccountingDocument     = _PaymentRequest.AccountingDocument 
                                                                                  and _AccountingDocItem002.FiscalYear             = _PaymentRequest.FiscalYear         
                                                                                  and _AccountingDocItem002.AccountingDocumentItem = '002' 
//                                                                                  and _AccountingDocItem002.DebitCreditCode        = 'S'

                                                                                            
  association [1..1] to I_Customer                      as _Customer              on  $projection.Customer           =  _Customer.Customer
  association [1..1] to I_Supplier                      as _Supplier              on  $projection.Supplier           =  _Supplier.Supplier
  association [1..1] to P_PFFPCustomerSupplierBankType  as _BankType              on  $projection.PaymentRequest     =  _BankType.PaymentRequest
  association [1..1] to E_PaymentRequest                as _Extension             on  $projection.PaymentRequest     = _Extension.PaymentRequest     
           
{
      @ObjectModel.readOnly
  key _PaymentRequest.PaymentRequest         as PaymentRequest,

      _PaymentRequest.CreatedByUser,
      _PaymentRequest.AccountingDocumentCreationDate,

      //Payee

      @Semantics: { amount : {currencyCode: 'PaymentRequestCurrency'} }
      _PaymentRequest.PaymentRequestAmountInPaytCrcy,

      @Semantics.currencyCode:true
      _PaymentRequest.PaymentRequestCurrency,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      _PaymentRequest.PaymentRequestAmountInCCCrcy,


      @Semantics.currencyCode:true
      _PaymentRequest.CompanyCodeCurrency,

      _PaymentRequest.PayeeName,

      _PaymentRequest.PayeeBankCountry,
      _PaymentRequest.PayeeBankInternalID,
      
      _PaymentRequest.BankDetailReference,
      _PaymentRequest.PayeeBankControlKey,
      _PaymentRequest.PayeeBank,

      cast(_PaymentRequest.PayeeBankAccount as fap_bpa_dzbnkn)  as PayeeBankAccount,

      _PaymentRequest.BankAccountHolderName,
      _PaymentRequest.PayeeTitle,
      _PaymentRequest.PayeePostalCode,
      _PaymentRequest.PayeePOBox,
      _PaymentRequest.POBoxPostalCode,
      _PaymentRequest.PayeeAdditionalName2,
      _PaymentRequest.PayeeAdditionalName3,
      _PaymentRequest.PayeeAdditionalName4,
      _PaymentRequest.PayeeCityName,
      _PaymentRequest.PayeeStreet,
      _PaymentRequest.PayeeCountry,
      _PaymentRequest.PayeeRegion,
      _PaymentRequest.PayeeLanguage,
      _PaymentRequest.PayeeFaxNumber,
      _PaymentRequest.PayeeTelephoneNumber,
      _PaymentRequest.PayeeIBAN,
      _PaymentRequest.ReferenceTypeText,
      _PaymentRequest.PaymentReference,

      //Posting Data

      @ObjectModel.foreignKey.association: '_CompanyCode'
      _PaymentRequest.CompanyCode as CompanyCode,
      _PaymentRequest.BusinessArea,

      cast(
        case
          when _AccountingDocItem002.FinancialAccountType is null
              then _PaymentRequest._PaytReqChangeAndPost.CustomerSupplierAccount
          when _AccountingDocItem002.FinancialAccountType = 'D'
              then _AccountingDocItem002.Customer
          when _AccountingDocItem002.FinancialAccountType = 'K'
              then _AccountingDocItem002.Supplier
          when _AccountingDocItem002.FinancialAccountType = 'S'
              then _AccountingDocItem002.GLAccount
          else ''
      end as farp_ktonr_av)             as CustomerSupplierAccount,

      cast(
        case
          when (    _AccountingDocItem002.FinancialAccountType is null 
                and _PaymentRequest._PaytReqChangeAndPost.FinancialAccountType = 'D' )
            then _PaymentRequest._PaytReqChangeAndPost.CustomerSupplierAccount
          
          when (    _AccountingDocItem002.FinancialAccountType is not null 
                and _AccountingDocItem002.FinancialAccountType = 'D' )
            then _AccountingDocItem002.Customer
          
          else ''
      end as farp_customer_id)          as Customer,

      cast(
        case
          when (    _AccountingDocItem002.FinancialAccountType is null
                and _PaymentRequest._PaytReqChangeAndPost.FinancialAccountType = 'K' )
            then _PaymentRequest._PaytReqChangeAndPost.CustomerSupplierAccount
          
          when (    _AccountingDocItem002.FinancialAccountType is not null
                and _AccountingDocItem002.FinancialAccountType = 'K' ) 
            then _AccountingDocItem002.Supplier

          else ''
      end as farp_supplier_id)          as Supplier,

      case
        when _AccountingDocItem002.DocumentItemText is null 
          then _PaymentRequest._PaytReqChangeAndPost.DocumentItemText
        else _AccountingDocItem002.DocumentItemText
      end                               as DocumentItemText,

      cast(
        case
          when _AccountingDocItem002.FinancialAccountType is null 
            then _PaymentRequest._PaytReqChangeAndPost.FinancialAccountType
          else _AccountingDocItem002.FinancialAccountType
      end as financialaccounttype)      as FinancialAccountType,

      case
        when _AccountingDocItem002.FinancialAccountType is null
          then _PaymentRequest._PaytReqChangeAndPost._FinancialAccountType._Text[1:Language = $session.system_language].FinancialAccountTypeName
        else _AccountingDocItem002._FinancialAccountType._Text[1:Language = $session.system_language].FinancialAccountTypeName
      end                               as FinancialAccountTypeName,

      //House Bank

      _PaymentRequest.PayingCompanyCode,
      _PaymentRequest.HouseBank,
      _PaymentRequest.HouseBankAccount,

      @ObjectModel.readOnly
      _PaymentRequest.AccountingDocument,

      @ObjectModel.readOnly
      _PaymentRequest.ClearingAccountingDocument,
      
      @ObjectModel.readOnly
      _PaymentRequest.ClearingDate,     
      
      @ObjectModel.readOnly             
      _CalendarDateForCompanyCode.FiscalYear as ClearingFiscalYear,

      //Payment Data

      _PaymentRequest.PaymentMethod,
      _PaymentRequest.PaymentMethodSupplement,
      @Semantics.booleanIndicator: true
      _PaymentRequest.IsSinglePayment,
      _PaymentRequest.ValueDate,
      _PaymentRequest.DataExchangeInstructionKey,
      _PaymentRequest.DataExchangeInstruction1,
      _PaymentRequest.DataExchangeInstruction2,
      _PaymentRequest.DataExchangeInstruction3,
      _PaymentRequest.DataExchangeInstruction4,
      
      @Semantics.booleanIndicator: true
      case
        when _PaymentRequest._DataExchangeInstructionKeys.IsUrgentPayment is null
        then ''
        else _PaymentRequest._DataExchangeInstructionKeys.IsUrgentPayment
      end as IsUrgentPayment,
      
      _PaymentRequest.PaymentRequestOrigin,
      
      @ObjectModel.readOnly
      _PaymentRequest.ReleaseDate,
      
      @ObjectModel.readOnly
      _PaymentRequest.ReleasedByUser,

      @ObjectModel.readOnly
      _PaymentRequest.PaymentRequestPostingDate,
            
      @ObjectModel.readOnly
      _PaymentRequest.PostingCreatedByUser,
      

      @ObjectModel.readOnly
      @Semantics.booleanIndicator: true
      _PaymentRequest.PaytReqIsReleasedForPosting,
      
      @Semantics.booleanIndicator: true
      _PaymentRequest.PaytReqIsCompleted,
      
      @Semantics.booleanIndicator: true
      _PaymentRequest.PaytReqIsReleasedForPayment,

      @ObjectModel.readOnly
      @Semantics.booleanIndicator: true
      _PaymentRequest.IsReversed,

      _PaymentRequest.ReversalReason,
      _PaymentRequest.StateCentralBankPaymentReason,
      _PaymentRequest.SupplyingCountry,
      _PaymentRequest.TaxID1,
      _PaymentRequest._PaytReqChangeAndPost.BankChain,

      cast( _BankType.PaymentRequestType as farp_payrq_type ) as PaymentRequestType,
      _BankType.CustomerBankType,
      _BankType.SupplierBankType,

      _PaymentRequest._PaytReqChangeAndPost.LastChangedByUser,
      _PaymentRequest._PaytReqChangeAndPost.LastChangeTime,
      _PaymentRequest._PaytReqChangeAndPost.LastChangeDate,
      _PaymentRequest._PaytReqChangeAndPost.CreationTime,

      cast (
      case tims_is_valid(_PaymentRequest._PaytReqChangeAndPost.CreationTime)
          when 1 then dats_tims_to_tstmp( _PaymentRequest.AccountingDocumentCreationDate, _PaymentRequest._PaytReqChangeAndPost.CreationTime,
                                     abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' )
          else dats_tims_to_tstmp( _PaymentRequest.AccountingDocumentCreationDate, _PaymentRequest.CreationTime,
                                     abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' )
       end as farp_prq_cr_date )        as CreationDateTime,

      cast( dats_tims_to_tstmp( _PaymentRequest._PaytReqChangeAndPost.LastChangeDate, _PaymentRequest._PaytReqChangeAndPost.LastChangeTime,
                                 abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' )
             as farp_prq_chg_date )     as LastChangeDateTime,

      @VDM.lifecycle.status:#DEPRECATED
      @VDM.lifecycle.successor: 'PaymentRequestTemplate'
      cast(' ' as fibl_opvar)               as PaymentRequestVariant,
      cast(' ' as payment_request_template) as PaymentRequestTemplate,

      _PaymentRequest.PaymentRepetitiveCode,
      _PaymentRequest.PayeePaymentSystem,
      _PaymentRequest.PayeeAliasType,
      _PaymentRequest.PayeeAliasName,
      _PaymentRequest.TradingPartner,

      @ObjectModel.readOnly
      _PaymentRequest.FiscalYear,
      _PaymentRequest.BankCountry,
      @ObjectModel.readOnly
      _PaymentRequest.BankInternalID,
      @ObjectModel.readOnly
      _PaymentRequest.GLAccount,
      @ObjectModel.readOnly
      _PaymentRequest.StatusCode,
      @ObjectModel.readOnly
      _PayingCompanyCode.FiscalYearVariant,
      
      @ObjectModel.readOnly
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      _PaymentRequest.AmountInAdditionalCurrency1,
      @ObjectModel.readOnly
      @Semantics.currencyCode: true
      _PaymentRequest.AdditionalCurrency1,
      
      @ObjectModel.readOnly
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      _PaymentRequest.AmountInAdditionalCurrency2,
      @ObjectModel.readOnly
      @Semantics.currencyCode: true
      _PaymentRequest.AdditionalCurrency2,
      @ObjectModel.foreignKey.association: '_PaymentReason'
      _PaymentRequest.PaymentReason,
      
      @Semantics.booleanIndicator: true
      cast('' as abap_boolean)           as BankAliasEntryIsSelected,
      
      _PaymentRequest._PaytReqAdditionalInfo[1:PaymentRequestNotificationType = 'Q'].PaymentRequestReferenceText,

      _PaymentRequest._PayeeBank,
      _PaymentRequest._Bank,
      _PaymentRequest._HouseBankAccount,
      _PaymentRequest._BusinessAreaText,
      _PaymentRequest._CompanyCode,
      _PaymentRequest._PayingCompanyCode,
      _PaymentRequest._PartnerCompany,
      _PaymentRequest._PaymentRequestCurrency,
      _PaymentRequest._CompanyCodeCurrency,
      _PaymentRequest._AdditionalCurrency1,
      _PaymentRequest._AdditionalCurrency2,
      _PaymentRequest._DataExchangeInstructionKeys,
      _PaymentRequest._PaymentMethod,
      _PaymentRequest._PaytReqChangeAndPost,
      _PaymentRequest._SystemStatusText,
      _PaymentRequest._ReversalReason,
      _PaymentRequest._CalendarDateForCompanyCode,
      _PaymentRequest._PaymentReason,      
      _Customer,
      _Supplier,
      _PayeePaymentSystem,
      _PayeeAliasType     
}