I_MaintOrderSubOperationTP

@AbapCatalog.sqlViewName: 'IMTORDSUBOPERTP'
@EndUserText.label: 'MaintOrder Sub-Operation w/ Tech. Object'
@ObjectModel.writeDraftPersistence: 'MAINTORDSOP_D'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.draftEnabled: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL

@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.semanticKey: ['MaintenanceOrder', 'MaintenanceOrderOperation', 'MaintenanceOrderSubOperation']

define view I_MaintOrderSubOperationTP
  as select from I_MaintOrderSubOperTechObj

  association [1..1] to I_MaintOrderTP          as _MaintOrderTP          on  _MaintOrderTP.MaintenanceOrder = $projection.MaintenanceOrder

  association [0..*] to I_MaintOrderComponentTP as _MaintOrderComponentTP on  _MaintOrderComponentTP.MaintenanceOrder          = $projection.MaintenanceOrder
                                                                          and _MaintOrderComponentTP.MaintenanceOrderOperation = $projection.MaintenanceOrderOperation

  association [1..1] to I_MaintOrderOperationTP as _MaintOrderOperationTP on  _MaintOrderOperationTP.MaintenanceOrder          = $projection.MaintenanceOrder
                                                                          and _MaintOrderOperationTP.MaintenanceOrderOperation = $projection.MaintenanceOrderOperation
  association [0..1] to I_Indicator             as _IsFinallyConfirmed    on  $projection.IsFinallyConfirmed = _IsFinallyConfirmed.IndicatorValue
  association [0..*] to I_StatusObjectStatus    as _StatusObjectStatus    on  $projection.MaintOrderOperationInternalID = _StatusObjectStatus.StatusObject

