I_InsurApplSubCoverage

@EndUserText.label: 'Cvrg SubCoverage of CvPcg in Insur Appl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurApplLimit',
                              '_InsurApplSubCvrgClause',
                              '_InsurApplSubCvrgDeductible']
}
@ObjectModel: {
   representativeKey: 'InsurPlcySubCvrgID',
   semanticKey: [ 'InsurPlcyInsuranceSubCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IASubCvrg'
}

define view entity I_InsurApplSubCoverage
  as select from P_InsurPolicyJournalKeys    as PlcyJrnl
    inner join   I_InsurPlcySubCoverageBasic as SubCoverage on  PlcyJrnl.InsurPlcyUUID                  =  SubCoverage.InsurPlcyUUID
                                                            and PlcyJrnl.InsurPlcyInsurContr            =  SubCoverage.InsurPlcyInsurContr
                                                            and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= SubCoverage.InsurPlcyJrnlNmbr
                                                            and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  SubCoverage.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurApplCoverage   as _InsurApplCoverage         on  $projection.InsurPlcyUUID                  = _InsurApplCoverage.InsurPlcyUUID
                                                                                   and $projection.InsurPlcyInsurContr            = _InsurApplCoverage.InsurPlcyInsurContr
                                                                                   and $projection.InsurPlcyCoveragePackageID     = _InsurApplCoverage.InsurPlcyCoveragePackageID
                                                                                   and $projection.InsurPlcyCoverageID            = _InsurApplCoverage.InsurPlcyCoverageID
                                                                                   and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurApplCoverage.InsurPlcyContrDataDetnJrnlNmbr

  composition [0..*] of I_InsurApplLimit             as _InsurApplLimit
  composition [0..*] of I_InsurApplSubCvrgClause     as _InsurApplSubCvrgClause
  composition [0..*] of I_InsurApplSubCvrgDeductible as _InsurApplSubCvrgDeductible

  association [1..1] to I_InsurPlcyCvrgInsrdSumCalc  as _InsurPlcyCvrgInsrdSumCalc on  $projection.InsurPlcySubCvrgInsrdSumCalc = _InsurPlcyCvrgInsrdSumCalc.InsurPlcyCvrgInsrdSumCalcMeth
  association [1..1] to I_Currency                   as _Currency                  on  $projection.InsurPlcySubCoverageCurrency = _Currency.Currency
  association [1..*] to I_InsurPlcyTemplateT         as _InsurPlcyTemplateT        on  $projection.InsurPlcySubCoverageTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

{

  key SubCoverage.InsurPlcyUUID,
  key SubCoverage.InsurPlcyInsurContr,
  key SubCoverage.InsurPlcyCoveragePackageID,
  key SubCoverage.InsurPlcyCoverageID,
  key SubCoverage.InsurPlcySubCvrgID,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      SubCoverage.InsurPlcyJrnlNmbr,
      SubCoverage.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      SubCoverage.InsurPlcyProductPackageID,
      SubCoverage.InsurPlcyInsuranceSubCoverage,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      SubCoverage.InsurPlcySubCoverageTemplate,
      SubCoverage.InsurPlcySubCoverageStartDate,
      SubCoverage.InsurPlcySubCoverageEndDate,
      @Semantics.amount.currencyCode: 'InsurPlcySubCoverageCurrency'
      SubCoverage.InsurPlcySubCvrgInsrdSumAmount,
      @ObjectModel.foreignKey.association: '_Currency'
      SubCoverage.InsurPlcySubCoverageCurrency,
      SubCoverage.InsurPlcySubCvrgInsuredSumPct,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgInsrdSumCalc'
      SubCoverage.InsurPlcySubCvrgInsrdSumCalc,
      @Semantics.systemDateTime.lastChangedAt: true
      SubCoverage.LastChangeDateTime,

      /* Associations */
      _InsurApplCoverage,
      _InsurApplLimit,
      _InsurApplSubCvrgClause,
      _InsurApplSubCvrgDeductible,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _Currency,
      @Consumption.hidden: true
      _InsurPlcyCvrgInsrdSumCalc

}
where
  SubCoverage.InsurPlcyCoveragePackageID <> 0