I_PPM_ProjectElementProgress

@EndUserText.label: 'Project Elements Progress'
@AbapCatalog.sqlViewName: 'IPPMPROJELEMPROG'
@VDM.viewType: #COMPOSITE
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED

@ObjectModel.representativeKey: 'TaskUUID'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
@Consumption.dbHints:[ 'USE_HEX_PLAN' ]

define view I_PPM_ProjectElementProgress  
  as select from    I_PPM_Task                  as Task
    left outer join I_PPM_Tasktype              as Tasktype  on Task.TaskType = Tasktype.TaskType
    left outer join I_EnterpriseProjElmntHier   as Hierarchy on Task.TaskUUID = Hierarchy.TaskUUID
    left outer join I_PPM_TaskText              as TaskText  on Task.TaskUUID = TaskText.TaskUUID
    left outer join I_EntProjectResponsiblePerson  as ResponsibleBP   on Task.ProjectUUID = ResponsibleBP.ProjectUUID   and Task.TaskUUID = ResponsibleBP.ReferencedObjectUUID
    left outer join I_EnterpriseProjectRole        as ResponsibleRole on Task.ProjectUUID = ResponsibleRole.ProjectUUID and ResponsibleRole.ProjectRoleType = 'YP_RL_0001'
                                                                
  association [0..1] to I_BusinessUserBasic        as _BusinessUser  on _BusinessUser.BusinessPartnerUUID = ResponsibleBP.BusinessPartnerUUID 
  association [0..1] to I_PPM_ProjectRoleText      as _RoleText      on _RoleText.ProjectRoleUUID         = ResponsibleRole.ProjectRoleUUID
  // PS Root WBS Element

  association [0..1] to I_WBSElementBasicData      as _ProjObjRoot   on (
       _ProjObjRoot.WBSElementInternalID = $projection.WBSElementInternalID
     )
  association [0..1] to I_PPM_Project as _Project on _Project.ProjectUUID = Task.ProjectUUID

{
  key Task.TaskUUID                                                                                   as TaskUUID,
      Task.ProjectUUID                                                                                as ProjectUUID,
      Task.ObjectType                                                                                 as ObjectType,
      Task.TaskType                                                                                   as TaskType,
      Hierarchy.ParentObjectUUID                                                                      as ParentObjectUUID,
      Hierarchy.OrdinalNumber                                                                         as OrdinalNumber,
      Hierarchy.HierarchyNodeLevel                                                                    as HierarchyNodeLevel,
      TaskText.ObjectName                                                                             as ObjectName,
      case
          when Task.ObjectType <> 'DPO' and Task.ObjectType <> 'PPO' and Task.TotalFloat <= 0 and Task.TaskProcessingStatus <> '40' and Task.TaskProcessingStatus <> '41'
                                        and Task.TaskProcessingStatus <> '42'
            then cast('X' as boolean)
          else cast('' as boolean)
        end                                                                                           as IsCriticalPath,
      cast(Task.IsProjectMilestone as boolean)                                                        as IsProjectMilestone,
      cast(Task.IsSummaryTask as boolean)                                                             as IsSummaryTask,
      Task.FactoryCalendar                                                                            as FactoryCalendar,
      Task.TaskProcessingStatus                                                                       as ProcessingStatus,
      Task._ProcessingStatus._Text[1:Language=$session.system_language].ProcessingStatusText          as ProcessingStatusText,
      Task.StartConstraintType                                                                        as StartConstraintType,
      Task.FinishConstraintType                                                                       as FinishConstraintType,
      
      
      // for some reasons someone did not understand the difference between date and date/time, therefor wrong naming in result field!

      Task.LatestStartDate      as LatestStartDateTime,

      // for some reasons someone did not understand the difference between date and date/time, therefor wrong naming in result field!

      Task.LatestFinishDate     as LatestFinishDateTime,

      // for some reasons someone did not understand the difference between date and date/time, therefor wrong naming in result field!

      Task.ForecastedFinishDate as ForecastedFinishDateTime,

      // for some reasons someone did not understand the difference between date and date/time, therefor wrong naming in result field!

      Task.ActualFinishDate     as ActualFinishDateTime,

      Tasktype.IsEssentialMilestone                                                                   as IsMainMilestone,

      Task.ProjectElementDuration                                                                     as ProjectElementDuration,
      Task.DurationUnit                                                                               as DurationUnit,
      Task.PercentageOfCompletion                                                                     as PercentageOfCompletion,
      Task.RemainingWorkQuantityInSeconds                                                             as RemainingWorkQuantityInSeconds,
      case
          when Task.ObjectType <> 'DPO' and Task.ObjectType <> 'PPO' and Task.TaskProcessingStatus <> '40' and Task.TaskProcessingStatus <> '41' and Task.TaskProcessingStatus <> '42'
            then cast(unit_conversion( quantity => Task.RemainingWorkQuantityInSeconds,
                  source_unit => cast( 'S' as abap.unit(3) ),
                  target_unit => Task.RemainingWorkExtQuantityUnit,
                  error_handling => 'KEEP_UNCONVERTED')
                  as abap.dec( 15, 2 ) )
            else cast(0 as abap.dec( 15, 2 ) )
          end                                                                                         as RemainingWorkQuantity,

      Task.RemainingWorkExtQuantityUnit                                                               as RemainingWorkExtQuantityUnit,
      Task._RemainingWorkExtQuantityUnit._Text[1:Language=$session.system_language].UnitOfMeasureName as RemainingWorkQuantityUnitName,
      Task.CreatedByUser                                                                              as CreatedByUser,
      Task.CreationDateTime                                                                           as CreationDateTime,
      Task.LastChangedByUser                                                                          as LastChangedByUser,
      Task.LastChangeDateTime                                                                         as LastChangeDateTime,
     ///removed as part of DPR carve out topic

     // Task._Severity.CriticalityCode                                                                  as CriticalityCode,

     // Task._Severity.SeverityText                                                                     as SeverityText,

      Task.WBSElementInternalID,
      ResponsibleBP.BusinessPartnerUUID                                                               as BusinessPartnerUUID,
      _BusinessUser.PersonFullName                                                                    as BusinessPartnerName,
      ResponsibleRole.ProjectRoleUUID                                                                 as ProjectRoleUUID,
      _BusinessUser._WorkplaceAddress.DefaultEmailAddress                                             as EmailAddress, 
      _BusinessUser._WorkplaceAddress.MobilePhoneNumber                                               as MobilePhoneNumber,
      _BusinessUser._WorkplaceAddress.PhoneNumber                                                     as AddressPhoneNumber,
      _RoleText.ProjectRoleName                                                                       as ProjectRoleName,

      // for authorization checks

      _BusinessUser,
      _AuthUser,
      _AuthSubst,
      _AuthRole,
      _AuthGroup,

      _ProjObjRoot,
      _Project

} where _Project.ProjectCategory = '6'