I_MRPMfgOrder

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IMRPMFGORDER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'MRP Manufacturing Order'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED

@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #REQUIRED

define view I_MRPMfgOrder
  as select from   I_ManufacturingOrder     as MfgOrder
    inner join     I_ManufacturingOrderItem as MfgOrderItem on  MfgOrderItem.ManufacturingOrder           = MfgOrder.ManufacturingOrder
                                                            and MfgOrderItem.OrderItemIsNotRelevantForMRP = ''
    inner join     I_ProductPlant as ProductPlant on  ProductPlant.Product = MfgOrderItem.Material
                                                  and ProductPlant.Plant   = MfgOrderItem.PlanningPlant
    left outer join(
                   I_ManufacturingOrder     as TopLevelOrder
        inner join I_ManufacturingOrderItem as OrderItem    on  OrderItem.ManufacturingOrder     = TopLevelOrder.ManufacturingOrder
                                                            and OrderItem.ManufacturingOrderItem = '0001'
    )
    on  TopLevelOrder.Reservation                = MfgOrder.SettlementReservation
    and TopLevelOrder.MfgOrderHierarchyLevel     = 0
    and TopLevelOrder.MfgOrderIsPartOfCollvOrder = 'X'

  association [1..1] to I_ProductSupplyPlanning       as _ProductSupplyPlanning on  $projection.Material = _ProductSupplyPlanning.Product
                                                                                and $projection.MRPPlant = _ProductSupplyPlanning.Plant
  association [0..1] to I_EntProjectResponsiblePerson as _ProjectRespPersn      on  $projection.WBSElementInternalID = _ProjectRespPersn.WBSElementInternalID
                                                                                and _ProjectRespPersn.WBSElementInternalID is not initial
  
{
  key MfgOrderItem.ManufacturingOrder,
  key MfgOrderItem.ManufacturingOrderItem,
      MfgOrder.ManufacturingOrderCategory,
      MfgOrder.ManufacturingOrderType,
      MfgOrderItem.Material,
      MfgOrderItem.PlanningPlant as MRPPlant,
      MfgOrderItem.ProductionPlant,
      MfgOrderItem.MaterialGoodsReceiptDuration,
      @Semantics.businessDate.from: true
      MfgOrder.MfgOrderPlannedStartDate,
      @Semantics.businessDate.to: true
      MfgOrder.MfgOrderPlannedEndDate,
      @Semantics.businessDate.from: true
      MfgOrder.MfgOrderActualStartDate,
      @Semantics.businessDate.to: true
      MfgOrder.MfgOrderActualEndDate,
      @Semantics.businessDate.at: true
      MfgOrder.MfgOrderActualReleaseDate,
      @Semantics.businessDate.from: true
      MfgOrder.MfgOrderScheduledStartDate,
      @Semantics.businessDate.to: true
      MfgOrder.MfgOrderScheduledEndDate,
      @Semantics.businessDate.at: true
      MfgOrder.MfgOrderScheduledReleaseDate,
      @Semantics.unitOfMeasure: true
      MfgOrder.ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrder.MfgOrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrder.MfgOrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrder.ExpectedDeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrder.ActualDeliveredQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      (MfgOrder.MfgOrderPlannedTotalQty - MfgOrder.MfgOrderPlannedScrapQty - MfgOrder.ExpectedDeviationQuantity - MfgOrder.ActualDeliveredQuantity) as  OpenQuantity,
      MfgOrder.ManufacturingOrderImportance,
      MfgOrder.MfgOrderIsPartOfCollvOrder,

      // Material/product data

      _ProductSupplyPlanning.PlannedDeliveryDurationInDays                                                                                          as  MaterialPlannedDeliveryDurn,
      //      @ObjectModel.text.element:  'PurchasingGroupName'

      ProductPlant.PurchasingGroup,
      //      case _PurchasingGroup.PhoneNumberExtension

      //        when '' then _PurchasingGroup.PurchasingGroupPhoneNumber

      //        else concat(_PurchasingGroup.PhoneNumber, concat('-', _PurchasingGroup.PhoneNumberExtension))

      //      end as PurchasingGroupPhoneNumber,

      _ProductSupplyPlanning.TotalReplenishmentLeadTime,
      _ProductSupplyPlanning.FixedLotSizeQuantity, // MaterialFixedLotSizeQuantity

      _ProductSupplyPlanning.MinimumLotSizeQuantity, //MaterialMinLotSizeQuantity,

      _ProductSupplyPlanning.MaximumLotSizeQuantity, //MaterialMaxLotSizeQuantity,

      _ProductSupplyPlanning.LotSizeRoundingQuantity, //MaterialRoundingQuantity

      _ProductSupplyPlanning.RoundingProfile, //MaterialRoundingProfile


      // Sales Order

      MfgOrderItem.SalesOrder,
      MfgOrderItem.SalesOrderItem,
      MfgOrderItem._SalesOrder.SalesOrderType,
      MfgOrderItem._SalesOrderItem.Material                                                                                                         as  SalesOrderItemMaterial,
      MfgOrderItem._SalesOrder.SoldToParty                                                                                                          as  Customer,

      // Production Version

      MfgOrderItem._ProductionVersion.ProductionVersionText,
      MfgOrderItem.ProductionVersion,
      MfgOrderItem._ProductionVersion.ProductionLine,

      // WBS Element

      MfgOrderItem.WBSElementInternalID_2                                                                                                           as WBSElementInternalID,
      MfgOrderItem._WBSElementBasicData2.WBSElementExternalID                                                                                       as WBSElement, //ExternalID

      MfgOrderItem._WBSElementBasicData2.WBSDescription,
      
      cast( _ProjectRespPersn.PersonWorkAgreement as ps_s4_vernr preserving type )                                                                  as ResponsiblePerson,
      _ProjectRespPersn._WorkforcePerson.PersonFullName                                                                                             as ResponsiblePersonName,
      
      MfgOrderItem._WBSElementBasicData2._Project.ProjectInternalID,
      MfgOrderItem._WBSElementBasicData2._Project.ProjectExternalID                                                                                 as Project, //ExternalID

      MfgOrderItem._WBSElementBasicData2._Project.ProjectDescription,
      cast( _ProjectRespPersn.PersonWorkAgreement as ps_s4_vernr preserving type )                                                                  as ProjectResponsiblePerson,
      _ProjectRespPersn._WorkforcePerson.PersonFullName                                                                                             as ProjectResponsiblePersonName,
      
      // Top Level Order

      TopLevelOrder.ManufacturingOrder                                                                                                              as  TopLevelOrder,
      OrderItem.Material                                                                                                                            as  TopLevelOrderMaterial,

      // Progress status

      case
          when MfgOrder.MfgOrderActualReleaseDate <> '00000000' //afko.ftrmi

             then 2 //'released'

          when MfgOrder.MfgOrderActualStartDate <> '00000000' //afko.gstri

             then 3 //'in progress'

          when MfgOrder.MfgOrderActualEndDate <> '00000000' //afko.getri

             then 4 //'finished'

         else 1 //'created'

      end                                                                                                                                           as  MfgOrderProgressStatus,

      // MRP Controller

      MfgOrder.MRPController,
      MfgOrder.ProductionSupervisor,
      MfgOrderItem._WBSElementBasicData2
};