I_AccountingDocument

 @AbapCatalog.entityBuffer.definitionAllowed: false
 @VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Accounting Document'
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@Analytics.dataCategory: #DIMENSION
@Analytics.technicalName: 'IFIACCDOC'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'AccountingDocument'
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@Metadata.ignorePropagatedAnnotations: true 
@Metadata.allowExtensions:true
//--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

@AccessControl.privilegedAssociations: ['_AccountingDocumentTypeText','_BusinessTransactionTypeText','_LedgerText']
// ]--GENERATED


@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
                                     
@VDM.lifecycle.status: #DEPRECATED       
@VDM.lifecycle.successor: 'I_JournalEntry'                               
                                     
define view entity I_AccountingDocument
  as select from bkpf

  
  //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

  association [0..*] to I_AccountingDocumentTypeText as _AccountingDocumentTypeText on  $projection.AccountingDocumentType = _AccountingDocumentTypeText.AccountingDocumentType
  association [0..*] to I_BusTransactionTypeText     as _BusinessTransactionTypeText on $projection.BusinessTransactionType = _BusinessTransactionTypeText.BusinessTransactionType
  association [0..*] to I_LedgerText                 as _LedgerText                 on  $projection.Ledger = _LedgerText.Ledger
  // ]--GENERATED

  association [0..*] to I_OperationalAcctgDocItem    as _OperationalAcctgDocItem    on  $projection.CompanyCode = _OperationalAcctgDocItem.CompanyCode and 
                                                                                        $projection.AccountingDocument = _OperationalAcctgDocItem.AccountingDocument and
                                                                                        $projection.FiscalYear = _OperationalAcctgDocItem.FiscalYear and
                                                                                        $projection.FiscalPeriod = _OperationalAcctgDocItem.FiscalPeriod and
                                                                                        $projection.AccountingDocumentCategory = _OperationalAcctgDocItem.AccountingDocumentCategory and
                                                                                        $projection.PostingDate = _OperationalAcctgDocItem.PostingDate and
                                                                                        $projection.DocumentDate = _OperationalAcctgDocItem.DocumentDate and
                                                                                        $projection.AccountingDocumentType = _OperationalAcctgDocItem.AccountingDocumentType
  association [1..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_FiscalYearForCompanyCode   as _FiscalYear                 on  $projection.FiscalYear  = _FiscalYear.FiscalYear
                                                                                    and $projection.CompanyCode = _FiscalYear.CompanyCode
  //association [0..1] to I_FiscalYear                 as _FiscalYear                 on  $projection.FiscalYear  = _FiscalYear.FiscalYear

  //                                                                                  and $projection.fiscalyearvariant = _FiscalYear.FiscalYearVariant 

                                                                                      // FiscalYearVariant not in BKPF, would require join with I_CompanyCode to get FiscalYearVariant                                                                                   

  association [0..1] to I_AccountingDocumentType     as _AccountingDocumentType     on  $projection.AccountingDocumentType = _AccountingDocumentType.AccountingDocumentType
  association [0..1] to I_User                       as _User                       on  $projection.AccountingDocCreatedByUser = _User.UserID
  association [0..1] to I_AccountingDocumentCategory as _AccountingDocumentCategory on  $projection.AccountingDocumentCategory = _AccountingDocumentCategory.AccountingDocumentCategory
  association [0..1] to I_BusinessTransactionType    as _BusinessTransactionType    on  $projection.BusinessTransactionType = _BusinessTransactionType.BusinessTransactionType
  association [0..1] to I_ReferenceDocumentType      as _ReferenceDocumentType      on  $projection.ReferenceDocumentType = _ReferenceDocumentType.ReferenceDocumentType
  association [0..1] to I_Ledger                     as _Ledger                     on  $projection.Ledger = _Ledger.Ledger
  association [0..1] to I_LedgerGroup                as _LedgerGroup                on  $projection.LedgerGroup = _LedgerGroup.LedgerGroup
  association [0..1] to I_Currency                   as _Currency                   on  $projection.Currency = _Currency.Currency
  association [0..1] to I_Currency                   as _CompanyCodeCurrency        on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_Currency                   as _AdditionalCurrency1        on  $projection.AdditionalCurrency1 = _AdditionalCurrency1.Currency
  association [0..1] to I_Currency                   as _AdditionalCurrency2        on  $projection.AdditionalCurrency2 = _AdditionalCurrency2.Currency
  association [0..1] to I_LogicalSystem              as _LogicalSystem              on  $projection.ReferenceDocumentLogicalSystem = _LogicalSystem.LogicalSystem

{
      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key cast(bkpf.bukrs as fis_bukrs preserving type)                                   as CompanyCode, // FieldGroup: _BASIC

      @ObjectModel.foreignKey.association: '_FiscalYear'
//      @Semantics.fiscal.year: true

  key cast(bkpf.gjahr as fis_gjahr preserving type)                                   as FiscalYear, // FieldGroup: AccountingGroup

  key cast(bkpf.belnr as farp_belnr_d preserving type)                                as AccountingDocument, // FieldGroup: AccountingGroup


      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_AccountingDocumentTypeStdVH',
                     element: 'AccountingDocumentType' }
        }]
      @ObjectModel.text.association: '_AccountingDocumentTypeText'
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      cast(bkpf.blart as farp_blart preserving type)                                  as AccountingDocumentType, // FieldGroup: AccountingGroup

      cast(bkpf.bldat as fis_bldat preserving type)                                   as DocumentDate, // FieldGroup: DocumentGroup

      cast(bkpf.budat as fis_budat preserving type)                                   as PostingDate, // FieldGroup: BASIC                                    //  New DTEL  toDo

      @Semantics.fiscal.period: true
      cast( cast( concat( '0', bkpf.monat ) as abap.numc( 3 ) ) as fins_fiscalperiod) as FiscalPeriod,
      --    monat as FiscalPeriod, // FieldGroup: AccountingGroup

      cast(bkpf.cpudt as farp_cpudt preserving type)                                  as AccountingDocumentCreationDate, // FieldGroup: AccountingGroup

      cast(bkpf.cputm as ttet_dt_cr_time preserving type)                             as CreationTime,
      cast(bkpf.aedat as ttet_dt_chg_date preserving type)                            as LastChangeDate,
      cast(bkpf.wwert as vdm_v_exchange_rate_date preserving type)                    as ExchangeRateDate,
      //    @ObjectModel.foreignKey.association: '_User'

      cast(bkpf.usnam as fis_usnam preserving type)                                   as AccountingDocCreatedByUser,
      bkpf.tcode                                                                      as TransactionCode,
      cast(bkpf.bvorg as fac_bvorg preserving type)                                                   as IntercompanyTransaction,
      bkpf.xblnr                                                                      as DocumentReferenceID, //FieldGroup: DocumentGroup

      cast(bkpf.dbblg as fac_rjet_id preserving type)                                                 as RecurringAccountingDocument,
      bkpf.stblg                                                                      as ReverseDocument,
      bkpf.stjah                                                                      as ReverseDocumentFiscalYear,
      bkpf.bktxt                                                                      as AccountingDocumentHeaderText,
      cast(bkpf.kursf as ukurs_curr preserving type)                                                  as ExchangeRate,
      bkpf.kzwrs                                                                      as GroupCurrency,
      @ObjectModel.foreignKey.association: '_AccountingDocumentCategory'
      cast(bkpf.bstat as farp_bstat_d preserving type)                                as AccountingDocumentCategory, //FieldGroup: AccountingGroup

      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_BusTransTypeStdVH',
                     element: 'BusinessTransactionType' }
        }]
      @ObjectModel.text.association: '_BusinessTransactionTypeText'
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_BusinessTransactionType'
      cast(bkpf.glvor as fins_bttype preserving type)                                 as BusinessTransactionType,
      cast(bkpf.grpid as fac_grpid preserving type)                                   as BatchInputSession,
      @ObjectModel.foreignKey.association: '_ReferenceDocumentType'
      cast(bkpf.awtyp as fis_awtyp)                                                   as ReferenceDocumentType,
      cast(bkpf.awkey as fac_awkey)                                                   as OriginalReferenceDocument,
      bkpf.fikrs                                                                      as FinancialManagementArea,
      cast(bkpf.awsys as fis_awsys)                                                   as ReferenceDocumentLogicalSystem, //?????????????I_LogicalSystem missing

      bkpf.brnch                                                                      as Branch,