{

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_TechnicalObjectStdVH',
                     element: 'MaintenanceOrder' }
        }]
      // ]--GENERATED

  key I_MaintOrderSubOperTechObj.MaintenanceOrder,
  key I_MaintOrderSubOperTechObj.MaintenanceOrderOperation,
  key I_MaintOrderSubOperTechObj.MaintenanceOrderSubOperation,
      I_MaintOrderSubOperTechObj.MaintenanceOrderSubOperation as MaintOrderSubOperationForEdit,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_TechnicalObjectStdVH',
                     element: 'TechnicalObject' },
          additionalBinding: [{ localElement: 'TechObjIsEquipOrFuncnlLoc',
                                element: 'TechObjIsEquipOrFuncnlLoc' }]
        }]
      // ]--GENERATED

      I_MaintOrderSubOperTechObj.TechnicalObject,
      I_MaintOrderSubOperTechObj.TechObjIsEquipOrFuncnlLoc,
      I_MaintOrderSubOperTechObj.ControllingArea,
      I_MaintOrderSubOperTechObj.MaintOrderRoutingNumber,
      I_MaintOrderSubOperTechObj.MaintOrderOperationCounter,
      I_MaintOrderSubOperTechObj.OperationControlKey,
      I_MaintOrderSubOperTechObj.OperationDescription,
      I_MaintOrderSubOperTechObj.MaintOrderOperationInternalID,
      I_MaintOrderSubOperTechObj.Equipment,
      I_MaintOrderSubOperTechObj.FunctionalLocation,
      I_MaintOrderSubOperTechObj.Plant,
      I_MaintOrderSubOperTechObj.OperationWorkCenterInternalID,
      I_MaintOrderSubOperTechObj.OperationWorkCenterTypeCode,
      I_MaintOrderSubOperTechObj.OperationPurgInfoRecdSearchTxt,
      I_MaintOrderSubOperTechObj.OperationRequisitionerName,
      I_MaintOrderSubOperTechObj.OperationGoodsRecipientName,
      I_MaintOrderSubOperTechObj.OpExternalProcessingPrice,
      I_MaintOrderSubOperTechObj.OpExternalProcessingPriceUnit,
      I_MaintOrderSubOperTechObj.OpExternalProcessingCurrency,
      I_MaintOrderSubOperTechObj.OperationTrackingNumber,
      I_MaintOrderSubOperTechObj.OperationPurchasingInfoRecord,
      I_MaintOrderSubOperTechObj.OperationUnloadingPointName,
      I_MaintOrderSubOperTechObj.OpPurchaseOutlineAgreement,
      I_MaintOrderSubOperTechObj.OpPurchaseOutlineAgreementItem,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Supplier_VH',
                     element: 'Supplier' }
        }]
      // ]--GENERATED

      I_MaintOrderSubOperTechObj.OperationSupplier,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_PersWrkAgrmtSrchHelp',
                     element: 'PersonWorkAgreement' }
        }]
      // ]--GENERATED

      I_MaintOrderSubOperTechObj.OperationPersonResponsible,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaterialStdVH',
                     element: 'Material' }
        }]
      // ]--GENERATED

      I_MaintOrderSubOperTechObj.Assembly,
      I_MaintOrderSubOperTechObj.OperationSystemCondition,
      I_MaintOrderSubOperTechObj.CostCtrActivityType,
      I_MaintOrderSubOperTechObj.ReqgCostCenterControllingArea,
      I_MaintOrderSubOperTechObj.OperationCalculationControl,
      I_MaintOrderSubOperTechObj.OperationWorkPercent,
      I_MaintOrderSubOperTechObj.CapacityRequirement,
      I_MaintOrderSubOperTechObj.CapacityRequirementItem,
      I_MaintOrderSubOperTechObj.PurchaseRequisition,
      I_MaintOrderSubOperTechObj.PurchaseRequisitionItem,
      I_MaintOrderSubOperTechObj.NumberOfCapacities,
      I_MaintOrderSubOperTechObj.OperationPlannedWork,
      I_MaintOrderSubOperTechObj.OperationPlannedWorkUnit,
      I_MaintOrderSubOperTechObj.OperationDuration,
      I_MaintOrderSubOperTechObj.OperationDurationUnit,
      I_MaintOrderSubOperTechObj.OperationWorkCenter,
      I_MaintOrderSubOperTechObj.CostElement,
      I_MaintOrderSubOperTechObj.MaterialGroup,
      I_MaintOrderSubOperTechObj.PurchasingGroup,
      I_MaintOrderSubOperTechObj.PurchasingOrganization,
      I_MaintOrderSubOperTechObj.Language,
      I_MaintOrderSubOperTechObj.OperationHasLongText,
      I_MaintOrderSubOperTechObj.IsDeleted,
      I_MaintOrderSubOperTechObj.MaintOperationExecStageCode,
      I_MaintOrderSubOperTechObj.MaintOrdOpProcessPhaseCode,
      I_MaintOrderSubOperTechObj.MaintOrdOpProcessSubPhaseCode,

      @ObjectModel.foreignKey.association: '_IsFinallyConfirmed'
      cast(
        case when _StatusObjectStatus[1: StatusCode = 'I0009'].StatusCode is not null
              and  _StatusObjectStatus[1: StatusCode = 'I0009'].StatusIsInactive <> 'X'
        then 'X' else '' end
      as eams_finally_confirmed )                             as IsFinallyConfirmed,
      I_MaintOrderSubOperTechObj._OperationControlKey.ConfirmationIsNotPossible,

      I_MaintOrderSubOperTechObj._ActivityType,
      I_MaintOrderSubOperTechObj._CostElement,
      I_MaintOrderSubOperTechObj._MaterialGroup,
      I_MaintOrderSubOperTechObj._Assembly,
      I_MaintOrderSubOperTechObj._MaintenanceOperationComponent,
      I_MaintOrderSubOperTechObj._MaintenanceOrder,
      I_MaintOrderSubOperTechObj._MaintenanceOrderOperation,
      I_MaintOrderSubOperTechObj._OperationCalculationControl,
      I_MaintOrderSubOperTechObj._OperationControlKey,
      I_MaintOrderSubOperTechObj._OperationPlanningValues,
      I_MaintOrderSubOperTechObj._OperationSystemCondition,
      I_MaintOrderSubOperTechObj._OpExternalProcessingCurrency,
      I_MaintOrderSubOperTechObj._PlannedWorkUnitOfMeasure,
      I_MaintOrderSubOperTechObj._Plant,
      I_MaintOrderSubOperTechObj._StatusObject,
      I_MaintOrderSubOperTechObj._TechnicalObject,
      I_MaintOrderSubOperTechObj._TechObjIsEquipOrFuncnlLoc,
      I_MaintOrderSubOperTechObj._WorkCenter,
      I_MaintOrderSubOperTechObj._MaintOrderOperObjectListLink,
      I_MaintOrderSubOperTechObj._OperationHasLongText,
      I_MaintOrderSubOperTechObj._Supplier,
      I_MaintOrderSubOperTechObj._PersonResponsible,
      I_MaintOrderSubOperTechObj._MaintOperationExecStageCode,
      I_MaintOrderSubOperTechObj._EAMProcessPhase,
      I_MaintOrderSubOperTechObj._EAMProcessSubPhase,
      _IsFinallyConfirmed,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _MaintOrderTP,

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _MaintOrderOperationTP,

      _MaintOrderComponentTP

}
where
  I_MaintOrderSubOperTechObj.IsDeleted = '' --where _IsDeletedStatus.StatusObject is null