I_InsurPlcyCashFlowHeader

DDL: I_INSURPLCYCASHFLOWHEADER Type: view_entity COMPOSITE Package: VDM_PM_PLCY_CF_COMMON

Insurance Policy Cash Flow Header

I_InsurPlcyCashFlowHeader is a Composite CDS View that provides data about "Insurance Policy Cash Flow Header" in SAP S/4HANA. It reads from 1 data source (I_InsurPlcyCashFlowHeaderBasic) and exposes 41 fields with key field InsurPolicyCashFlowDocument. It has 11 associations to related views. Part of development package VDM_PM_PLCY_CF_COMMON.

1 data source(s) 41 fields

Data Sources (1)

SourceAliasJoin Type
I_InsurPlcyCashFlowHeaderBasic CFHeader from

Associations (11)

CardinalityTargetAliasCondition
[1..1] I_Currency _Currency $projection.InsurPlcyCshFlwDocCurrency = _Currency.Currency
[1..1] I_InsurPlcyCshFlwDocPostgState _InsurPlcyCshFlwDocPostgState $projection.InsurPlcyCshFlwDocPostingState = _InsurPlcyCshFlwDocPostgState.InsurPlcyCshFlwDocPostingState
[1..1] I_InsurPlcyCshFlwNoTransfRsn _InsurPlcyCshFlwNoTransfRsn $projection.InsurPlcyCshFlwDocNoTransfRsn = _InsurPlcyCshFlwNoTransfRsn.InsurPlcyCshFlwDocNoTransfRsn
[1..1] I_InsurPlcyBusinessObject _InsurPlcyBusinessObject $projection.InsurPlcyBusinessObject = _InsurPlcyBusinessObject.InsurPlcyBusinessObject
[1..1] I_InsurPlcyCshFlwDocOrigin _InsurPlcyCshFlwDocOrigin $projection.InsurPlcyCshFlwDocumentOrigin = _InsurPlcyCshFlwDocOrigin.InsurPlcyCshFlwDocumentOrigin
[1..1] I_InsurPlcyCashFlowHeader _InsurPlcyCashFlowRevDocHeader $projection.InsurPlcyCshFlwDocReversalDoc = _InsurPlcyCashFlowRevDocHeader.InsurPolicyCashFlowDocument
[1..1] I_InsurPlcyCashFlowHeader _InsurPlcyCshFlwCoinsurDocHdr $projection.InsurPlcyCshFlwDocCoinsurDoc = _InsurPlcyCshFlwCoinsurDocHdr.InsurPolicyCashFlowDocument
[1..*] I_InsurPlcyTemplateT _InsurPlcySlsProductTemplateT $projection.InsurPlcySalesProductTemplate = _InsurPlcySlsProductTemplateT.InsurPlcyTemplate
[1..*] I_InsurPlcyTemplateT _InsurPlcyProductTemplateT $projection.InsurPlcyProductTemplate = _InsurPlcyProductTemplateT.InsurPlcyTemplate
[1..1] I_InsurancePolicy _InsurancePolicy $projection.InsurPlcyUUID = _InsurancePolicy.InsurPlcyUUID
[0..*] I_InsurPlcyCashFlowItem _InsurPlcyCashFlowItem

Annotations (11)

NameValueLevelField
EndUserText.label Insurance Policy Cash Flow Header view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #CHECK view
ObjectModel.representativeKey InsurPolicyCashFlowDocument view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XXL view
Metadata.allowExtensions false view
Metadata.ignorePropagatedAnnotations false view
Analytics.technicalName IPPlcyCFH view

Fields (41)

