I_OpActyCompInstceAssignment

@AbapCatalog.sqlViewName: 'IMPEOACMPINSTASS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC@EndUserText.label: 'Assignment of component instance to operation activity'
define view I_OpActyCompInstceAssignment
  as select from mpe_cmp_oai_inst
  association [1..1] to I_OpActyComponentAssignment   as _OpActyComponentAssignment   on  $projection.Reservation        = _OpActyComponentAssignment.Reservation
                                                                                      and $projection.ReservationItem    = _OpActyComponentAssignment.ReservationItem
                                                                                      and $projection.RecordType         = _OpActyComponentAssignment.RecordType
                                                                                      and $projection.OpActyNtwkInstance = _OpActyComponentAssignment.OpActyNtwkInstance
                                                                                      and $projection.OpActyNtwkElement  = _OpActyComponentAssignment.OpActyNtwkElement
  association [1..1] to I_OpActyNtwkInstance          as _OpActyNtwkInstance          on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OpActyNtwkInstanceBasic     as _OpActyNtwkInstanceBasic     on  $projection.OpActyNtwkInstance = _OpActyNtwkInstanceBasic.OpActyNtwkInstance
  association [1..1] to I_OperationActivityInstance   as _OperationActivityInstance   on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                      and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [1..1] to I_ReservationDocumentHeader   as _ReservationHeader           on  $projection.Reservation = _ReservationHeader.Reservation
  association [0..1] to I_InstanceReferenceDesignator as _InstanceReferenceDesignator on  $projection.DgtlMockUpCharcsUUID                   = _InstanceReferenceDesignator.DgtlMockUpCharcsUUID

  association [0..1] to I_OpActyCompInstceAssignment  as _ReltdOpActyCompAssgmt       on  $projection.OpActyNtwkInstance             = _ReltdOpActyCompAssgmt.OpActyNtwkInstance
                                                                                      and $projection.OpActyNtwkElement              = _ReltdOpActyCompAssgmt.OpActyNtwkElement
                                                                                      and $projection.Reservation                    = _ReltdOpActyCompAssgmt.Reservation
                                                                                      and $projection.ReservationItem                = _ReltdOpActyCompAssgmt.ReservationItem
                                                                                      and $projection.RecordType                     = _ReltdOpActyCompAssgmt.RecordType
                                                                                      and $projection.ReltdOriglDgtlMockUpCharcsUUID = _ReltdOpActyCompAssgmt.OriglDgtlMockUpCharcsUUID
  association [0..*] to I_DigitalMockUpCharcs         as _DigitalMockUpCharcs         on  $projection.DgtlMockUpCharcsUUID = _DigitalMockUpCharcs.DgtlMockUpCharcsUUID
  association [0..1] to I_BOMItmMfgRefStrucItmAssgmt  as _BOMItmMfgRefStrucItmAssgmt  on  $projection.MfgRefStrucBOMLeafAssgmtUUID = _BOMItmMfgRefStrucItmAssgmt.MfgRefStrucBOMLeafAssgmtUUID
  association [0..1] to I_MfgReferenceStructureItem   as _MfgReferenceStructureItem   on  $projection.MfgRefStructureItemDetailUUID = _MfgReferenceStructureItem.MfgRefStructureItemUUID
                                                                                      and $projection.MfgRefStrucItmDetIsContextual = ''
  association [0..1] to I_MfgReferenceHierarchyItem   as _MfgReferenceHierarchyItem   on  $projection.MfgRefStructureItemDetailUUID = _MfgReferenceHierarchyItem.MfgRefHierarchyItemUUID
                                                                                      and $projection.MfgRefStrucItmDetIsContextual = 'X'
  association [0..1] to I_MfgRefStrucItemWithDetails  as _MfgRefStrucItemWithDetails  on  $projection.MfgRefStructureItemDetailUUID = _MfgRefStrucItemWithDetails.MfgRefStructureItemUUID
                                                                                      and $projection.MfgRefStrucItmDetIsContextual = ''
  association [0..1] to I_MfgRefHierItemWithDetails   as _MfgRefHierItemWithDetails   on  $projection.MfgRefStructureItemDetailUUID = _MfgRefHierItemWithDetails.MfgRefHierarchyItemUUID
                                                                                      and $projection.MfgRefStrucItmDetIsContextual = 'X'
{
      @ObjectModel.foreignKey.association: '_ReservationHeader'
  key rsnum                         as Reservation,
  key rspos                         as ReservationItem,
  key rsart                         as RecordType,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key oan_instance_id               as OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key oan_element_number            as OpActyNtwkElement,
  key inst_guid                     as OriglDgtlMockUpCharcsUUID,
      tmxguid                       as DgtlMockUpCharcsUUID,
      inst_guid_reference           as ReltdOriglDgtlMockUpCharcsUUID,
      mrs_leaf_assignment_uuid      as MfgRefStrucBOMLeafAssgmtUUID,
      mrs_item_detail_uuid          as MfgRefStructureItemDetailUUID,
      mrs_item_detail_is_contextual as MfgRefStrucItmDetIsContextual,

      _OpActyComponentAssignment,
      _OpActyNtwkInstance,
      _OpActyNtwkInstanceBasic,
      _OperationActivityInstance,
      _ReservationHeader,
      _InstanceReferenceDesignator,
      _ReltdOpActyCompAssgmt,
      _DigitalMockUpCharcs,
      _BOMItmMfgRefStrucItmAssgmt,
      _MfgRefStrucItemWithDetails,
      _MfgRefHierItemWithDetails
}