I_MaintOrderSubOperTechObj

@EndUserText.label: 'MaintOrder Sub-Operation w/ Tech. Object'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AbapCatalog.sqlViewName: 'IMTORDSOPTECOBJ'

@ObjectModel.representativeKey: 'MaintenanceOrderSubOperation'
@ObjectModel.semanticKey:  [ 'MaintenanceOrder', 'MaintenanceOrderOperation', 'MaintenanceOrderSubOperation' ]

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

define view I_MaintOrderSubOperTechObj
  as select from I_MaintenanceOrderSubOperation
  association [1..1] to I_MaintOrderTechObj            as _MaintenanceOrder              on  $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder
  association [1..1] to I_MaintOrderOperTechObj        as _MaintenanceOrderOperation     on  $projection.MaintenanceOrder          = _MaintenanceOrderOperation.MaintenanceOrder
                                                                                         and $projection.MaintenanceOrderOperation = _MaintenanceOrderOperation.MaintenanceOrderOperation
  association [0..*] to I_MaintOrderOperComp           as _MaintenanceOperationComponent on  $projection.MaintenanceOrder          = _MaintenanceOperationComponent.MaintenanceOrder
                                                                                         and $projection.MaintenanceOrderOperation = _MaintenanceOperationComponent.MaintenanceOrderOperation
  association [0..1] to I_TechnicalObject              as _TechnicalObject               on  $projection.TechnicalObject           = _TechnicalObject.TechnicalObject
                                                                                         and $projection.TechObjIsEquipOrFuncnlLoc = _TechnicalObject.TechObjIsEquipOrFuncnlLoc
  association [0..1] to I_TechObjIsEquipOrFuncnlLoc    as _TechObjIsEquipOrFuncnlLoc     on  $projection.TechObjIsEquipOrFuncnlLoc = _TechObjIsEquipOrFuncnlLoc.TechObjIsEquipOrFuncnlLoc
  association [0..*] to I_CostCenterActivityType       as _ActivityType                  on  $projection.ControllingArea     = _ActivityType.ControllingArea
                                                                                         and $projection.CostCtrActivityType = _ActivityType.CostCtrActivityType
  association [0..1] to I_CostElement                  as _CostElement                   on  $projection.ControllingArea = _CostElement.ControllingArea
                                                                                         and $projection.CostElement     = _CostElement.CostElement
  association [0..1] to I_MaterialGroup                as _MaterialGroup                 on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_MaintOrderOperObjectListLink as _MaintOrderOperObjectListLink  on  $projection.MaintOrderOperationCounter = _MaintOrderOperObjectListLink.MaintOrderOperationCounter
                                                                                         and $projection.MaintOrderRoutingNumber    = _MaintOrderOperObjectListLink.MaintOrderRoutingNumber
  association [0..*] to I_StatusObjectStatus           as _StatusObjectStatus            on  $projection.MaintOrderOperationInternalID = _StatusObjectStatus.StatusObject
  association [0..1] to I_Indicator                    as _IsDeleted                     on  $projection.IsDeleted = _IsDeleted.IndicatorValue
{
      @ObjectModel.foreignKey.association: '_MaintenanceOrder'
  key I_MaintenanceOrderSubOperation.MaintenanceOrder,
      @ObjectModel.foreignKey.association: '_MaintenanceOrderOperation'
  key I_MaintenanceOrderSubOperation.MaintenanceOrderOperation,
  key I_MaintenanceOrderSubOperation.MaintenanceOrderSubOperation,

      @ObjectModel.foreignKey.association: '_TechnicalObject'
      cast( case when _MaintOrderOperObjectListLink.MaintenanceItemObject is not null then
        case when _MaintOrderOperObjectListLink._MaintenanceItemObject.Equipment <> '' then _MaintOrderOperObjectListLink._MaintenanceItemObject.Equipment
        else _MaintOrderOperObjectListLink._MaintenanceItemObject.FunctionalLocation end
           else case when Equipment != '' then
                          Equipment
                     when Equipment = '' and
                          FunctionalLocation != '' then
                          FunctionalLocation
                     else '' end
       end as eams_tec_obj )                                                                                                    as TechnicalObject,

      @ObjectModel.foreignKey.association: '_TechObjIsEquipOrFuncnlLoc'
      case when _MaintOrderOperObjectListLink.MaintenanceItemObject is not null then
          case when _MaintOrderOperObjectListLink._MaintenanceItemObject.Equipment <> '' then cast('EAMS_EQUI' as eams_tec_obj_type_value )
          when _MaintOrderOperObjectListLink._MaintenanceItemObject.FunctionalLocation <> '' then cast('EAMS_FL' as eams_tec_obj_type_value )
          else cast('' as eams_tec_obj_type_value ) end
      else case when Equipment != '' then
                           cast ( 'EAMS_EQUI' as eams_tec_obj_type_value)
           when Equipment = '' and
                          FunctionalLocation != '' then
                           cast ( 'EAMS_FL' as eams_tec_obj_type_value)
           else cast('' as eams_tec_obj_type_value ) end
      end                                                                                                                       as TechObjIsEquipOrFuncnlLoc,

      /* Fields */
      _MaintenanceOrder._Order.ControllingArea                                                                                  as ControllingArea,

      I_MaintenanceOrderSubOperation.MaintOrderRoutingNumber,
      I_MaintenanceOrderSubOperation.MaintOrderOperationCounter,
      I_MaintenanceOrderSubOperation.OperationControlKey,
      I_MaintenanceOrderSubOperation.OperationDescription,
      I_MaintenanceOrderSubOperation.MaintOrderOperationInternalID,
      I_MaintenanceOrderSubOperation.Equipment,
      I_MaintenanceOrderSubOperation.FunctionalLocation,
      I_MaintenanceOrderSubOperation.Plant,
      I_MaintenanceOrderSubOperation.OperationWorkCenterInternalID,
      I_MaintenanceOrderSubOperation.OperationWorkCenterTypeCode,
      I_MaintenanceOrderSubOperation.OperationPurgInfoRecdSearchTxt,
      I_MaintenanceOrderSubOperation.OperationRequisitionerName,
      I_MaintenanceOrderSubOperation.OperationGoodsRecipientName,
      I_MaintenanceOrderSubOperation.OpExternalProcessingPrice,
      I_MaintenanceOrderSubOperation.OpExternalProcessingPriceUnit,
      I_MaintenanceOrderSubOperation.OpExternalProcessingCurrency,
      I_MaintenanceOrderSubOperation.OperationTrackingNumber,
      I_MaintenanceOrderSubOperation.OperationPurchasingInfoRecord,
      I_MaintenanceOrderSubOperation.OperationUnloadingPointName,
      I_MaintenanceOrderSubOperation.OpPurchaseOutlineAgreement,
      I_MaintenanceOrderSubOperation.OpPurchaseOutlineAgreementItem,
      I_MaintenanceOrderSubOperation.OperationSupplier,
      I_MaintenanceOrderSubOperation.OperationPersonResponsible,
      I_MaintenanceOrderSubOperation.Assembly,
      I_MaintenanceOrderSubOperation.OperationSystemCondition,
      I_MaintenanceOrderSubOperation.CostCtrActivityType,
      I_MaintenanceOrderSubOperation.ReqgCostCenterControllingArea,
      I_MaintenanceOrderSubOperation.OperationCalculationControl,
      I_MaintenanceOrderSubOperation.OperationWorkPercent,
      I_MaintenanceOrderSubOperation.CapacityRequirement,
      I_MaintenanceOrderSubOperation.CapacityRequirementItem,
      I_MaintenanceOrderSubOperation.PurchaseRequisition,
      I_MaintenanceOrderSubOperation.PurchaseRequisitionItem,
      I_MaintenanceOrderSubOperation.NumberOfCapacities,
      I_MaintenanceOrderSubOperation.CostElement,
      I_MaintenanceOrderSubOperation.MaterialGroup,
      I_MaintenanceOrderSubOperation.PurchasingGroup,
      I_MaintenanceOrderSubOperation.PurchasingOrganization,
      I_MaintenanceOrderSubOperation.Language,
      I_MaintenanceOrderSubOperation.OperationHasLongText,
      I_MaintenanceOrderSubOperation.MaintOperationExecStageCode,
      I_MaintenanceOrderSubOperation.MaintOrdOpProcessPhaseCode,
      I_MaintenanceOrderSubOperation.MaintOrdOpProcessSubPhaseCode,

      I_MaintenanceOrderSubOperation._OperationPlanningValues.OperationPlannedWork,
      I_MaintenanceOrderSubOperation._OperationPlanningValues.OperationPlannedWorkUnit,
      I_MaintenanceOrderSubOperation._OperationPlanningValues.OperationDuration,
      I_MaintenanceOrderSubOperation._OperationPlanningValues.OperationDurationUnit,
      I_MaintenanceOrderSubOperation._OperationPlanningValues._PlannedWorkUnitOfMeasure,

      I_MaintenanceOrderSubOperation._WorkCenter.WorkCenter                                                                     as OperationWorkCenter,

      @ObjectModel.foreignKey.association: '_IsDeleted'
      case when _StatusObjectStatus[1: StatusCode = 'I0013'].StatusCode is not null
           and  _StatusObjectStatus[1: StatusCode = 'I0013'].StatusIsInactive <> 'X'
      then 'X' else ''
      end                                                                                                                       as IsDeleted,

      /* Associations from  I_MaintenanceOrderOperation */
      I_MaintenanceOrderSubOperation._OperationControlKey,
      I_MaintenanceOrderSubOperation._OperationPlanningValues,
      I_MaintenanceOrderSubOperation._OpExternalProcessingCurrency,
      //I_MaintenanceOrderOperation._PersonResponsible,

      I_MaintenanceOrderSubOperation._OperationSystemCondition,
      I_MaintenanceOrderSubOperation._Plant,
      I_MaintenanceOrderSubOperation._StatusObject,
      I_MaintenanceOrderSubOperation._WorkCenter,
      I_MaintenanceOrderSubOperation._OperationCalculationControl,
      I_MaintenanceOrderSubOperation._Assembly,
      I_MaintenanceOrderSubOperation._Language,
      I_MaintenanceOrderSubOperation._OperationHasLongText,
      I_MaintenanceOrderSubOperation._Supplier,
      I_MaintenanceOrderSubOperation._PersonResponsible,
      I_MaintenanceOrderSubOperation._MaintOperationExecStageCode,
      I_MaintenanceOrderSubOperation._EAMProcessPhase,
      I_MaintenanceOrderSubOperation._EAMProcessSubPhase,
      

      /* Local associations */
      _MaintenanceOrder,
      _MaintenanceOrderOperation,
      _MaintenanceOperationComponent,
      _TechnicalObject,
      _TechObjIsEquipOrFuncnlLoc,
      _ActivityType,
      _CostElement,
      _MaterialGroup,
      _MaintOrderOperObjectListLink,
      _IsDeleted
}