I_PT_SAFTTaxCodeCheck

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Tax Code used for SAFT File'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
define view entity I_PT_SAFTTaxCodeCheck
  as select distinct from I_BillingDocumentItem  as Document

    inner join            I_PT_BillgDocDgtlSgntr as DigSig on  DigSig.BillingDocument = Document.BillingDocument
                                                           and DigSig.CompanyCode     = Document.CompanyCode

  //    inner join            I_PT_SAFTBillgMasterDataTax as TaxTab on  Document.TaxCode             =  TaxTab.TaxCode

  //                                                                and Document.BillingDocumentDate >= TaxTab.StartDate

  //                                                                and Document.BillingDocumentDate <= TaxTab.EndDate



{
  key Document.CompanyCode,
  key DigSig.PortugueseInvoiceNumber,
  key Document.BillingDocumentItem,
  key Document.BillingDocumentDate    as DocumentDate,
      cast(Document.TaxCode as mwskz) as TaxCode
}

union select from I_OperationalAcctgDocItem as Document
  inner join      I_PT_AcctgDocDgtlSgntr    as DigSig on  DigSig.AccountingDocument = Document.AccountingDocument
                                                      and DigSig.CompanyCode        = Document.CompanyCode
                                                      and DigSig.FiscalYear         = Document.FiscalYear

//  inner join      I_PT_SAFTBillgMasterDataTax as TaxTab on  Document.TaxCode      =       TaxTab.TaxCode

//                                                        and Document.DocumentDate between TaxTab.StartDate and TaxTab.EndDate


{
  key Document.CompanyCode,
  key DigSig.PortugueseInvoiceNumber,
  key cast(Document.AccountingDocumentItem as abap.char(6)) as BillingDocumentItem,
  key Document.DocumentDate,
      cast(Document.TaxCode as mwskz)                       as TaxCode
}
where
      Document.AccountingDocumentItemType <> 'T'
  and Document.FinancialAccountType       =  'S'

union select from R_SetlMgmtDocItmCustPrcgElmnt as Document
  inner join      R_SettlmtMgmtDocItem          as DocumentItem on  Document.SettlmtMgmtDoc     = DocumentItem.SettlmtMgmtDoc
                                                                and Document.SettlmtMgmtDocItem = DocumentItem.SettlmtMgmtDocItem

  inner join      I_PT_SettlmtDocsDgtlSgntr     as DigSig       on  Document.SettlmtMgmtDoc  = DigSig.InvoiceDocumentNumber
                                                                and DocumentItem.CompanyCode = DigSig.CompanyCode

//  inner join      I_PT_SAFTBillgMasterDataTax   as TaxTab       on  Document.TaxCode   =       TaxTab.TaxCode

//                                                                and DigSig.InvoiceDate between TaxTab.StartDate and TaxTab.EndDate


{
  key DocumentItem.CompanyCode,
  key DigSig.ReferenceDocumentNumber                        as PortugueseInvoiceNumber,
  key cast(DocumentItem.SettlmtMgmtDocItem as abap.char(6)) as BillingDocumentItem,
  key DigSig.InvoiceDate                                    as DocumentDate,
      cast(Document.TaxCode as mwskz)                       as TaxCode

}
where
       Document.ConditionClass           = 'D'
  and  Document.ConditionIsForStatistics = ''
  and(
       Document.ConditionInactiveReason  = ''
    or Document.ConditionInactiveReason  = 'W'
  )

union select from I_PT_SAFTDeliveryItemTax as Document
  inner join      I_PT_DeliveryDgtlSgntr   as DigSig on Document.DeliveryDocument = DigSig.DeliveryDocument

//  inner join      I_PT_SAFTBillgMasterDataTax as TaxTab on  Document.TaxCode      =       TaxTab.TaxCode

//                                                        and Document.DeliveryDate between TaxTab.StartDate and TaxTab.EndDate


{
  key Document.CompanyCode,
  key DigSig.PortugueseDeliveryNumber                     as PortugueseInvoiceNumber,
  key cast(Document.DeliveryDocumentItem as abap.char(6)) as BillingDocumentItem,
  key Document.DeliveryDate                               as DocumentDate,
      cast(Document.TaxCode as mwskz)                     as TaxCode
}