I_LCMContextEntity

@AbapCatalog.sqlViewName: 'ILCMCTXENT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType : #BASIC

@ObjectModel: {
  representativeKey: 'LglCntntMCntxtEntityUUID',
  usageType.serviceQuality: #A,
  usageType.sizeCategory: #L,
  usageType.dataClass: #TRANSACTIONAL
}

@AccessControl.personalData.blocking: #REQUIRED

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'Basic view for LCM Context Entity'
define view I_LCMContextEntity
  as select from lcm_ctx_entity

  association [1..1] to I_LcmContext             as _LglCntntMContext       on  $projection.LglCntntMContextUUID = _LglCntntMContext.LglCntntMContextUUID
  association [0..1] to I_LCMEntityType          as _LCMEntityType          on  _LCMEntityType.LglCntntMEntityType = $projection.LglCntntMEntityType
  association [0..*] to I_LCMEntityTypeText      as _MainEntityTypeText     on  $projection.LglCntntMEntityType = _MainEntityTypeText.LglCntntMEntityType

  association [0..1] to I_PurchasingOrganization as _PurchasingOrganization on  _PurchasingOrganization.PurchasingOrganization = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType            = '05'

  association [0..1] to I_Supplier               as _Supplier               on  _Supplier.Supplier                  = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType = '01'

  association [0..1] to I_SalesOrganizationText  as _SalesOrganizationText  on  _SalesOrganizationText.SalesOrganization = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType      = '04'
                                                                            and _SalesOrganizationText.Language          = $session.system_language

  association [0..1] to I_Customer               as _Customer               on  _Customer.Customer                  = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType = '02'

  association [0..1] to I_CompanyCode            as _CompanyCode            on  _CompanyCode.CompanyCode            = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType = '03'

  association [0..1] to I_BusinessPartner        as _BusinessPartner        on  _BusinessPartner.BusinessPartner    = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType = '06'

  // ESH association

  association [0..1] to I_LCMEntityTypeText      as _EntityTypeText         on  $projection.LglCntntMEntityType = _EntityTypeText.LglCntntMEntityType
                                                                            and _EntityTypeText.Language        = $session.system_language

{

  key lglcntntmcntxtentityuuid               as LglCntntMCntxtEntityUUID,
      lglcntntmcontextuuid                   as LglCntntMContextUUID,
      _LCMEntityType.LglCntntMTechEntityType as LglCntntMTechEntityType,
      lglcntntmrank                          as LglCntntMRank,
      lglcntntmentity                        as LglCntntMEntity,
      lglcntntmentitytype                    as LglCntntMEntityType,
      lglcntntmismandatory                   as LglCntntMIsMandatory,
      lglcntntmismainentity                  as LglCntntMIsMainEntity,
      lglcntntmisintegrelevant               as LglCntntMIsIntegRelevant,

      //Authorization

      _LglCntntMContext,

      _EntityTypeText,
      _MainEntityTypeText,
      _PurchasingOrganization,
      _Supplier,
      _SalesOrganizationText,
      _Customer,
      _CompanyCode,
      _BusinessPartner
}