I_InsurApplCoverage

@EndUserText.label: 'Coverage of Cvrg Package in Insur Appl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
                    privilegedAssociations:  [  '_InsurApplCvrgSurchrgDiscount',
                                                '_InsurApplCoverageLimit',
                                                '_InsurApplCvrgClause',
                                                '_InsurApplCvrgDeductible',
                                                '_InsurApplInsuredObject',
                                                '_InsurApplSubCoverage',
                                                '_InsurApplCvrgTypeRegionalCl',
                                                '_InsurApplCvrgPremComparison']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyCoverageID',
   semanticKey: [ 'InsurPlcyInsuranceCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IACvrg'
}

define view entity I_InsurApplCoverage
  as select from P_InsurPolicyJournalKeys  as PlcyJrnl
    inner join   I_InsurPlcyCoverageBasic  as Coverage              on  PlcyJrnl.InsurPlcyUUID                  =  Coverage.InsurPlcyUUID
                                                                    and PlcyJrnl.InsurPlcyInsurContr            =  Coverage.InsurPlcyInsurContr
                                                                    and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= Coverage.InsurPlcyJrnlNmbr
                                                                    and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  Coverage.InsurPlcyJrnlEndNmbr

  // Get Template of Contract

    inner join   I_InsurApplContract       as InsurApplContractTmpl on  Coverage.InsurPlcyUUID                  = InsurApplContractTmpl.InsurPlcyUUID
                                                                    and Coverage.InsurPlcyInsurContr            = InsurApplContractTmpl.InsurPlcyInsurContr
                                                                    and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr = InsurApplContractTmpl.InsurPlcyContrDataDetnJrnlNmbr

  // Join to Regular Premium on Coveragelevel

    inner join   R_InsurApplicationPremium as RegularPremium        on  RegularPremium.InsurPlcyUUID                  = Coverage.InsurPlcyUUID
                                                                    and RegularPremium.InsurPlcyInsurContr            = Coverage.InsurPlcyInsurContr
                                                                    and RegularPremium.InsurPlcyCoveragePackageID     = Coverage.InsurPlcyCoveragePackageID
                                                                    and RegularPremium.InsurPlcyCoverageID            = Coverage.InsurPlcyCoverageID
                                                                    and RegularPremium.InsurPlcyContrDataDetnJrnlNmbr = PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr
  // Filter Premium Objects

    inner join   I_InsurPlcyRegPremConfig  as PremiumConfig         on  PremiumConfig.InsurPlcyProductTemplate = InsurApplContractTmpl.InsurPlcyProductTemplate
                                                                    and PremiumConfig.InsurPremType            = RegularPremium.InsurPremType

  association        to parent I_InsurApplCoveragePackage as _InsurApplCoveragePackage  on  $projection.InsurPlcyUUID                  = _InsurApplCoveragePackage.InsurPlcyUUID
                                                                                        and $projection.InsurPlcyInsurContr            = _InsurApplCoveragePackage.InsurPlcyInsurContr
                                                                                        and $projection.InsurPlcyCoveragePackageID     = _InsurApplCoveragePackage.InsurPlcyCoveragePackageID
                                                                                        and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurApplCoveragePackage.InsurPlcyContrDataDetnJrnlNmbr

  composition [0..*] of I_InsurApplCvrgSurchrgDiscount    as _InsurApplCvrgSurchrgDiscount
  composition [0..*] of I_InsurApplCoverageLimit          as _InsurApplCoverageLimit
  composition [0..*] of I_InsurApplCvrgClause             as _InsurApplCvrgClause
  composition [0..*] of I_InsurApplCvrgDeductible         as _InsurApplCvrgDeductible
  composition [0..*] of I_InsurApplInsuredObject          as _InsurApplInsuredObject
  composition [0..*] of I_InsurApplSubCoverage            as _InsurApplSubCoverage
  composition [0..*] of I_InsurApplCvrgTypeRegionalCl     as _InsurApplCvrgTypeRegionalCl
  composition [0..*] of I_InsurApplCvrgPremComparison     as _InsurApplCvrgPremComparison
  composition [0..*] of I_InsurApplCoverageBonusMalus     as _InsurApplCoverageBonusMalus

  association [1..1] to I_Currency                        as _PremiumCurrency           on  $projection.InsurPlcyPremiumCurrency = _PremiumCurrency.Currency
  association [1..1] to I_Currency                        as _CoverageCurrency          on  $projection.InsurPlcyCoverageCurrency = _CoverageCurrency.Currency
  association [1..1] to I_InsurContrCanclnReason          as _InsurContrCanclnReason    on  $projection.InsurContrCanclnRsn = _InsurContrCanclnReason.InsurContrCanclnRsn
  association [1..1] to I_InsurPlcyCvrgLifeCycSts         as _InsurPlcyCvrgLifeCycSts   on  $projection.InsurPlcyCvrgLifeCycleStatus = _InsurPlcyCvrgLifeCycSts.InsurPlcyCvrgLifeCycleStatus
  association [1..1] to I_InsurPlcyCvrgInsrdSumCalc       as _InsurPlcyCvrgInsrdSumCalc on  $projection.InsurPlcyCvrgInsrdSumCalcMeth = _InsurPlcyCvrgInsrdSumCalc.InsurPlcyCvrgInsrdSumCalcMeth
  association [1..1] to I_InsurPlcyCvrgSuspension         as _InsurPlcyCvrgSuspension   on  $projection.InsurPlcyCoverageSuspension = _InsurPlcyCvrgSuspension.InsurPlcyCoverageSuspension
  association [1..*] to I_InsurPlcyTemplateT              as _InsurPlcyTemplateT        on  $projection.InsurPlcyElementaryProdTmpl = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurPlcyCvrgPremExmpRsnLink    as _InsurPlcyCvrgPremExmpRsn  on  $projection.InsurPlcyCvrgPremExmpReason = _InsurPlcyCvrgPremExmpRsn.InsurPlcyCvrgPremExmpReason
                                                                                        and $projection.InsurPlcyElementaryProdTmpl = _InsurPlcyCvrgPremExmpRsn.InsurancePolicyCoverageControl