KeyFieldSource TableSource FieldDescription
KEY InsurPolicyCashFlowDocument I_InsurPlcyCashFlowHeaderBasic InsurPolicyCashFlowDocument
InsurancePolicy I_InsurPlcyCashFlowHeaderBasic InsurancePolicy
InsurPlcyUUID I_InsurPlcyCashFlowHeaderBasic InsurPlcyUUID
InsuranceApplication I_InsurPlcyCashFlowHeaderBasic InsuranceApplication
InsuranceContract I_InsurPlcyCashFlowHeaderBasic InsuranceContract
InsurPlcyCashFlowDocumentDate I_InsurPlcyCashFlowHeaderBasic InsurPlcyCashFlowDocumentDate
InsurPlcyCshFlwDocPostingState I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocPostingState
InsurPlcyCshFlwDocNoTransfRsn I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocNoTransfRsn
InsurPlcyCshFlwDocPostingDate I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocPostingDate
InsurPlcyCshFlwSettlmtStrtDate I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwSettlmtStrtDate
InsurPlcyCshFlwSettlmtEndDate I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwSettlmtEndDate
InsurPlcyCshFlwDocCompanyCode I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocCompanyCode
InsurPlcyCshFlwDocCurrency I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocCurrency
InsurPlcyCshFlwOriglJrnlNmbr I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwOriglJrnlNmbr
InsurPlcyBusinessObject I_InsurPlcyCashFlowHeaderBasic InsurPlcyBusinessObject
InsurPlcyCshFlwDocCurJrnlNmbr I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocCurJrnlNmbr
InsurPlcyCshFlwDocumentOrigin I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocumentOrigin
InsurPlcyCshFlwDocReversalDoc I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocReversalDoc
InsurPlcyCshFlwDocIsRvslDoc I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocIsRvslDoc
InsurPlcyCshFlwDocIsReversed I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocIsReversed
InsurPlcyCshFlwDocCoinsurDoc I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocCoinsurDoc
InsurPlcyInsurContr I_InsurPlcyCashFlowHeaderBasic InsurPlcyInsurContr
InsurPlcyCshFlwDocumentDueDate I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwDocumentDueDate
InsurPlcySalesProductTemplate I_InsurPlcyCashFlowHeaderBasic InsurPlcySalesProductTemplate
InsurPlcyProductTemplate I_InsurPlcyCashFlowHeaderBasic InsurPlcyProductTemplate
InsurPlcyCshFlwValdtyBeginDte I_InsurPlcyCashFlowHeaderBasic InsurPlcyCshFlwValdtyBeginDte
InsurPlcyChangedByUser I_InsurPlcyCashFlowHeaderBasic InsurPlcyChangedByUser
LastChangeDateTime I_InsurPlcyCashFlowHeaderBasic LastChangeDateTime
InsrrIDByInsrr _InsurancePolicy InsrrIDByInsrr
InsurPlcyAuthznSlsProductGroup _InsurancePolicy InsurPlcyAuthznSlsProductGroup
_InsurPlcyCashFlowItem _InsurPlcyCashFlowItem
_InsurPlcySlsProductTemplateT _InsurPlcySlsProductTemplateT
_InsurPlcyProductTemplateT _InsurPlcyProductTemplateT
_InsurPlcyCshFlwCoinsurDocHdr _InsurPlcyCshFlwCoinsurDocHdr
_InsurPlcyCashFlowRevDocHeader _InsurPlcyCashFlowRevDocHeader
_InsurPlcyCshFlwDocOrigin _InsurPlcyCshFlwDocOrigin
_InsurPlcyBusinessObject _InsurPlcyBusinessObject
_InsurPlcyCshFlwDocPostgState _InsurPlcyCshFlwDocPostgState
_InsurPlcyCshFlwNoTransfRsn _InsurPlcyCshFlwNoTransfRsn
_Currency _Currency
_InsurancePolicy _InsurancePolicy 
@EndUserText.label: 'Insurance Policy Cash Flow Header'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
                    privilegedAssociations:  [ '_InsurPlcyCashFlowItem']
}
@ObjectModel: {
   representativeKey: 'InsurPolicyCashFlowDocument',
   semanticKey: [ 'InsurPolicyCashFlowDocument' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XXL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcyCFH'
}

define root view entity I_InsurPlcyCashFlowHeader
  as select from I_InsurPlcyCashFlowHeaderBasic as CFHeader

  composition [0..*] of I_InsurPlcyCashFlowItem        as _InsurPlcyCashFlowItem

  association [1..1] to I_Currency                     as _Currency                      on $projection.InsurPlcyCshFlwDocCurrency = _Currency.Currency
  association [1..1] to I_InsurPlcyCshFlwDocPostgState as _InsurPlcyCshFlwDocPostgState  on $projection.InsurPlcyCshFlwDocPostingState = _InsurPlcyCshFlwDocPostgState.InsurPlcyCshFlwDocPostingState
  association [1..1] to I_InsurPlcyCshFlwNoTransfRsn   as _InsurPlcyCshFlwNoTransfRsn    on $projection.InsurPlcyCshFlwDocNoTransfRsn = _InsurPlcyCshFlwNoTransfRsn.InsurPlcyCshFlwDocNoTransfRsn
  association [1..1] to I_InsurPlcyBusinessObject      as _InsurPlcyBusinessObject       on $projection.InsurPlcyBusinessObject = _InsurPlcyBusinessObject.InsurPlcyBusinessObject
  association [1..1] to I_InsurPlcyCshFlwDocOrigin     as _InsurPlcyCshFlwDocOrigin      on $projection.InsurPlcyCshFlwDocumentOrigin = _InsurPlcyCshFlwDocOrigin.InsurPlcyCshFlwDocumentOrigin
  association [1..1] to I_InsurPlcyCashFlowHeader      as _InsurPlcyCashFlowRevDocHeader on $projection.InsurPlcyCshFlwDocReversalDoc = _InsurPlcyCashFlowRevDocHeader.InsurPolicyCashFlowDocument
  association [1..1] to I_InsurPlcyCashFlowHeader      as _InsurPlcyCshFlwCoinsurDocHdr  on $projection.InsurPlcyCshFlwDocCoinsurDoc = _InsurPlcyCshFlwCoinsurDocHdr.InsurPolicyCashFlowDocument
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcySlsProductTemplateT  on $projection.InsurPlcySalesProductTemplate = _InsurPlcySlsProductTemplateT.InsurPlcyTemplate
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyProductTemplateT     on $projection.InsurPlcyProductTemplate = _InsurPlcyProductTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurancePolicy              as _InsurancePolicy               on $projection.InsurPlcyUUID = _InsurancePolicy.InsurPlcyUUID
{

  key CFHeader.InsurPolicyCashFlowDocument,
      CFHeader.InsurancePolicy,
      @ObjectModel.foreignKey.association: '_InsurancePolicy'
      CFHeader.InsurPlcyUUID,
      CFHeader.InsuranceApplication,
      CFHeader.InsuranceContract,
      @Semantics.businessDate.at: true
      CFHeader.InsurPlcyCashFlowDocumentDate,
      @ObjectModel.foreignKey.association: '_InsurPlcyCshFlwDocPostgState'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCshFlwDocPostingState'
      CFHeader.InsurPlcyCshFlwDocPostingState,
      @ObjectModel.foreignKey.association: '_InsurPlcyCshFlwNoTransfRsn'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCshFlwDocNoTransfRsn'
      CFHeader.InsurPlcyCshFlwDocNoTransfRsn,
      @Semantics.businessDate.at: true
      CFHeader.InsurPlcyCshFlwDocPostingDate,
      @Semantics.businessDate.from: true
      CFHeader.InsurPlcyCshFlwSettlmtStrtDate,
      @Semantics.businessDate.to: true
      CFHeader.InsurPlcyCshFlwSettlmtEndDate,
      CFHeader.InsurPlcyCshFlwDocCompanyCode,
      @ObjectModel.foreignKey.association: '_Currency'
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      CFHeader.InsurPlcyCshFlwDocCurrency,
      CFHeader.InsurPlcyCshFlwOriglJrnlNmbr,
      @ObjectModel.foreignKey.association: '_InsurPlcyBusinessObject'
      // @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyBusinessObject'

      CFHeader.InsurPlcyBusinessObject,
      CFHeader.InsurPlcyCshFlwDocCurJrnlNmbr,
      @ObjectModel.foreignKey.association: '_InsurPlcyCshFlwDocOrigin'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCshFlwDocumentOrigin'
      CFHeader.InsurPlcyCshFlwDocumentOrigin,
      @ObjectModel.foreignKey.association: '_InsurPlcyCashFlowRevDocHeader'
      CFHeader.InsurPlcyCshFlwDocReversalDoc,
      CFHeader.InsurPlcyCshFlwDocIsRvslDoc,
      CFHeader.InsurPlcyCshFlwDocIsReversed,
      @ObjectModel.foreignKey.association: '_InsurPlcyCshFlwCoinsurDocHdr'
      CFHeader.InsurPlcyCshFlwDocCoinsurDoc,
      CFHeader.InsurPlcyInsurContr,
      @Semantics.businessDate.at: true
      CFHeader.InsurPlcyCshFlwDocumentDueDate,
      @ObjectModel.text.association: '_InsurPlcySlsProductTemplateT'
      // @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyTemplate'

      CFHeader.InsurPlcySalesProductTemplate,
      @ObjectModel.text.association: '_InsurPlcyProductTemplateT'
      // @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyTemplate'

      CFHeader.InsurPlcyProductTemplate,
      @Semantics.businessDate.at: true
      CFHeader.InsurPlcyCshFlwValdtyBeginDte,
      @Semantics.user.lastChangedBy: true
      CFHeader.InsurPlcyChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      CFHeader.LastChangeDateTime,
      _InsurancePolicy.InsrrIDByInsrr,
      @Consumption.hidden: true
      _InsurancePolicy.InsurPlcyAuthznSlsProductGroup,

      /* Associations */
      _InsurPlcyCashFlowItem,

      @Consumption.hidden: true
      _InsurPlcySlsProductTemplateT,
      @Consumption.hidden: true
      _InsurPlcyProductTemplateT,
      @Consumption.hidden: true
      _InsurPlcyCshFlwCoinsurDocHdr,
      @Consumption.hidden: true
      _InsurPlcyCashFlowRevDocHeader,
      @Consumption.hidden: true
      _InsurPlcyCshFlwDocOrigin,
      @Consumption.hidden: true
      _InsurPlcyBusinessObject,
      @Consumption.hidden: true
      _InsurPlcyCshFlwDocPostgState,
      @Consumption.hidden: true
      _InsurPlcyCshFlwNoTransfRsn,
      @Consumption.hidden: true
      _Currency,
      @Consumption.hidden: true
      _InsurancePolicy

}

Learn More