I_MaintenancePackageText

@AbapCatalog.sqlViewName: 'IMNTPCKGTXT'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Package - Text'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'MaintenancePackage'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@VDM.viewType: #BASIC
@Analytics.dataExtraction.enabled: true
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [ #EXTRACTION_DATA_SOURCE ]
@Metadata.ignorePropagatedAnnotations: true
define view I_MaintenancePackageText
  as select from t351x
  
  association [0..1] to I_MaintenanceStrategy as _MaintenanceStrategy on  _MaintenanceStrategy.MaintenanceStrategy = $projection.MaintenanceStrategy
  
  association [0..1] to I_MaintenancePackage  as _MaintenancePackage  on  _MaintenancePackage.MaintenanceStrategy = $projection.MaintenanceStrategy
                                                                      and _MaintenancePackage.MaintenancePackage  = $projection.MaintenancePackage
  
  association [0..1] to I_Language            as _Language            on  _Language.Language = $projection.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key spras as Language,

      @ObjectModel.foreignKey.association: '_MaintenanceStrategy'
  key strat as MaintenanceStrategy,

      @ObjectModel.foreignKey.association: '_MaintenancePackage'
  key paket as MaintenancePackage,

      @Semantics.text: true
      ktex1 as MaintenancePackageText,
      
      @Semantics.text: true
      ktxhi as MaintPackageHierarchyShortText,

      @Semantics.text: true
      kzyk1 as MaintenanceCycleShortText,
      
      @Semantics.text: true
      koff1 as StartOffsetShortText,

      /* Associations - locally defined */
      _Language,
      _MaintenancePackage,
      _MaintenanceStrategy
}