I_PT_DelDocCustAddrHist_2

@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@AccessControl.authorizationCheck:#MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'SAFT PT Delivery Doc CustAddr History'
define view entity I_PT_DelDocCustAddrHist_2
  as select from I_PT_DelDocCustAddVers_2 as Version 
    inner join   I_PT_SAFTCustAddrHist  as History on  Version.Customer                  = History.Customer
                                                   and Version.PortugueseCustomerVersion = History.PortugueseCustomerVersion
{
  key Version.DeliveryDocument        as DeliveryDocument,
  key History.Customer                as Customer,

      Version.CompanyCode             as CompanyCode,
      concat(Version.Customer,concat('_',Version.PortugueseCustomerVersion))     as BusinessPartnerCustomer, 

      History.CustomerVATRegistration as CustomerVATRegistration,
      History.CompanyName             as CompanyName,

      cast(
      concat_with_space(History.PartnerFirstName,History.PartnerLastName,1)
      as saft_pt_contact_name)        as ContactPersonName,

      History.CustomerSupplierAddress as PT_CustomerSupplierAddressText,       
      History.CityName                as CityName,
      History.PostalCode              as PostalCode,
      History.Country                 as Country,
      History.PhoneNumber             as PhoneNumber,
      cast( History.FaxNumber as telfx)               as FaxNumber,
      History.EmailAddress            as EmailAddress,
      History.SearchURLAddress        as SearchURLAddress,

      /* Associations */
      //FOR DPP AUTHORIZATION CHECK

      History._Customer

}