I_PT_DelDocCustAddVers_2

@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@AccessControl.authorizationCheck:#MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'SAFT Cust Address Version'
define view entity I_PT_DelDocCustAddVers_2
  as select from I_PT_DeliveryDgtlSgntr      as Signature
    inner join   I_DeliveryDocument          as DeliveryDocument on Signature.DeliveryDocument = DeliveryDocument.DeliveryDocument
    inner join   I_PT_CustomerAddressVersion_2 as Version          on DeliveryDocument.ShipToParty                  =  Version.Customer
                                                                 and(
                                                                   Signature.PortugueseDigitalSignatureDate       >  Version.PortugueseDigitalSignatureDate
                                                                   or(
                                                                     Signature.PortugueseDigitalSignatureDate     =  Version.PortugueseDigitalSignatureDate
                                                                     and Signature.PortugueseDigitalSignatureTime >= Version.PortugueseDigitalSignatureTime
                                                                   )
                                                                 )
{
  key DeliveryDocument.DeliveryDocument                                 as DeliveryDocument,
  key DeliveryDocument.ShipToParty                                      as Customer,
      DeliveryDocument._SalesOrganization.CompanyCode                   as CompanyCode,
      cast(max(Version.PortugueseCustomerVersion) as sipt_data_version) as PortugueseCustomerVersion,

      /* Associations */
      //FOR DPP AUTHORIZATION CHECK

      DeliveryDocument._ShipToParty
}
where
 Signature.PortugueseDigitalSignature <> ''
group by
  DeliveryDocument.DeliveryDocument,
  DeliveryDocument._SalesOrganization.CompanyCode,
  DeliveryDocument.ShipToParty;