I_OrderProdnResourceTool

@AbapCatalog.sqlViewName: 'IORDPRODNRSCTOOL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser', '_StatusObject', '_LongText']
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'OrderProdnRsceToolInternalID'
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Order Production Resource Tool'
// Basic view for PRTs assigned to any category of orders

// Due to the high number of consumers, this CDS view is protected against incompatible changes


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK", "CARDINALITY_CHECK" ]  } */
define view I_OrderProdnResourceTool
  as select from           affh  as affh
    left outer to one join caufv as aufv on aufv.aufpl = affh.aufpl

  association [1..1] to I_OrdInternalBillOfOperations as _OrdInternalBillOfOperations   on  $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalBillOfOperations
  association [1..1] to I_OrderInternalID             as _OrderInternalID               on  $projection.OrderInternalBillOfOperations = _OrderInternalID.OrderInternalID 
  association [0..1] to I_LogisticsOrder              as _Order                         on  $projection.OrderID = _Order.OrderID
  association [0..1] to I_OrderCategory               as _OrderCategory                 on  $projection.OrderCategory = _OrderCategory.OrderCategory
  association [0..1] to I_OrderType                   as _OrderType                     on  $projection.OrderType = _OrderType.OrderType
  association [1..1] to I_OrderOperationBasic         as _OrderOperation                on  $projection.OrderInternalBillOfOperations = _OrderOperation.OrderInternalID
                                                                                        and $projection.OrderIntBillOfOperationsItem  = _OrderOperation.OrderOperationInternalID
  association [0..1] to I_Plant                       as _Plant                         on  $projection.Plant = _Plant.Plant
  association [0..1] to I_ProdnRsceToolControlProfile as _ProdnRsceToolControlProfile   on  $projection.ProdnRsceToolControlProfile = _ProdnRsceToolControlProfile.ProdnRsceToolControlProfile
  association [0..1] to I_ProductionResourceType      as _ProductionResourceType        on  $projection.ProductionResourceType = _ProductionResourceType.ProductionResourceType
  association [1..1] to I_ProdnRsceToolByInternalKey  as _ProdnRsceToolByInternalKey    on  $projection.ProductionResourceType       = _ProdnRsceToolByInternalKey.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _ProdnRsceToolByInternalKey.ProductionResourceInternalID
  association [1..1] to I_ProdnRsceToolMasterData     as _ProdnRsceToolMasterData       on  $projection.ProductionResourceType       = _ProdnRsceToolMasterData.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _ProdnRsceToolMasterData.ProductionResourceInternalID
  association [1..1] to I_User                        as _CreatedByUser                 on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangedByUser             on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_Language                    as _Language                      on  $projection.Language = _Language.Language
  association [0..1] to I_BillOfOperationsType        as _BillOfOperationsType          on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup         on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [0..1] to I_UnitOfMeasure               as _ProdnRsceToolUsageDurnUnit    on  $projection.ProdnRsceToolUsageDurnUnit = _ProdnRsceToolUsageDurnUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _ProdnRsceToolStdWorkQtyUnit   on  $projection.ProdnRsceToolStdWorkQtyUnit = _ProdnRsceToolStdWorkQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _PlannedProdnRsceToolQtyUnit   on  $projection.PlannedProdnRsceToolQtyUnit = _PlannedProdnRsceToolQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _ConfirmedProdnRsceToolQtyUnit on  $projection.ConfirmedProdnRsceToolQtyUnit = _ConfirmedProdnRsceToolQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _RemainingProdnRsceToolQtyUnit on  $projection.RemainingProdnRsceToolQtyUnit = _RemainingProdnRsceToolQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _ProdnRsceToolUsageQtyUnit     on  $projection.ProdnRsceToolUsageQuantityUnit = _ProdnRsceToolUsageQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _PlndProdnRsceToolUsageQtyUnit on  $projection.PlndProdnRsceToolUsageQtyUnit  = _PlndProdnRsceToolUsageQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _ConfdProdnRsceToolUsgeQtyUnit on  $projection.ConfdProdnRsceToolUsageQtyUnit = _ConfdProdnRsceToolUsgeQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _RmngProdnRsceToolUsageQtyUnit on  $projection.RmngProdnRsceToolUsageQtyUnit  = _RmngProdnRsceToolUsageQtyUnit.UnitOfMeasure
  association [1..1] to I_StatusObject                as _StatusObject                  on  $projection.ObjectInternalID = _StatusObject.StatusObject
  association [0..1] to I_OrderOperationPRTLongText   as _LongText                      on  $projection.OrderInternalBillOfOperations = _LongText.OrderInternalID
                                                                                        and $projection.OrderProdnRsceToolInternalID  = _LongText.OrderProdnRsceToolInternalID
                                                                                        and $projection.Language                      = _LongText.LongTextLanguage
