I_EntProjectResponsiblePerson

@AbapCatalog.sqlViewName: 'IEPRJRESPPERSN'
@VDM.viewType: #BASIC

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER

@ObjectModel.representativeKey: 'EntProjResponsiblePersonUUID'

@EndUserText.label: 'Responsible Person for Ent Projects'
define view I_EntProjectResponsiblePerson
  as select from /s4ppm/resppersn as RespPerson
  association [1..1] to I_EnterpriseProject     as _EnterpriseProject     on $projection.ProjectUUID = _EnterpriseProject.ProjectUUID
  association [1..1] to I_WorkforcePerson       as _WorkforcePerson       on $projection.BusinessPartnerUUID = _WorkforcePerson.BusinessPartnerUUID
  association [1..1] to I_BusinessPartner       as _BusinessPartner       on $projection.BusinessPartnerUUID = _BusinessPartner.BusinessPartnerUUID
  association [1..1] to I_PersonWorkAgreement_1 as _PersonWorkAgreement_1 on $projection.PersonWorkAgreement = _PersonWorkAgreement_1.PersonWorkAgreement
  //For Cat 7 Authorization                                                                                      

  association [0..1] to I_EnterpriseProjectForUser     as _EnterpriseProjectForUser on _EnterpriseProjectForUser.ProjectUUID = $projection.ProjectUUID
{

  key entprojresponsiblepersonuuid as EntProjResponsiblePersonUUID,

      @ObjectModel.foreignKey.association: '_EnterpriseProject'
      projectuuid                  as ProjectUUID,

      referencedobjectuuid         as ReferencedObjectUUID,

      //    @ObjectModel.foreignKey.association: '_BusinessPartner'    // cannot be added as BUPA GUID is not the key

      businesspartneruuid          as BusinessPartnerUUID,

      @ObjectModel.foreignKey.association: '_PersonWorkAgreement_1'
      employmentinternalid         as PersonWorkAgreement,

      projectinternalid            as ProjectInternalID,

      wbselementinternalid         as WBSElementInternalID,
      
      createdbyuser                as CreatedByUser,
      
      creationdatetime             as CreationDateTime,
      
      lastchangedbyuser            as LastChangedByUser,
      
      lastchangeddatetime          as LastChangeDateTime,   
      
      _EnterpriseProject,
      _WorkforcePerson,
      _BusinessPartner,
      _PersonWorkAgreement_1,
      _EnterpriseProjectForUser

}