{

  key Coverage.InsurPlcyUUID,
  key Coverage.InsurPlcyInsurContr,
  key Coverage.InsurPlcyCoveragePackageID,
  key Coverage.InsurPlcyCoverageID,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Coverage.InsurPlcyJrnlNmbr,
      Coverage.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Coverage.InsurPlcyProductPackageID,
      Coverage.InsurPlcyInsuranceCoverage,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Coverage.InsurPlcyElementaryProdTmpl,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCoverageStartDateTime,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCoverageEndDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgPremExmpRsn'
      Coverage.InsurPlcyCvrgPremExmpReason,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgLifeCycSts'
      Coverage.InsurPlcyCvrgLifeCycleStatus,
      @ObjectModel.foreignKey.association: '_InsurContrCanclnReason'
      Coverage.InsurContrCanclnRsn,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgCanclnDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgSuspension'
      Coverage.InsurPlcyCoverageSuspension,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgSuspnStrtDateTime,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgSuspnEndDateTime,
      @Semantics.amount.currencyCode: 'InsurPlcyCoverageCurrency'
      Coverage.InsurPlcyCvrgInsuredSumAmount,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgInsrdSumCalc'
      Coverage.InsurPlcyCvrgInsrdSumCalcMeth,
      Coverage.InsurPlcyCvrgInsuredSumPercent,
      @ObjectModel.foreignKey.association: '_CoverageCurrency'
      Coverage.InsurPlcyCoverageCurrency,
      //FS-PM Auto sibling specific fields

      Coverage.InsurPlcyBonusRestorerType,
      Coverage.InsurPlcyVehDeregistrationDate,
      Coverage.InsurPlcyBonusMalusIsNotCeded,
      Coverage.InsurPlcyInsurEndMsgSendDate,
      Coverage.InsurPlcySubcoverageVariant,
      Coverage.InsurPlcyVehInsurCoverEndDate,
      Coverage.InsurPlcyNrOfVehClaimsRestored,
      Coverage.InsurPlcyCrteInsurEndMessage,
      Coverage.InsurPlcyDiscProtIsActive,
      @Semantics.systemDateTime.lastChangedAt: true
      Coverage.LastChangeDateTime,

      RegularPremium.InsurancePolicyPremium,
      RegularPremium.InsurPlcyJrnlNmbr                                                                as InsurPlcyPremiumJournalNumber,
      RegularPremium.InsurPlcyJrnlEndNmbr                                                             as InsurPlcyPremJournalEndNumber,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPerdPremBfrTaxPaytAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPerdPremAftTaxPaytAmt,
      RegularPremium.InsurPremType,
      @Semantics.booleanIndicator:true
      RegularPremium.InsurPlcyCvrgIsPremiumExempt,
      RegularPremium.InsurPlcyCvrgPremExmpEndDate,
      @ObjectModel.foreignKey.association: '_PremiumCurrency'
      RegularPremium.InsurPlcyPremiumCurrency,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPlcyTotAnnPremAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPlcyPerdPremBfrTxPaytAmt,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      RegularPremium.InsurPlcyPremiumTemplate,

      /* Associations */
      _InsurApplCoveragePackage,
      _InsurApplCvrgSurchrgDiscount,
      _InsurApplCoverageLimit,
      _InsurApplCvrgClause,
      _InsurApplCvrgTypeRegionalCl,
      _InsurApplCvrgPremComparison,
      _InsurApplCvrgDeductible,
      _InsurApplInsuredObject,
      _InsurApplSubCoverage,
      _InsurApplCoverageBonusMalus,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurContrCanclnReason,
      @Consumption.hidden: true
      _InsurPlcyCvrgLifeCycSts,
      @Consumption.hidden: true
      _InsurPlcyCvrgSuspension,
      @Consumption.hidden: true
      _InsurPlcyCvrgInsrdSumCalc,
      @Consumption.hidden: true
      _CoverageCurrency,
      @Consumption.hidden: true
      _PremiumCurrency,
      @Consumption.hidden: true
      _InsurPlcyCvrgPremExmpRsn

}
where
  Coverage.InsurPlcyCoveragePackageID <> 0