-- to individual PRTs
  association [0..1] to I_DocumentProdnRsceTool       as _DocumentProdnRsceTool         on  $projection.ProductionResourceType       = _DocumentProdnRsceTool.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _DocumentProdnRsceTool.ProductionResourceInternalID
  association [0..1] to I_EquipmentProdnRsceTool      as _EquipmentProdnRsceTool        on  $projection.ProductionResourceType       = _EquipmentProdnRsceTool.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _EquipmentProdnRsceTool.ProductionResourceInternalID
  association [0..1] to I_MaterialProdnRsceTool       as _MaterialProdnRsceTool         on  $projection.ProductionResourceType       = _MaterialProdnRsceTool.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _MaterialProdnRsceTool.ProductionResourceInternalID
  association [0..1] to I_MiscProdnRsceTool           as _MiscProdnRsceTool             on  $projection.ProductionResourceType       = _MiscProdnRsceTool.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _MiscProdnRsceTool.ProductionResourceInternalID
{
      // Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
  key cast(affh.aufpl as pph_aufpl preserving type)           as OrderInternalBillOfOperations,
      @ObjectModel.text.element: ['OrderProdnRsceToolText']
  key affh.pzlfh                                              as OrderProdnRsceToolInternalID,

      // Admin Data

      affh.loekz                                              as IsDeleted,
      @Semantics.systemDate.createdAt: true
      affh.datui                                              as CreationDate,
      @Semantics.user.createdBy: true
      affh.useri                                              as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      affh.datuc                                              as LastChangeDate,
      @Semantics.user.lastChangedBy: true
      affh.userc                                              as LastChangedByUser,

      // Text

      @Semantics.text: true
      affh.txtz1                                              as OrderProdnRsceToolText,
      @ObjectModel.foreignKey.association: '_Language'
      affh.txtsp                                              as Language,
      @Semantics.booleanIndicator
      cast(case 
             when affh.txtsp <> '' then 'X'
             else affh.txtsp
      end as pph_prtltxt preserving type)                     as ProdnRsceToolHasLongText,

      // Order Data

      @ObjectModel.foreignKey.association: '_Order'
      aufv.aufnr                                              as OrderID,
      @ObjectModel.foreignKey.association: '_OrderCategory'
      cast(aufv.autyp as pph_autyp preserving type)           as OrderCategory,
      @ObjectModel.foreignKey.association: '_OrderType'
      aufv.auart                                              as OrderType,
      @ObjectModel.foreignKey.association: '_Plant'
      aufv.werks                                              as Plant,
      @ObjectModel.foreignKey.association: '_OrderOperation'
      cast(affh.aplzl as operationinternalid preserving type) as OrderIntBillOfOperationsItem,
      // for DCL

      aufv.dispo                                              as MRPController,

      // PRT Data

      @ObjectModel.foreignKey.association: '_ProductionResourceType'
      affh.objty                                              as ProductionResourceType,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolByInternalKey'
      affh.objid                                              as ProductionResourceInternalID,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolControlProfile'
      affh.steuf                                              as ProdnRsceToolControlProfile,
      @ObjectModel.text.element: ['OrderProdnRsceToolText']
      affh.psnfh                                              as ProdnRsceToolItemNumber,
      @ObjectModel.foreignKey.association: '_StatusObject'   
      affh.objnr                                              as ObjectInternalID,

      // BOO Data

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      affh.plnty_key                                          as BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      affh.plnnr_key                                          as BillOfOperationsGroup,      
      affh.pzlfh_key                                          as BOOOperationPRTInternalID,
      affh.zaehl_key                                          as BOOOperationPRTIntVersCounter,

      // Dates and Times

      affh.fsfhd                                              as EarliestSchedldUsageStartDate,
      affh.fsfhz                                              as EarliestSchedldUsageStartTime,
      affh.fefhd                                              as EarliestSchedldUsageEndDate,
      affh.fefhz                                              as EarliestSchedldUsageEndTime,
      affh.ssfhd                                              as LatestSchedldUsageStartDate,
      affh.ssfhz                                              as LatestSchedldUsageStartTime,
      affh.sefhd                                              as LatestSchedldUsageEndDate,
      affh.sefhz                                              as LatestSchedldUsageEndTime,
      affh.isfhd                                              as ActualUsageStartDate,
      affh.isfhz                                              as ActualUsageStartTime,
      affh.iefhd                                              as ActualUsageEndDate,
      affh.iefhz                                              as ActualUsageEndTime,

      // Duration

      @ObjectModel.foreignKey.association: '_ProdnRsceToolUsageDurnUnit'
      @Semantics.unitOfMeasure: true
      affh.daueh                                              as ProdnRsceToolUsageDurnUnit,
      affh.daufl                                              as ProdnRsceToolUsageDuration,

      // Quantities and UoMs

      @ObjectModel.foreignKey.association: '_ProdnRsceToolStdWorkQtyUnit'
      @Semantics.unitOfMeasure: true
      affh.mgeinh                                             as ProdnRsceToolStdWorkQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ProdnRsceToolStdWorkQtyUnit'
      @Aggregation.default: #SUM
      affh.mgvgw                                              as ProdnRsceToolStandardWorkQty,

      @ObjectModel.foreignKey.association: '_PlannedProdnRsceToolQtyUnit'
      @Semantics.unitOfMeasure: true
      cast(affh.mgsoleh as pph_mgsoleh preserving type)       as PlannedProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'PlannedProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      affh.mgsol                                              as PlannedTotalProdnRsceToolQty,

      @ObjectModel.foreignKey.association: '_ConfirmedProdnRsceToolQtyUnit'
      @Semantics.unitOfMeasure: true
      cast(affh.mgisteh as pph_mgisteh preserving type)       as ConfirmedProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfirmedProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      affh.mgist                                              as ConfirmedProdnRsceToolQty,

      @ObjectModel.foreignKey.association: '_RemainingProdnRsceToolQtyUnit'
      @Semantics.unitOfMeasure: true
      cast(affh.mgrsteh as pph_mgrsteh preserving type)       as RemainingProdnRsceToolQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'RemainingProdnRsceToolQtyUnit'
      @Aggregation.default: #SUM
      affh.mgrst                                              as RemainingProdnRsceToolQty,

      // Usage Quantities and UoMs

      @ObjectModel.foreignKey.association: '_ProdnRsceToolUsageQtyUnit'
      @Semantics.unitOfMeasure: true
      affh.eweinh                                             as ProdnRsceToolUsageQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'ProdnRsceToolUsageQuantityUnit'
      @Aggregation.default: #SUM
      affh.ewvgw                                              as ProdnRsceToolUsageQuantity,

      @ObjectModel.foreignKey.association: '_PlndProdnRsceToolUsageQtyUnit'
      @Semantics.unitOfMeasure: true
      cast(affh.ewsoleh as vdm_ewsoleh preserving type)       as PlndProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'PlndProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      affh.ewsol                                              as PlannedProdnRsceToolUsageQty,

      @ObjectModel.foreignKey.association: '_ConfdProdnRsceToolUsgeQtyUnit'
      @Semantics.unitOfMeasure: true
      cast(affh.ewisteh as vdm_ewisteh preserving type)       as ConfdProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ConfdProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      affh.ewist                                              as ConfirmedProdnRsceToolUsageQty,

      @ObjectModel.foreignKey.association: '_RmngProdnRsceToolUsageQtyUnit'
      @Semantics.unitOfMeasure: true
      cast(affh.ewrsteh as vdm_ewrsteh preserving type)       as RmngProdnRsceToolUsageQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'RmngProdnRsceToolUsageQtyUnit'
      @Aggregation.default: #SUM
      affh.ewrst                                              as RemainingProdnRsceToolUsageQty,

      //Formula

      affh.mgform                                             as ProdnRsceToolTotQtyCalcFormula,
      affh.ewform                                             as ProdnRsceToolUsageQtyCalcFmla,

      @Semantics.booleanIndicator
      affh.registrable                                        as ProdnRsceToolRegnIsAllowed,
      
/*    // Cloud system indicator to switch visibility of User Status

      @UI.hidden: true
      @ObjectModel : {
        readOnly : true,
        virtualElement: true,                            <<<< Virtual Elements are NOT allowed in basic dimension views!
        virtualElementCalculatedBy: 'ABAP:CL_EAM_OBJPG_MNTORD_PHMOD_EXIT'
      } */
      @Semantics.booleanIndicator
      cast( '' as char1 ) as IsCloudSystem,
 
      // Associations

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_OrderInternalID'
      _OrdInternalBillOfOperations,
      _OrderInternalID,
      _Order,
      _OrderCategory,
      _OrderType,
      _OrderOperation,
      _Plant,
      _ProdnRsceToolControlProfile,
      _ProductionResourceType,
      _ProdnRsceToolByInternalKey,
      _ProdnRsceToolMasterData,
      _CreatedByUser,
      _LastChangedByUser,
      _Language,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _ProdnRsceToolUsageDurnUnit,
      _ProdnRsceToolStdWorkQtyUnit,
      _PlannedProdnRsceToolQtyUnit,
      _ConfirmedProdnRsceToolQtyUnit,
      _RemainingProdnRsceToolQtyUnit,
      _ProdnRsceToolUsageQtyUnit,
      _PlndProdnRsceToolUsageQtyUnit,
      _ConfdProdnRsceToolUsgeQtyUnit,
      _RmngProdnRsceToolUsageQtyUnit,
      _StatusObject,
      _LongText,
      _DocumentProdnRsceTool,
      _EquipmentProdnRsceTool,
      _MaterialProdnRsceTool,
      _MiscProdnRsceTool
}
where affh.loekz is initial;