I_OffsettingAccount

DDL: I_OFFSETTINGACCOUNT Type: view_entity COMPOSITE Package: FINS_FIS_FICO

Offsetting Account

I_OffsettingAccount is a Composite CDS View (Dimension) that provides data about "Offsetting Account" in SAP S/4HANA. It reads from 1 data source (P_OffsettingAccount) and exposes 11 fields with key fields ChartOfAccounts, OffsettingAccountType, OffsettingAccount. It has 6 associations to related views. Part of development package FINS_FIS_FICO.

1 data source(s) 11 fields

Data Sources (1)

SourceAliasJoin Type
P_OffsettingAccount P_OffsettingAccount from

Associations (6)

CardinalityTargetAliasCondition
[0..1] I_ChartOfAccounts _ChartOfAccounts $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
[0..1] I_GLAccountInChartOfAccounts _GLAccount $projection.OffsettingAccount = _GLAccount.ChartOfAccounts and $projection.OffsettingAccount = _GLAccount.GLAccount and ( $projection.OffsettingAccountType = 'S' or $projection.OffsettingAccountType = 'M' or $projection.OffsettingAccountType = 'A' )
[0..1] I_GLAccountInChartOfAccounts _GLAccountInChartOfAccounts $projection.ChartOfAccounts = _GLAccountInChartOfAccounts.ChartOfAccounts and $projection.OffsettingAccount = _GLAccountInChartOfAccounts.GLAccount and ( $projection.OffsettingAccountType = 'S' or $projection.OffsettingAccountType = 'M' or $projection.OffsettingAccountType = 'A' )
[0..1] I_FinancialAccountType _OffsettingAccountType $projection.OffsettingAccountType = _OffsettingAccountType.FinancialAccountType
[0..1] I_Customer _Customer $projection.OffsettingAccount = _Customer.Customer and $projection.OffsettingAccountType = 'D'
[0..1] I_Supplier _Supplier $projection.OffsettingAccount = _Supplier.Supplier and $projection.OffsettingAccountType = 'K'

Annotations (14)

NameValueLevelField
AbapCatalog.entityBuffer.definitionAllowed false view
EndUserText.label Offsetting Account view
Analytics.dataCategory #DIMENSION view
Analytics.technicalName IFIOFFSETACCT view
VDM.viewType #COMPOSITE view
ObjectModel.representativeKey OffsettingAccount view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view
Metadata.ignorePropagatedAnnotations true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
Metadata.allowExtensions true view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY ChartOfAccounts P_OffsettingAccount ChartOfAccounts
KEY OffsettingAccountType P_OffsettingAccount OffsettingAccountType
KEY OffsettingAccount P_OffsettingAccount OffsettingAccount
OffsettingAccountName P_OffsettingAccount OffsettingAccountName
OffsettingAccountShortName P_OffsettingAccount OffsettingAccountShortName
_ChartOfAccounts _ChartOfAccounts
_GLAccountInChartOfAccounts _GLAccountInChartOfAccounts
_GLAccount _GLAccount
_Customer _Customer
_Supplier _Supplier
_OffsettingAccountType _OffsettingAccountType 
 @AbapCatalog.entityBuffer.definitionAllowed: false
 @EndUserText.label: 'Offsetting Account'
@Analytics: {dataCategory: #DIMENSION}
@Analytics.technicalName: 'IFIOFFSETACCT'
@VDM.viewType: #COMPOSITE
@ObjectModel: { representativeKey: 'OffsettingAccount',
                usageType: { sizeCategory: #XL,
                             dataClass:  #MASTER,
                             serviceQuality: #C },
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE],
                modelingPattern: #ANALYTICAL_DIMENSION }
                             
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED 
@Metadata.allowExtensions:true
@Consumption.dbHints:  ['USE_HEX_PLAN']                      

define view entity I_OffsettingAccount
  as select from P_OffsettingAccount as P_OffsettingAccount

  association [0..1] to I_ChartOfAccounts            as _ChartOfAccounts           on  $projection.ChartOfAccounts       = _ChartOfAccounts.ChartOfAccounts
// association is incorrect - do not use

  association [0..1] to I_GLAccountInChartOfAccounts as _GLAccount                 on  $projection.OffsettingAccount     = _GLAccount.ChartOfAccounts
                                                                                  and  $projection.OffsettingAccount     = _GLAccount.GLAccount
                                                                                  and  ( $projection.OffsettingAccountType = 'S' or 
                                                                                         $projection.OffsettingAccountType = 'M' or
                                                                                         $projection.OffsettingAccountType = 'A' )
// correct association                                                                                         

  association [0..1] to I_GLAccountInChartOfAccounts as _GLAccountInChartOfAccounts on  $projection.ChartOfAccounts     = _GLAccountInChartOfAccounts.ChartOfAccounts
                                                                                    and  $projection.OffsettingAccount     = _GLAccountInChartOfAccounts.GLAccount
                                                                                    and  ( $projection.OffsettingAccountType = 'S' or 
                                                                                         $projection.OffsettingAccountType = 'M' or
                                                                                         $projection.OffsettingAccountType = 'A' )                                                                                         
//  association [0..*] to I_OffsettingAccountText     as _Text                      on  $projection.ChartOfAccounts       = _Text.ChartOfAccounts

//                                                                                  and $projection.OffsettingAccount     = _Text.OffsettingAccount

  association [0..1] to I_FinancialAccountType       as _OffsettingAccountType     on  $projection.OffsettingAccountType = _OffsettingAccountType.FinancialAccountType
//  association [0..*] to I_GLAccountHierarchyNode     as _GLAccountHierarchyNode    on  $projection.OffsettingAccount     = _GLAccountHierarchyNode.GLAccount

//                                                                                  and  $projection.ChartOfAccounts       = _GLAccountHierarchyNode.ChartOfAccounts

//                                                                                  and  $projection.OffsettingAccountType = 'S'

  association [0..1] to I_Customer                   as _Customer                  on  $projection.OffsettingAccount     = _Customer.Customer
                                                                                  and  $projection.OffsettingAccountType = 'D'                                                                                                                                                   
  association [0..1] to I_Supplier                   as _Supplier                  on  $projection.OffsettingAccount     = _Supplier.Supplier
                                                                                  and  $projection.OffsettingAccountType = 'K'
{
  @ObjectModel.foreignKey.association: '_ChartOfAccounts' //Inserted by VDM CDS Suite Plugin

  key P_OffsettingAccount.ChartOfAccounts,
  @ObjectModel.foreignKey.association: '_OffsettingAccountType'                  
  key P_OffsettingAccount.OffsettingAccountType,
  @ObjectModel.text.element: ['OffsettingAccountName']
  key P_OffsettingAccount.OffsettingAccount,
  
  @Semantics.text: true
  P_OffsettingAccount.OffsettingAccountName,
  @Semantics.text: true
  @Consumption.hidden: true
  P_OffsettingAccount.OffsettingAccountShortName,
       
      _ChartOfAccounts,
      _GLAccountInChartOfAccounts,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    '_GLAccountInChartOfAccounts'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: '_GLAccountInChartOfAccounts'            
      _GLAccount,
//      _GLAccountHierarchyNode,

      _Customer,
      _Supplier,
      _OffsettingAccountType
};

Learn More