I_MaintenancePackage

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Package'
@ObjectModel.representativeKey: 'MaintenancePackage'
@Analytics.technicalName: 'IMNTPCKG'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@VDM.viewType: #BASIC
@ObjectModel.modelingPattern: #VALUE_HELP_PROVIDER
@Metadata.ignorePropagatedAnnotations: true
@Analytics.dataExtraction.enabled: true
@ObjectModel.supportedCapabilities: [ #EXTRACTION_DATA_SOURCE ]
@ObjectModel.sapObjectNodeType.name: 'MaintenancePackage'
define view entity I_MaintenancePackage
  as select from t351p

  association [0..1] to I_MaintenanceStrategy       as _MaintenanceStrategy         on  _MaintenanceStrategy.MaintenanceStrategy = $projection.MaintenanceStrategy

  association [0..*] to I_MaintenancePackageText    as _MaintenancePackageText      on  _MaintenancePackageText.MaintenanceStrategy = $projection.MaintenanceStrategy
                                                                                    and _MaintenancePackageText.MaintenancePackage  = $projection.MaintenancePackage                                                                         
  association [0..1] to I_UnitOfMeasure             as _MaintenancePackageUnit      on _MaintenancePackageUnit.UnitOfMeasure = $projection.MaintenanceTaskPerformanceUnit
  
{
      @ObjectModel.foreignKey.association: '_MaintenanceStrategy'
  key strat as MaintenanceStrategy,

      @ObjectModel.text.association: '_MaintenancePackageText'
  key zaehl as MaintenancePackage,

      @ObjectModel.foreignKey.association: '_MaintenancePackageUnit'
      zeieh as MaintenanceTaskPerformanceUnit,

      zykzt as MaintenancePackageCycle,
           
      offzt as MaintPackageTimeStartOffset,         

      hiera as MaintenancePackageNature,
      
      puffp as MaintenanceLeadFloatInDays,
      
      puffn as FollowUpFloat,                      
      
      perkn as MaintPackagePeriodType,              
      
      eroef as CallHorizonInDays,

      /* Associations - locally defined */
      _MaintenancePackageText,
      _MaintenanceStrategy,
      _MaintenancePackageUnit
}