//      @Semantics.booleanIndicator 

      bkpf.adisc                                                                      as IsDiscountDocument,
      cast(bkpf.xref1_hd as fins_xref1_hd)                                            as Reference1InDocumentHeader,
      cast(bkpf.xref2_hd as fins_xref2_hd)                                            as Reference2InDocumentHeader,
      bkpf.reindat                                                                    as InvoiceReceiptDate,
      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_LedgerStdVH',
                     element: 'Ledger' }
        }]
      @ObjectModel.text.association: '_LedgerText'
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_Ledger'
      cast(bkpf.rldnr as fis_rldnr preserving type)                                   as Ledger,
      @ObjectModel.foreignKey.association: '_LedgerGroup'
      bkpf.ldgrp                                                                      as LedgerGroup,
//    cast(bkpf.xblnr_alt as fis_xblnr_alt_wo_exit preserving type)                   as AlternativeReferenceDocument,

      cast(bkpf.xblnr_alt as fac_xblnr_alt preserving type)                           as AlternativeReferenceDocument,
      cast(bkpf.xreversing as fins_xreversing)                                        as IsReversal,
      cast(bkpf.xreversed as fins_xreversed)                                          as IsReversed,
      bkpf.vatdate                                                                    as TaxReportingDate,
      bkpf.stgrd                                                                      as ReversalReason,
      bkpf.ppdat                                                                      as ParkingDate,
      bkpf.pptme                                                                      as ParkingTime,

      @ObjectModel.foreignKey.association: '_Currency'
      cast(bkpf.waers as waers preserving type)                                       as Currency,
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      cast(bkpf.hwaer as fis_hwaer preserving type)                                   as CompanyCodeCurrency, //FieldGroup: AccountingGroup

      @ObjectModel.foreignKey.association: '_AdditionalCurrency1'
      cast(bkpf.hwae2 as fis_hwae2 preserving type)                                   as AdditionalCurrency1, //FieldGroup: AccountingGroup                    //  New DTEL  toDo

      @ObjectModel.foreignKey.association: '_AdditionalCurrency2'
      cast(bkpf.hwae3 as fis_hwae3 preserving type)                                   as AdditionalCurrency2, //FieldGroup: AccountingGroup                    //  New Dtel  toDo

      
      
      bkpf.xmwst as TaxIsCalculatedAutomatically,
      bkpf.numpg as NmbrOfPages,

      _OperationalAcctgDocItem,
      _CompanyCode,
      _FiscalYear,
      _AccountingDocumentType,
      _AccountingDocumentCategory,
      _BusinessTransactionType,
      _ReferenceDocumentType,
      _Ledger,
      _LedgerGroup,
      _User,
      _Currency,
      _CompanyCodeCurrency,
      _AdditionalCurrency1,
      _AdditionalCurrency2,
      _LogicalSystem,
      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.hidden: true
      _AccountingDocumentTypeText,
      @Consumption.hidden: true
      _BusinessTransactionTypeText,
      @Consumption.hidden: true
      _LedgerText
      // ]--GENERATED


}