I_JVANonOperatorInvoiceFDP

@AbapCatalog.sqlViewName: 'IJVANONOPTRIVFDP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Non Operator Invoice Data'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_JVANonOperatorInvoiceFDP
  as select from I_GLAccountLineItem
    inner join   I_JVALedger as ld                on ld.CompanyCode = I_GLAccountLineItem.CompanyCode
    inner join   bseg        as _AccountingDocSeg on  I_GLAccountLineItem.CompanyCode        = _AccountingDocSeg.bukrs
                                                  and I_GLAccountLineItem.AccountingDocument = _AccountingDocSeg.belnr
                                                  and I_GLAccountLineItem.FiscalYear         = _AccountingDocSeg.gjahr
  association [1..1] to I_JntVntrCoCodeParam     as _JV_Company         on  $projection.CompanyCode = _JV_Company.CompanyCode
  association [1..1] to I_AccountingDocument     as _AccountingDocHdr   on  $projection.CompanyCode        = _AccountingDocHdr.CompanyCode
                                                                        and $projection.AccountingDocument = _AccountingDocHdr.AccountingDocument
                                                                        and $projection.FiscalYear         = _AccountingDocHdr.FiscalYear
  association [1..1] to I_JointVentureDetails    as _Venture            on  $projection.JointVenture            = _Venture.JointVenture
                                                                        and $projection.CompanyCode             = _Venture.CompanyCode
                                                                        and $projection.JointVentureEquityGroup = _Venture.JntOpgAgrmtEquityGrp
  association [1..1] to I_JointVentureDesc       as _Venture_Desc       on  $projection.JointVenture = _Venture_Desc.JointVenture
                                                                        and $projection.CompanyCode  = _Venture_Desc.CompanyCode
                                                                        and _Venture_Desc.Language   = $session.system_language
  association [1..1] to I_JntVntrBusinessPartner as _Partner            on  $projection.CompanyCode         = _Partner.CompanyCode
                                                                        and $projection.JointVenturePartner = _Partner.JointVenturePartner
  association [1..1] to I_Customer               as _Partner_Data       on  $projection.JointVenturePartner = _Partner_Data.Customer
  association [1..1] to I_JntVntrEquityGrp       as _VentureEquity_Data on  $projection.JointVenture            = _VentureEquity_Data.JointVenture
                                                                        and $projection.CompanyCode             = _VentureEquity_Data.CompanyCode
                                                                        and $projection.JointVentureEquityGroup = _VentureEquity_Data.JntOpgAgrmtEquityGrp
  association [1..1] to I_JntVntrEquityGrpText   as _Equity_Desc        on  $projection.CompanyCode             = _Equity_Desc.CompanyCode
                                                                        and $projection.JointVenture            = _Equity_Desc.JointVenture
                                                                        and $projection.JointVentureEquityGroup = _Equity_Desc.JntOpgAgrmtEquityGrp
                                                                        and _Equity_Desc.Language               = $session.system_language
{
  // Field Names

  I_GLAccountLineItem.SourceLedger,
  I_GLAccountLineItem.AccountingDocument,
  I_GLAccountLineItem.CompanyCode,
  I_GLAccountLineItem.FiscalYear,
  I_GLAccountLineItem.LedgerGLLineItem,

  I_GLAccountLineItem.Ledger,
  I_GLAccountLineItem.JointVenture,
  I_GLAccountLineItem.JointVenturePartner,
  I_GLAccountLineItem.JointVentureEquityGroup,
  I_GLAccountLineItem.JointVentureEquityType,
  I_GLAccountLineItem.JointVentureAccountingActivity,
  I_GLAccountLineItem.FiscalPeriod                                 as PostingPeriod,
  I_GLAccountLineItem.ReferenceDocumentItem,
  I_GLAccountLineItem.TransactionSubitem,
  @Semantics.currencyCode: true
  I_GLAccountLineItem.BalanceTransactionCurrency,
  @Semantics.currencyCode: true
  I_GLAccountLineItem.CompanyCodeCurrency,
  @Semantics.currencyCode: true
  I_GLAccountLineItem.GlobalCurrency,

  I_GLAccountLineItem.CostCenter,

  //      @Semantics: { amount : { currencyCode: 'BalanceTransactionCurrency'} }

  I_GLAccountLineItem.AmountInBalanceTransacCrcy,
  //      @Semantics: { amount : { currencyCode: 'CurrencyKey'} }

  I_GLAccountLineItem.AmountInCompanyCodeCurrency,
  //      @Semantics: { amount : { currencyCode: 'TransactionCurrency'} }

  I_GLAccountLineItem.AmountInTransactionCurrency,
  //      @Semantics: { amount : { currencyCode: 'GlobalCurrency'} }

  I_GLAccountLineItem.AmountInGlobalCurrency,

  I_GLAccountLineItem.ItemIsSplit,
  I_GLAccountLineItem.DocumentItemText,
  //    I_GLAccountLineItem.InventorySpecialStockSupplier        ,

  I_GLAccountLineItem.Supplier,
  I_GLAccountLineItem.InvtrySpclStockWBSElmntIntID,
  I_GLAccountLineItem.InventorySpclStockWBSElement,
  I_GLAccountLineItem.MasterFixedAsset,
  I_GLAccountLineItem.AssetClass,

  I_GLAccountLineItem.WBSElementInternalID,
  I_GLAccountLineItem.WBSElement,
  I_GLAccountLineItem.ProjectInternalID,
  I_GLAccountLineItem.Project,

  I_GLAccountLineItem.ControllingDocumentItem,

  _AccountingDocSeg.dmbtr                                          as LocalCrcyTotal,
  _AccountingDocSeg.wrbtr                                          as FundingCrcyTotal,

  _Venture.JntVntrBillgFormat,
  _Venture.JntVntrNonBillgFormat,

  _Venture_Desc.JointVentureName,

  _Partner.JntVntrBillgFormat                                      as JntVntrPartnerBillgFormat,
  _Partner.JntVntrHardCopyBillgIsSupp                              as JntVntrHardCopyBillgIsSupp,

  _Partner_Data._StandardAddress.Country                           as Country,
  _Partner_Data.FaxNumber                                          as JntVntrPartnerFaxNumber,
  _Partner_Data.Country                                            as JntVntrPartnerCountry,
  _Partner_Data.AddressID                                          as JntVntrPartnerAddressID,
  _Partner_Data.Language                                           as Language,
  _Partner_Data._StandardAddress._DefaultEmailAddress.EmailAddress as EmailAddress,
  _Partner_Data.BusinessPartnerName1                               as JointVentureOperatorName,
  _JV_Company.Operator                                             as JointVentureOperator,
  _AccountingDocHdr.Currency                                       as Currency,
  _AccountingDocHdr.ExchangeRate                                   as ExchangeRate,
  _AccountingDocHdr.CompanyCodeCurrency                            as LocalCurrency,

  _VentureEquity_Data.JntVntrNonOperatedShare                      as JntVntrNonOperatedShare,
  _VentureEquity_Data.JntVntrOperatedShare                         as JntVntrOperatedShare,

  _Equity_Desc.JntOpgAgrmtEquityGrpText                            as JointVentureEquityGroupName,

  cast( concat( I_GLAccountLineItem.AccountingDocument,
           concat( I_GLAccountLineItem.CompanyCode, I_GLAccountLineItem.FiscalYear ) )
            as apoc_appl_object_id )                               as OutputControlApplicationObject,
  _Partner_Data.BPCustomerName                                     as JointVenturePartnerName
}
where
      I_GLAccountLineItem.SourceLedger = ld.Ledger
  and I_GLAccountLineItem.Ledger       = ld.Ledger
  and _AccountingDocSeg.xbilk          = 'X'