I_PT_BILLGDOCDGTLSGNTR

@AbapCatalog.sqlViewName: 'IPTBLGDIGSIG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('BLOCKED_DATA_INCLUDED')
@EndUserText.label: 'PT BillingDoc Digital Signature'
define view I_PT_BillgDocDgtlSgntr
  as select from P_PT_BillgDocDgtlSgntr(P_SAPClient : $session.client) as Signature // access signature table function to get converted value


  association [1..1] to I_CompanyCode as _CompanyCode on Signature.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_PT_DgtlSgntrStartBilling as _DgtlsgntrStartBillg on _DgtlsgntrStartBillg.PT_SeriesNumberRangeInterval = Signature.NumberRangeInterval
{
  key BillingDocument                                                                                  as   BillingDocument,
  key NumberRangeInterval                                                                              as   NumberRangeInterval,

      Signature.CompanyCode                                                                            as   CompanyCode,

      PortugueseLeadingBillgDocType                                                                    as   PortugueseLeadingBillgDocType,

      PortugueseDgtlSignatureSeries                                                                    as   PortugueseDgtlSignatureSeries,

      PortugueseInvoiceDate                                                                            as   PortugueseInvoiceDate,

      PTDgtlSgntrSystemDateTimeText                                                                    as   PTDgtlSgntrSystemDateTimeText,

      PortugueseDgtlSgntrSystDteTime                                                                   as   PortugueseDgtlSgntrSystDteTime,

      PortugueseInvoiceNumber                                                                          as   PortugueseInvoiceNumber,

      @Semantics.currencyCode: true
      _CompanyCode.Currency                                                                            as   CompanyCodeCurrency,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TotalGrossAmount                                                                                 as   TotalGrossAmount,

      PortugueseDgtlSgntrKeyVersion                                                                    as   PortugueseDgtlSgntrKeyVersion,

      PortugueseDigitalSignature                                                                       as   PortugueseDigitalSignature,

      cast(
      case
      when PortugueseDgtlSgntrDocChgDate <> '00000000'
      then PortugueseDgtlSgntrDocChgDate
      else PortugueseDgtlSgntrDocCrteDate
      end as sipt_creadate)                                                                            as   PortugueseDigitalSignatureDate,

      cast(
      case
      when PortugueseDgtlSgntrDocChgDate <> '00000000'
      then PortugueseDgtlSgntrDocChgTime
      else PortugueseDgtlSgntrDocCrteTime
      end as sipt_creatime)                                                                            as   PortugueseDigitalSignatureTime,

      _DgtlsgntrStartBillg.PT_SeriesDocumentType                                                       as   PT_SeriesDocumentType,
       
       cast(
       case
       when _DgtlsgntrStartBillg.PT_SeriesValdtnCode is not initial
       then concat(concat(_DgtlsgntrStartBillg.PT_SeriesValdtnCode,('-')), BillingDocument)                
       else '0'   
       end as glo_pt_atcud)                                                                            as   PT_SeriesDocumentNumber,
      /* Associations */
      _CompanyCode._Currency

}